Skip to main content
Topic: A good mmpc foobar display config? (Read 57909 times) previous topic - next topic
0 Members and 1 Guest are viewing this topic.

A good mmpc foobar display config?

Reply #50
copyright on artist pictures? LOL!
Seriously, what is there to laugh about here?


Well first of all: Pictures of artists have already been posted. (in a setup or not, they are "copyrighted", no?) 
2nd: It's not like anyone would get in trouble for posting a link to a pack of promotional artist pictures...

Call me stupid, but thats how i see it.

A good mmpc foobar display config?

Reply #51

copyright on artist pictures? LOL!
Seriously, what is there to laugh about here?


Well first of all: Pictures of artists have already been posted. (in a setup or not, they are "copyrighted", no?) 
2nd: It's not like anyone would get in trouble for posting a link to a pack of promotional artist pictures...

Call me stupid, but thats how i see it.

Well...I get both of your points; technically it's illegal, but IRL no one will care...so I'll upload thewm tommorrow...maybe with a nice disclaimer or something
Les mots d'amour...

A good mmpc foobar display config?

Reply #52
Well...I get both of your points; technically it's illegal, but IRL no one will care...so I'll upload thewm tommorrow...maybe with a nice disclaimer or something
There's always an industry which cares. Well, who cares?

A good mmpc foobar display config?

Reply #53
Well first of all: Pictures of artists have already been posted. (in a setup or not, they are "copyrighted", no?) 
2nd: It's not like anyone would get in trouble for posting a link to a pack of promotional artist pictures...

Now that statement is a lot more meaningful than your original post which looked like you were just ridiculing the concept of having artist pictures copyrighted. By the way, I am strongly in favor of posting links to download pages instead of hotlinking to content or even uploading things to HA.

A good mmpc foobar display config?

Reply #54
Well first of all: Pictures of artists have already been posted. (in a setup or not, they are "copyrighted", no?) 
2nd: It's not like anyone would get in trouble for posting a link to a pack of promotional artist pictures...

Now that statement is a lot more meaningful than your original post which looked like you were just ridiculing the concept of having artist pictures copyrighted. By the way, I am strongly in favor of posting links to download pages instead of hotlinking to content or even uploading things to HA.

Well...you're right but:
  • There are 236 images, noe of which I know the original URL of.
  • All the images have been resized.
  • When I "hotlink", I have control over the availablility of the files. If I posted 236 links to JPG's, in one month at least 20% of them would give you a 404...

So here are the images, as I said earlier all in 1280x671; the correct size for use with ojdo's config:

http://www.filefactory.com/file/9fccfb/

I don't know exactly if the file will stay on there forever, but if not I will re-upload and renew the link. Good luck with it all
Les mots d'amour...

A good mmpc foobar display config?

Reply #55
What about your trackinfo mod settings?
Lighten up, it's just foobar.


A good mmpc foobar display config?

Reply #57
BTW, that's mostly ojdo's work, so thank him



Thanks 2 both of you    I'm really enjoying this setup

(I'm also having fun checking out some new artists on youtube atm from your fantastic wallpaper collection...)

A good mmpc foobar display config?

Reply #58
Here's my version. Based on ojdos layout (thanks a lot for sharing).
I'm using it on my laptop. Fonts are quite big so I can read the text from distance when connecting it to my LCD-TV.

I actually just changed the design a bit and added a second trackinfo (set to autohide) with a control bar at the bottom (as you can see in the second screenshot).

Both screenshots are fullscreen (removed the titlebar with autohotkey).

           

A good mmpc foobar display config?

Reply #59
Thanks all here for posting your screenshots. It's very nice to see that my config is useful for someone else. Sadly, some well made layouts make me want to update my config already. I hoped to be able to stick to my layout for some time...
I need a self-help group for foobar-addicted people.. 

A good mmpc foobar display config?

Reply #60
And... quicker than expected I finished version 2 of my fullscreen layout (version 1). This time it is much better coded and highly configurable. Credits go to FofR for inspiration and Cyex for his beautiful cd cover.

Preview


Default view


Addinfo (can be switched off) at beginning and end of a song


Pause


Personal modded version (second codebox)

Stuff needed
  • Images. Extract to your foobar's image directory.
  • Font used: Calibri. All font settings are at the top, so you easily can change it to another one if you don't have it
Trackinfo mod code (also included in the images' download)
Code: [Select]
// Global
// CONFIGURATION ///////////////////////////////////////////

// Album Art
// Use $if and $fileexists if more locations need to be checked
$puts(path.albumart,$replace(%path%,$if(%disc%,$directory(%path%,1)\)%filename_ext%,folder.jpg))

// Additional info
// addinfo.show: delete the '1' to disable additional info
// addinfo.time: determines how long addinfo is shown
$puts(addinfo.show,1)
$puts(addinfo.time,30)

// Positions
// pos.horizon: y-position of the grey horizon gradient
// pos.shadow: increase to see more reflection of the cd-cover
// pos.artx: if changed, further changes will  be necessary for text positioning
// pos.arty: change position of album art relative to horizon line
$puts(pos.horizon,$muldiv(%_height%,4,7))
$puts(pos.shadow,120)
$puts(pos.artx,$sub($div(%_width%,2),278))
$puts(pos.arty,$sub($get(pos.horizon),400))

// Fonts
// font.a, font.b: used by addinfo for a) filling text, b) values
$puts(font.track,$font(Calibri,32,,255-255-255))
$puts(font.artist,$font(Calibri,24,,255-255-255))
$puts(font.a,$font(Calibri,16,,150-150-150))
$puts(font.b,$font(Calibri,16,,255-255-255))

// Progress bar
$puts(bar.height,5)
$puts(bar.color,255-255-255)

// END OF CONFIG ///////////////////////////////////////////

// Background
$drawrect(,,,,brushcolor-0-0-0 pencolor-null)
$imageabs(,$get(pos.horizon),/images/htpc2/horizon.png,)

// PerTrack

// Album Art
$imageabs2(556,516,0,0,556,$add(29,$get(pos.shadow)),$get(pos.artx),$add(460,$get(pos.arty)),/images/htpc2/case.png,ROTATEFLIP-6)
$imageabs2(454,454,0,0,454,$add(-2,$get(pos.shadow)),$add(71,$get(pos.artx)),$add(460,31,$get(pos.arty)),$get(path.albumart),NOKEEPASPECT ROTATEFLIP-6)
$imageabs($get(pos.artx),$add($get(pos.shadow),299,$get(pos.arty)),/images/htpc2/shadow.png,)

$imageabs($get(pos.artx),$get(pos.arty),/images/htpc2/case.png,)
$imageabs2(454,454,0,0,454,454,$add(71,$get(pos.artx)),$add(31,$get(pos.arty)),$get(path.albumart),NOKEEPASPECT)
$imageabs($add(71,$get(pos.artx)),$add(31,$get(pos.arty)),/images/htpc2/gloss.png,)

// PerSecond

// Pause Overlay
$if(%ispaused%,
$drawrect($add(71,$get(pos.artx)),$add(31,$get(pos.arty)),454,454,pencolor-0-0-0 alpha-150)
$alignabs($add(71,$get(pos.artx)),$add(31,$get(pos.arty)),454,454,center,middle)$font(Webdings,72,,255-255-255)';'
$drawrect($add(71,$get(pos.artx)),$add(460,31,$get(pos.arty)),454,$add(-2,$get(pos.shadow)),pencolor-0-0-0 alpha-150)
)

// Progress Bar
$ifgreater($muldiv(%playback_time_seconds%,%_width%,%length_seconds%),0,
$drawrect(0,$sub(%_height%,$mul($get(bar.height),3)),$muldiv(%playback_time_seconds%,%_width%,%length_seconds%),$get(bar.height),pencolor-null brushcolor-$get(bar.color))
,)

// Trackinfo
$if($and($or($greater($get(addinfo.time),%playback_time_seconds%),$greater($get(addinfo.time),%playback_time_remaining_seconds%)),$get(addinfo.show)),
// Detailed
$alignabs(80,$add($get(pos.horizon),$get(pos.shadow)),$sub(%_width%,160),$sub(%_height%,$get(pos.horizon),$get(pos.shadow),64),center,bottom)
$get(font.track)$if2(%title%,%filename%)$char(10)
$get(font.artist)[%artist%]
$char(10)$font(Arial,10,,0-0-0) $char(10)
$if(%last_played%,$get(font.a)Bisher $get(font.b)%play_counter%$get(font.a)mal gehört', 'zuletzt am $get(font.b)$substr(%last_played%,9,10). $select($substr(%last_played%,6,7),Januar,Februar,März,April,Mai,Juni,Juli,August,September,Oktober,November,Dezember) $substr(%last_played%,1,4)$get(font.a).$char(10))
$if(%playback_time_seconds%,$get(font.a)Erschienen $if(%date%,im Jahr $get(font.b)%date%$get(font.a) )$if(%publisher%,bei $get(font.b)%publisher%$get(font.a) )$if(%album%,auf dem Album $get(font.b)%album%$get(font.a)).)
,
// Default
$alignabs($get(pos.artx),$add($get(pos.horizon),$get(pos.shadow)),556,$sub(%_height%,$get(pos.horizon),$get(pos.shadow),64),center,bottom)
$get(font.track)$if2(%title%,%filename%)$char(10)
$get(font.artist)[%artist%]
)

Personal modded version (displays rating and mood with colored bars, progress bar changes color on shuffle mode)
Code: [Select]
// Global
// CONFIGURATION ///////////////////////////////////////////

// Album Art
// Use $if and $fileexists if more locations need to be checked
$puts(path.albumart,
$if($fileexists($replace(%path%,%filename_ext%,%filename%.jpg)),$replace(%path%,%filename_ext%,%filename%.jpg),
$replace(%path%,$if(%disc%,$directory(%path%,1)\)%filename_ext%,folder.jpg)
)
)

// Additional info
// addinfo.show: delete the '1' to disable additional info
// addinfo.time: determines how long addinfo is shown
$puts(addinfo.show,1)
$puts(addinfo.time,30)

// Positions
// pos.horizon: y-position of the grey horizon gradient
// pos.shadow: increase to see more reflection of the cd-cover
// pos.artx: if changed, further changes will  be necessary for text positioning
// pos.arty: change position of album art relative to horizon line
$puts(pos.horizon,$muldiv(%_height%,4,7))
$puts(pos.shadow,120)
$puts(pos.artx,$sub($div(%_width%,2),278))
$puts(pos.arty,$sub($get(pos.horizon),400))

// Fonts
// font.a, font.b: used by addinfo for a) filling text, b) values
$puts(font.track,$font(Calibri,32,,255-255-255))
$puts(font.artist,$font(Calibri,24,,255-255-255))
$puts(font.a,$font(Calibri,16,,150-150-150))
$puts(font.b,$font(Calibri,16,,255-255-255))

// Progress bar
$puts(bar.height,5)
$puts(bar.width,32)
$puts(bar.progresscolor,$if($strstr(%cwb_playback_order%,Shuffle),128-0-255,0-128-255))
$puts(bar.ratingcolor,255-128-0)
$puts(bar.moodcolor,0-255-0)

// END OF CONFIG ///////////////////////////////////////////

// Background
$drawrect(,,,,brushcolor-0-0-0 pencolor-null)
$imageabs2(%_width%,49,0,0,%_width%,49,0,$get(pos.horizon),/images/htpc2/horizon.png,NOKEEPASPECT)

// PerTrack

// Album Art
$imageabs2(556,516,0,0,556,$add(29,$get(pos.shadow)),$get(pos.artx),$add(460,$get(pos.arty)),/images/htpc2/case.png,ROTATEFLIP-6)
$imageabs2(454,454,0,0,454,$add(-2,$get(pos.shadow)),$add(71,$get(pos.artx)),$add(460,31,$get(pos.arty)),$get(path.albumart),NOKEEPASPECT ROTATEFLIP-6)
$imageabs($get(pos.artx),$add($get(pos.shadow),299,$get(pos.arty)),/images/htpc2/shadow.png,)

$imageabs($get(pos.artx),$get(pos.arty),/images/htpc2/case.png,)
$imageabs2(454,454,0,0,454,454,$add(71,$get(pos.artx)),$add(31,$get(pos.arty)),$get(path.albumart),NOKEEPASPECT)
$imageabs($add(71,$get(pos.artx)),$add(31,$get(pos.arty)),/images/htpc2/gloss.png,)

// PerSecond

// Pause Overlay
$if(%ispaused%,
$drawrect($add(71,$get(pos.artx)),$add(31,$get(pos.arty)),454,454,pencolor-0-0-0 alpha-150)
$alignabs($add(71,$get(pos.artx)),$add(31,$get(pos.arty)),454,454,center,middle)$font(Webdings,72,,255-255-255)';'
$drawrect($add(71,$get(pos.artx)),$add(460,31,$get(pos.arty)),454,$add(-2,$get(pos.shadow)),pencolor-0-0-0 alpha-150)
)

// Bars
$ifgreater($muldiv(%playback_time_seconds%,%_width%,%length_seconds%),0,$drawrect(0,$sub(%_height%,$mul($get(bar.height),3)),$muldiv(%playback_time_seconds%,%_width%,%length_seconds%),$get(bar.height),pencolor-null brushcolor-$get(bar.progresscolor)),)

$ifgreater(%rating%,0,
$drawrect(0,$sub(%_height%,$mul($get(bar.height),6)),$mul(%rating%,$get(bar.width)),$get(bar.height),pencolor-null brushcolor-$get(bar.ratingcolor))
$alignabs($add(5,$mul(%rating%,$get(bar.width))),$sub(%_height%,$mul($get(bar.height),5),$div($get(bar.height),2),3,32),64,64,left,middle)$get(font.b)%rating%
,)

$ifgreater(%mood%,0,
$drawrect($sub(%_width%,$mul(%mood%,$get(bar.width))),$sub(%_height%,$mul($get(bar.height),6)),$mul(%mood%,$get(bar.width)),$get(bar.height),pencolor-null brushcolor-$get(bar.moodcolor))
$alignabs($sub(%_width%,$mul(%mood%,$get(bar.width)),64,5),$sub(%_height%,$mul($get(bar.height),5),$div($get(bar.height),2),3,32),64,64,right,middle)$get(font.b)%mood%
,)

// Trackinfo
$if($and($or($greater($get(addinfo.time),%playback_time_seconds%),$greater($get(addinfo.time),%playback_time_remaining_seconds%)),$get(addinfo.show)),
// Detailed
$alignabs(80,$add($get(pos.horizon),$get(pos.shadow)),$sub(%_width%,160),$sub(%_height%,$get(pos.horizon),$get(pos.shadow),64),center,bottom)
$get(font.track)$if2(%title%,[%filename%])$char(10)
$get(font.artist)[%artist%]
$char(10)$font(Arial,10,,0-0-0) $char(10)
$if(%last_played%,$get(font.a)Bisher $get(font.b)%play_counter%$get(font.a)mal gehört', 'zuletzt am $get(font.b)$substr(%last_played%,9,10). $select($substr(%last_played%,6,7),Januar,Februar,März,April,Mai,Juni,Juli,August,September,Oktober,November,Dezember) $substr(%last_played%,1,4)$get(font.a)., )$char(10)
$if(%playback_time_seconds%,$get(font.a)Erschienen $if(%date%,im Jahr $get(font.b)%date%$get(font.a) )$if(%publisher%,bei $get(font.b)%publisher%$get(font.a) )$if(%album%,auf dem Album $get(font.b)%album%$get(font.a))., )$char(10)
,
// Default
$alignabs(80,$add($get(pos.horizon),$get(pos.shadow)),$sub(%_width%,160),$sub(%_height%,$get(pos.horizon),$get(pos.shadow),64),center,bottom)
$get(font.track)$if2(%title%,%filename%)$char(10)
$get(font.artist)[%artist%]
$char(10)$font(Arial,10,,0-0-0) $char(10)
$get(font.a) $char(10) $char(10)
)

Edit: Bugfixed pause overlay. Now mirrored album art image gets darker, too.
Edit2: Added personal modded version
Edit3: Added screenshot of personal modded version


A good mmpc foobar display config?

Reply #62
why does that not work at all?

I just double-checked the code in the codebox, it should work as expected if the images are at the correct position (maybe you have multi-user support enabled?) and you have the latest trackinfo_mod version. Not up-to-date-versions could have problemes with the relative paths (strange enough, the mirrored case works and the unrotated does not).

A good mmpc foobar display config?

Reply #63
ojdo nice work on your newest config...but where's the artist image man 

I'll stick to the old one; artist image>album cover, especially with trackinfo_mod where half the images are blurry due to progressive-JPG
Les mots d'amour...

A good mmpc foobar display config?

Reply #64
noob here

Like a few others I've had trouble getting the wallpaper to display, I only get a black background. What is the exact filename and directory the wallpaper image needs to be at?

Thanks in advance for any help

A good mmpc foobar display config?

Reply #65
noob here

Like a few others I've had trouble getting the wallpaper to display, I only get a black background. What is the exact filename and directory the wallpaper image needs to be at?

Thanks in advance for any help

I had the same problem of no BG's showing up, here's how i fixed it..

The config needs editing to direct to YOUR music collection, and also the first line of the artist photo code needs editing to remove the /Alben/ text. Also, the Folder name has to be EXACTLY the same as the Artist name in the MP3 Tag's or no pic's will show.

If you're Already using the "folder.jpg" to display the album art, you also want to change that name to something more appropriate  ie - "bg.jpg" 

Code: [Select]
// Global
$puts(path.library,'Your music path here.')

// PerTrack
// Artist photo
$if($fileexists($get(path.library)%artist\bg.jpg),$imageabs2(%_width%,%_height%,0,0,%_width%,%_height%,0,0,$get(path.library)\%artist%\bg.jpg,nokeepaspect),


Now works a charm, and i love it. Slightly edited the progress bar, but aside from that i like it how it is, and im not experienced enough to do much else anyway.

Thanks for sharing!



[edit] Oh, one question, how do i get the %mood% box working?

A good mmpc foobar display config?

Reply #66
thanks Aliarse, that got it to work

what is the code to get the opacity fade in look on the black box in the lower third of the screen?

A good mmpc foobar display config?

Reply #67
// Artist overlays
$drawrect(,$get(art.h),,,brushcolor-19-19-19 pencolor-0-0-0 alpha-155)

Adjust the alpha number.

A good mmpc foobar display config?

Reply #68
ojdo nice work on your newest config...but where's the artist image man 
I'll stick to the old one;

Your good right
I wanted a less ressource hungry config as the reaction time on rating (or "mooding"?) a file were too long for my taste. When I get a stronger CPU, I will probably will redo a luxurious layout including big and fat artist photos  .

artist image>album cover, especially with trackinfo_mod where half the images are blurry due to progressive-JPG

Did you try the latest trackinfo_mod version? Since then, the only blurry images I still had where low-resolution ones which couldn't look better anywhere.


Like a few others I've had trouble getting the wallpaper to display, I only get a black background. What is the exact filename and directory the wallpaper image needs to be at?


It's just the other way round. Where do you have your artist pictures? When you tell the scheme, then the line of code can be written that will find the pictures.

Oh, one question, how do i get the %mood% box working?

This code displays the mood-number (for me: 1-3) if available. As your rating-box works, I can't see any trackinfo_mod related reason why the mood-box shouldn't work:

Code: [Select]
$font(Arial Unicode MS,18,glow-64-64-64 glowblur-5 glowexpand-1,19-19-19)
$alignabs($sub(%_width%,211),$sub(%_height%,$get(pos.y2),58),60,60,center,middle)[%rating%]
$alignabs($sub(%_width%,177),$sub(%_height%,$get(pos.y2),58),60,60,center,middle)[%mood%]

A good mmpc foobar display config?

Reply #69
Hehe, your code was fine already, the reason it wasn't working is because i didn't have the custom info component installed (which i found out after searching for mood). Installed that and set it up and its now working. 

A good mmpc foobar display config?

Reply #70

why does that not work at all?

I just double-checked the code in the codebox, it should work as expected if the images are at the correct position (maybe you have multi-user support enabled?) and you have the latest trackinfo_mod version. Not up-to-date-versions could have problemes with the relative paths (strange enough, the mirrored case works and the unrotated does not).

i have 0.8.0 beta

thats the one i got off of the official site

A good mmpc foobar display config?

Reply #71
fixed it


A good mmpc foobar display config?

Reply #73
Hey leokennis, can you please share your code for getting a general genre pic to show if there is no artist pic found?

A good mmpc foobar display config?

Reply #74
Hey leokennis, can you please share your code for getting a general genre pic to show if there is no artist pic found?

Code: [Select]
$if(%isplaying%,$if($fileexists(M:\Art\%artist%.jpg),$imageabs2(1280,671,0,0,1280,671,0,0,M:\Art\%artist%.jpg,nokeepaspect),$imageabs2(1280,671,0,0,1280,671,0,0,M:\Art\%genre%.jpg,nokeepaspect)),)
Les mots d'amour...

 
SimplePortal 1.0.0 RC1 © 2008-2019