I should use your screenshots as advertisements for my component This is really amazing! Could you please paste your codes and colours here so I can post them on the first page as an example?
thank you! as you requested, i'm posting my formatting here and you're free to do whatever you want with it. it could use some work (as some new features are somehow hot-glued to the rest).
separator playlists can be either with empty (or space-filled) names or starting with -. when using -, you can also specify the character to be used for line drawing: -line_character; or text to be used on the separator: -separator_text (separator_text has to be longer than 1 character). also the line can be disabled for index and / or number columns, as in this screenshot (it's just a showcase of what it can do; i wouldn't use that dashed line before send playlist and the thick one):
with the introduction of style formatting, one doesn't have to set colors with the dialogs. you would need the font from here (it's in the rar with fcs files).
padding: 4 (left, right), 0 (top, bottom)
font: Calibri MOD2 8pt Bold
display:
//// column widths -----------------------------------------------------------------------------
$puts(ci,1)
$puts(ct,12)
$puts(cl,2)
$puts(cn,2)
$puts(cs,1)
$if(,
$puts(ci,1)
$puts(ct,12)
$puts(cl,7)
$puts(cn,2)
$puts(cs,1)
,)
//// colors --------------------------------------------------------------------------------------
$puts(cols,cccccc|FFFFFF)
$puts(colse,cccccc|cccccc)
$puts(coli,888888|FFFFFF)
$puts(colt,818181|FFFFFF)
$puts(colti,F9D577|FEEFBF)
$puts(coll,009CE8|E0AD12)
$puts(coln,888888|FFFFFF)
//// other ---------------------------------------------------------------------------------------
// lock name abbr. (toggle: 1 - enabled, nothing - disabled; ex.: $puts(la,) )
$puts(la,1)
// separators for index / number (toggle)
$puts(tsi,)
$puts(tsn,)
//// set-up -------------------------------------------------------------------------------------
//$puts(s,$get(cols)┇$tab($get(cs)))
$if($or($strcmp($replace(%title%, ,),),$stricmp($left(%title%,1),-)),$puts(empty,1)$puts(cols,$get(colse)),)
$if($stricmp($left(%title%,1),-),$ifgreater($len(%title%),2,$puts(stitle,$substr(%title%,2,$len(%title%))),$puts(ss,$substr(%title%,2,2))),)
$puts(s,$get(cols)┇)
//$if(%lock%,,$puts(ct,$add($get(ct),$get(cl))))
//// separators --------------------------------------------------------------------------------
$if($get(ss),,
//$puts(ss,╴)
$puts(ss,─)
//$puts(ss,–)
)
$if($get(tsi),$puts(si,$repeat($get(ss),6)),)
$puts(st,$if($get(stitle),──┐$get(stitle)┌,)$repeat($get(ss),100))
$if($get(tsn),$puts(sn,$repeat($get(ss),6)),)
// ------------------------------------------------------------------------------------------------
// formatting string
// index
$if($get(empty),$get(cols)$get(si),
$get(coli)$replace($num(%index%,2),0,₀,1,₁,2,₂,3,₃,4,₄,5,₅,6,₆,7,₇,8,₈,9,₉))
$tab($get(ci))
// index-sep
$get(s)
// title
$if($get(empty),$get(st),
$get(colt)
%title%
$get(colti)
//$if(%isactive%,' (active'$if(%isplaying%,', playing')')',$if(%isplaying%,' (playing)'))
$if($and(%isactive%,%isplaying%), '(↔)',$if(%isactive%, '(↓)',$if(%isplaying%, '(→)',)))
)
$tab($get(ct))
// lock
$if(%lock%,
$get(coll)
'('$if($get(la),$abbr($upper(%lock%)),$lower(%lock%))')'
,)
$tab($get(cl))
// size-sep
$get(s)$if($get(empty),$get(sn),)$tab($get(cn))
// size
$ifgreater(%size%,0,$get(coln)$replace(%size%,0,₀,1,₁,2,₂,3,₃,4,₄,5,₅,6,₆,7,₇,8,₈,9,₉),)
style:
$if($or($strcmp($replace(%title%, ,),),$stricmp($left(%title%,1),-)),
$set_style(back,FFFFFF,FFFFFF)
//$set_style(text,CCCCCC,CCCCCC)
,$set_style(back,FFFFFF,F9D577))
$set_style(text,818181,FFFFFF)