Hi Everyone
I've started using EAC with mareo a couple of years ago, but have been putting off ripping my entire collection for the n-th time as I wasn't 100% convinced with the setup I had.
Then at last I discovered REACT2 and some excellent hi-fi guides which made me feel much more confident in creating an almost perfect archive, especially with the CD repair guide.
After a few tests with the setup I still have a few questions which require clarification.
(My settings and log file follows below.)
1) Setting replaygain to '1' only seems to produce replaygain for the flac files and not the MP3 or Ogg files for the same album. How do I get it to apply the same replaygain settings calculated for the flac files into the ogg & mp3 tags?
I know LAME can perform replaygain, but I would like it to use the settings determined for the flac files.
1a) Even though I asked it to, REACT did not add any replaygain info to the cue sheets.
(work around)
The problem here was that the cue sheet to which REACT adds the RG info is not one of the four that is being copied to the flac directory. It does add it but to the wrong cue file.
As I did not know how to add it to all 4 cue sheets, I changed the image.cfg file to add it to the log file instead, by making the following code changes
REM ---- Image ----
REM Ensure that the EAC log is available
:CheckForLog
IF NOT EXIST "@eaclog@" GOTO Pause
REM Add ReplayGain to front of log file
TYPE "@eaclog@" >> %wg_tmp%.rg
MOVE /Y %wg_tmp%.rg "@eaclog@"
2) I've tested three different (popular) albums and none of these seems to have any album art which I find curious. (All three sites return nothing.) How do I test this, can I add sites and/or load the album art manually either from other sites or scanning it myself?(solved in post #1207 of this thread)
2a) If I put the album art only in the (album) folder will media players such as an iPod (Classic v5) or XBMC (XBOX Media Centre) pick up the art when playing playlists or in random order?
3) I assume that REACT automatically complete the tags and it thus need not be specified in the flac, ogg or mp3 options?
(solved)
Inspecting the image.cfg file indicates that the tags are populated when the tracks are created.
3a) I noticed that foobar would recognise the total number of tracks (xx/yy) but only for ogg and flac files. Am I missing a setting for the MP3 tracks or does the MP3 tags not allow/cater for this?
3b) What type of tags does REACT produce and can this be changed?
4) Is it possible to rename the EAC logfile to "album + EACLogfile"?
(work around)
I used the following code to copy the log file without renaming it. You of course have to do this for each of the encodings for which you require a copy of the log file.
Replace...
COPY /Y "@eaclog@" "EACLog.txt"
...with...
COPY /Y "@eaclog@" .
5) Is it possible to produce a logfile of the actual Ogg and MP3 encoding results or is there any other way to produce a file that states the encoding options used?
6) Are there any media players that recognise the cue sheets in random play order mode and thus not play the gaps?
7) Do I still have to submit my results to accurate rip or is that also automated?
How do I make the files read-only so the media players cannot alter any of the files?
The idea with my setup is as follows;
1) Rip my entire collection as flac tracks for archive purposes and perform backup of archive (on HDD)
2) Encode flac tracks in Ogg for playback on XBMC (XBOX Media Centre) and my computer (via NAS)
3) Encode flac tracks in MP3 for playback on iPod
4) Directory structure -> "Artist - Album [YEAR]/TrackNo. TrackName" and "Various Artist - Album [YEAR]/TrackNo. TrackName [Artist]" (I know my ini does not reflect this yet.)
5) Include album art so it will be displayed on all players and all different replay modes.
6) Apply track and album replaygain
7) Generate cue and log files
Generate flac fingerprints
9) make all files and directories read only to protect it from modification by players which might try to "fix" the tags, artwork, etc.
10) Generate MD5 checksums on directories for backup purposes
Thanks for the assistance/advice
Regards
Paul
Ps. I use XP Pro SP3, EAC V0.99 pb4, REACT2, flac 1.2.1, lame 3.98 and oggenc 2.85
--------------> Debug.bat file
@ECHO OFF
CHCP 1252 | PROMPT
TITLE "The Memory Of Trees"
REM Copyright © Tycho, 2006
REM
REM ** Ripping to .wav image.
REM **
REM ** To archive a CD as one large "image", you must SET
REM ** ImageExt=... in the REACT.ini file (Press Alt-F2).
REM ** This will set the wav variable. Extensions
REM ** currently supported: flac, wv, mp3. Set to 'wav'
REM ** for no image archiving (default).
REM **
REM ** Also creates tracks by encoding directly to tracks, using ACDIR.
REM **
REM ** Flac requires flac.exe/metaflac.exe (v1.1.3)
REM ** NeroAac requires NeroAacEnc.exe/NeroAacTag.exe/AacGain.exe.
REM ** OggEnc2 requires OggEnc2.exe/VorbisGain.exe.
REM **
REM ** I prefer applying album gain 92dB to get a reasonable
REM ** volume for my DAP. The RG tags are still relative
REM ** to 89dB SPL, i.e. album gain will be about -3.0dB.
REM ============== Begin Main Script ==================
IF 1==1 ECHO ON
IF 0==0 SET TrackName=$n - $~t
IF 0==1 SET TrackName=$n - $~t [$~a]
SET add_rg=1
SET have_cover=0
SET embed_cover=0
IF NOT 1==1 GOTO end_RG
SET RG_Flac=--replay-gain
SET RG_MetaFlac=--add-replay-gain
SET RG_MetaMP3=--replay-gain
:end_RG
IF NOT 1==1 GOTO end_apply_AG
SET ApplyAG_MetaMP3=--apply-gain album+3
SET ApplyAG_AacGain=/a /o /c /d +3
SET add_rg=1
:end_apply_AG
IF EXIST "C:\Music (EAC)\The Memory Of Trees.jpg" (
SET have_cover=1
SET embed_cover=1
)
IF 0==0 (
SET ArtistField=artist
SET MP3Artist=--artist "Enya"
) else (
SET ArtistField=album artist
SET MP3Artist=--user-text "[album artist]Various Artists" --frame "TPE2:Various Artists"
)
REM ** Create Disc-related tags if we have a set
REM If a disc name has been provided
IF "" EQU "" GOTO end_discname
SET discName=discname
SET discName=@%discname%@
IF "" EQU "%discName%" GOTO end_discname
REM Set tagging switches
SET Disc_Flac=-T "discname="
SET Disc_Wavpack=-w "discname="
REM SET Disc_MP3=--frame TSST:""
SET Disc_MP3=--frame "TXXX[setsubtitle]:"
SET Disc_OggEnc2=-c "discname="
SET Disc_Tak=-t "discname="
SET Disc_Flac_acdir=-T $qdiscname=$q
SET Disc_Wavpack_acdir=-w $qdiscname=$q
REM SET Disc_MP3_acdir=--frame TSST:$q$q
SET Disc_MP3_acdir=--frame $qTXXX[setsubtitle]:$q
SET Disc_OggEnc2_acdir=-c $qdiscname=$q
SET Disc_Tak_acdir=-t $qdiscname=$q
REM Add disc name to image and track folder paths
SET imageDir=%imageDir%\
SET trackDir=%trackDir%\
GOTO :end_discnumber
:end_discname
REM Ensure that we have numeric values
SET /A discNumber = 1 + 0
SET /A totalDiscs = 1 + 0
REM IF a valid disc number and total number of discs has been provided
IF %totalDiscs% LEQ 1 GOTO :end_discnumber
IF %discNumber% LEQ 0 GOTO :end_discnumber
REM Set tagging switches
SET Disc_Flac=-T "discnumber=1" -T "totaldiscs=1"
SET Disc_Wavpack=-w "discnumber=1" -w "totaldiscs=1"
SET Disc_MP3=--frame TPOS:"1/1"
SET Disc_NeroAac=--disk "1/1"
SET Disc_OggEnc2=-c "discnumber=1" -c "totaldiscs=1"
SET Disc_Tak=-t "discnumber=1" -t "totaldiscs=1"
SET Disc_Flac_acdir=-T $qdiscnumber=1$q -T $qtotaldiscs=1$q
SET Disc_Wavpack_acdir=-w $qdiscnumber=1$q -w $qtotaldiscs=1$q
SET Disc_MP3_acdir=--frame TPOS:$q1/1$q
SET Disc_NeroAac_acdir=--disk $q1/1$q
SET Disc_OggEnc2_acdir=-c $qdiscnumber=1$q -c $qtotaldiscs=1$q
SET Disc_Tak_acdir=-t $qdiscnumber=1$q -t $qtotaldiscs=1$q
REM Add disc number to image and track folder paths
SET imageDir=%imageDir%\Disc 1
SET trackDir=%trackDir%\Disc 1
:end_discnumber
SET run_wavegain=1
IF 1==1 SET run_wavegain=1
IF %run_wavegain%==0 GOTO end_wavegain
SET wg_tmp=wg_%RANDOM%
C:\PROGRA~1\REACT2\tools\WaveGain.exe --album "C:\Music (EAC)\Etmp!58)5.wav" --exec ECHO '%%ALBUM_GAIN%%'%%ALBUM_PEAK%%'%%ALBUM_NEW_PEAK%%'%%ALBUM_SCALE%%'> %wg_tmp%.txt
FOR /F "usebackq tokens=1-6 delims='" %%a IN (%wg_tmp%.txt) DO (
SET album_gain=%%b
SET album_peak=%%c
SET album_new_peak=%%d
SET album_scale=%%e
)
ECHO REM REPLAYGAIN_ALBUM_GAIN %album_gain% dB> %wg_tmp%.rg
ECHO REM REPLAYGAIN_ALBUM_PEAK %album_peak%>> %wg_tmp%.rg
ECHO REM REPLAYGAIN_ALBUM_SCALE %album_scale%>> %wg_tmp%.rg
REM DEL %wg_tmp%.txt
REM TYPE "C:\Music (EAC)\Enya - The Memory Of Trees [1995].log" >> %wg_tmp%.rg
REM MOVE /Y %wg_tmp%.rg "C:\Music (EAC)\Enya - The Memory Of Trees [1995].log"
:end_wavegain
REM ** Transfer RG values from Wavgain calculations, instead of recalculation.
IF 1==1 IF %add_rg%==1 (
SET RG_Flac=-T "replaygain_album_gain=%album_gain% dB" -T "replaygain_album_peak=%album_peak%"
SET RG_MetaFlac=--set-tag="replaygain_album_gain=%album_gain% dB" --set-tag="replaygain_album_peak=%album_peak%"
SET RG_Wavpack=-w "replaygain_album_gain=%album_gain% dB" -w "replaygain_album_peak=%album_peak%"
SET RG_Wavpack_acdir=-w $qreplaygain_album_gain=%album_gain% dB$q -w $qreplaygain_album_peak=%album_peak%$q
SET RG_Tak=-t "replaygain_album_gain=%album_gain% dB" -t "replaygain_album_peak=%album_peak%"
SET RG_Tak_acdir=-t $qreplaygain_album_gain=%album_gain% dB$q -t $qreplaygain_album_peak=%album_peak%$q
SET RG_MetaMP3=--user-text "[replaygain_album_gain]%album_gain% dB" --user-text "[replaygain_album_peak]%album_peak%"
SET RG_OggEnc2_acdir=-c $qreplaygain_album_gain=%album_gain% dB$q -c $qreplaygain_album_peak=%album_peak%$q
)
REM ** Apply AlbumGain by using --scale <factor> computed from WaveGain. Only for MP3 and OGG.
IF 1==1 IF 1==1 (
SET ApplyAG_Lame=--scale %album_scale%
SET ApplyAG_MetaMP3=--apply-gain +3
SET RG_MetaMP3=--user-text "[replaygain_album_gain]0.0 dB" --user-text "[replaygain_album_peak]%album_new_peak%"
SET RG_OggEnc2_acdir=--scale %album_scale% -c $qreplaygain_album_gain=0.0 dB$q -c $qreplaygain_album_peak=%album_new_peak%$q
)
REM ---- Image ----
REM Ensure that the EAC log is available
:CheckForLog
IF NOT EXIST "C:\Music (EAC)\Enya - The Memory Of Trees [1995].log" GOTO Pause
REM Add ReplayGain to front of log file
TYPE "C:\Music (EAC)\Enya - The Memory Of Trees [1995].log" >> %wg_tmp%.rg
MOVE /Y %wg_tmp%.rg "C:\Music (EAC)\Enya - The Memory Of Trees [1995].log"
IF NOT wav==flac GOTO end_flac_image
SET dest="C:\Music (EAC)\FLAC-images\Enya - The Memory Of Trees [$year]%imageDir%"
IF NOT EXIST %dest% MKDIR %dest%
IF %embed_cover%==1 SET Cover_tag=--picture="|image/jpeg|||C:\Music (EAC)\The Memory Of Trees.jpg"
C:\PROGRA~1\REACT2\tools\flac.exe -6 -f %RG_Flac% %Cover_tag% %Disc_Flac% -T "%ArtistField%=Enya" -T album="The Memory Of Trees" -T totaltracks="11" -T date="1995" -T genre="Celtic" -T comment="Created with EAC/REACT2, 2008-08-04" -T encoded-by="%USERNAME%" -T encoding="Flac 1.2.1 -6 -f" --tag-from-file="cuesheet=C:\Music (EAC)\Enya - The Memory Of Trees [1995].cue" --tag-from-file="eaclog=C:\Music (EAC)\Enya - The Memory Of Trees [1995].log" "C:\Music (EAC)\Etmp!58)5.wav" -o "C:\Music (EAC)\Enya - The Memory Of Trees [1995].wav"
MOVE /Y "C:\Music (EAC)\Enya - The Memory Of Trees [1995].wav" %dest%
MOVE /Y "C:\Music (EAC)\Enya - The Memory Of Trees [1995].cue" %dest%
IF %have_cover%==1 COPY /Y "C:\Music (EAC)\The Memory Of Trees.jpg" %dest%\"Enya - The Memory Of Trees [1995].jpg"
:end_flac_image
IF NOT wav==wv GOTO end_wavpack_image
SET dest="C:\Music (EAC)\WV-images\Enya [$year] The Memory Of Trees%imageDir%"
IF NOT EXIST %dest% MKDIR %dest%
C:\PROGRA~1\REACT2\tools\wavpack.exe -hmy %RG_Wavpack% %Disc_Wavpack% -w "%ArtistField%=Enya" -w album="The Memory Of Trees" -w totaltracks="11" -w year="1995" -w genre="Celtic" -w comment="Created with EAC/REACT2, 2008-08-04" -w encodedby="%USERNAME%" -w encodersettings="Wavpack 4.40 -hmy" -w cuesheet="@C:\Music (EAC)\Enya - The Memory Of Trees [1995].cue" -w eaclog="@C:\Music (EAC)\Enya - The Memory Of Trees [1995].log" "C:\Music (EAC)\Etmp!58)5.wav" "C:\Music (EAC)\Enya - The Memory Of Trees [1995].wav"
IF 1==1 IF 1==0 C:\PROGRA~1\REACT2\tools\wvgain.exe -a "C:\Music (EAC)\Enya - The Memory Of Trees [1995].wav"
TITLE "The Memory Of Trees"
MOVE /Y "C:\Music (EAC)\Enya - The Memory Of Trees [1995].wav" %dest%
MOVE /Y "C:\Music (EAC)\Enya - The Memory Of Trees [1995].cue" %dest%
IF %have_cover%==1 COPY /Y "C:\Music (EAC)\The Memory Of Trees.jpg" %dest%\"Enya - The Memory Of Trees [1995].jpg"
:end_wavpack_image
IF NOT wav==tak GOTO end_tak_image
SET dest="C:\Music (EAC)\TAK-images\Enya [$year] The Memory Of Trees%imageDir%"
IF NOT EXIST %dest% MKDIR %dest%
C:\PROGRA~1\REACT2\tools\takc.exe -e -pN -overwrite "C:\Music (EAC)\Etmp!58)5.wav" "C:\Music (EAC)\Enya - The Memory Of Trees [1995].wav"
C:\PROGRA~1\REACT2\tools\tag.exe %RG_Tak% %Disc_Tak% -t "%ArtistField%=Enya" -t album="The Memory Of Trees" -t totaltracks="11" -t year="1995" -t genre="Celtic" -t comment="Created with EAC/REACT2, 2008-08-04" -t encodedby="%USERNAME%" -t encodersettings="TAK 1.0.1 -pN -overwrite" -f cuesheet="C:\Music (EAC)\Enya - The Memory Of Trees [1995].cue" -f eaclog="C:\Music (EAC)\Enya - The Memory Of Trees [1995].log" "C:\Music (EAC)\Enya - The Memory Of Trees [1995].wav"
MOVE /Y "C:\Music (EAC)\Enya - The Memory Of Trees [1995].wav" %dest%
MOVE /Y "C:\Music (EAC)\Enya - The Memory Of Trees [1995].cue" %dest%
IF %have_cover%==1 COPY /Y "C:\Music (EAC)\The Memory Of Trees.jpg" %dest%\"Enya - The Memory Of Trees [1995].jpg"
:end_tak_image
IF NOT wav==mp3 GOTO end_lame_image
SET dest="C:\Music (EAC)\MP3-images\Enya [$year] The Memory Of Trees%imageDir%"
IF NOT EXIST %dest% MKDIR %dest%
IF %embed_cover%==1 SET Cover_tag=--pict "{3}C:\Music (EAC)\The Memory Of Trees.jpg"
C:\PROGRA~1\REACT2\tools\lame.exe -V4 --vbr-new --noreplaygain --nohist %ApplyAG_Lame% "C:\Music (EAC)\Etmp!58)5.wav" "C:\Music (EAC)\Enya - The Memory Of Trees [1995].wav"
C:\PROGRA~1\REACT2\tools\metamp3.exe %RG_MetaMP3% %Cover_tag% %Disc_MP3% %MP3Artist% --album "The Memory Of Trees" --track 11 --year "1995" --genre "Celtic" --comment "Created with EAC/REACT2, 2008-08-04" --frame TENC:"%USERNAME%" --frame TSSE:"LAME 3.98 -V4 --vbr-new --noreplaygain --nohist" "C:\Music (EAC)\Enya - The Memory Of Trees [1995].wav"
IF 1==1 C:\PROGRA~1\REACT2\tools\metamp3.exe %ApplyAG_MetaMP3% "C:\Music (EAC)\Enya - The Memory Of Trees [1995].wav"
MOVE /Y "C:\Music (EAC)\Enya - The Memory Of Trees [1995].wav" %dest%
MOVE /Y "C:\Music (EAC)\Enya - The Memory Of Trees [1995].cue" %dest%
IF %have_cover%==1 COPY /Y "C:\Music (EAC)\The Memory Of Trees.jpg" %dest%\"Enya - The Memory Of Trees [1995].jpg"
:end_lame_image
REM ---- Tracks ----
IF NOT 1==1 GOTO end_flac_tracks
SET dest="C:\Music (EAC)\FLAC\Enya - The Memory Of Trees [1995]%trackDir%"
IF NOT EXIST %dest% MKDIR %dest%
PUSHD %dest%
IF 0==1 SET VA_tag=-T $qalbum artist=Various Artists$q
IF %embed_cover%==1 SET Cover_tag=--picture=$#x
C:\PROGRA~1\REACT2\tools\acdir.exe --overwrite --output "%TrackName%.flac" --extra-opt "|image/jpeg|||C:\Music (EAC)\The Memory Of Trees.jpg" --pipe "TITLE $n/$N flac $#T & C:\PROGRA~1\REACT2\tools\flac.exe -6 -f %Cover_tag% %VA_tag% %Disc_Flac_acdir% -T artist=$#a -T album=$#T -T title=$#t -T tracknumber=$n/$N -T date=$q1995$q -T genre=$qCeltic$q -T comment=$qCreated with EAC/REACT2, 2008-08-04$q -T encoded-by=$q%USERNAME%$q -T encoding=$qFlac 1.2.1 -6 -f$q - -o $#o" "C:\Music (EAC)\Etmp!58)5-react.cue"
IF %add_rg%==1 C:\PROGRA~1\REACT2\tools\Glob.exe -v -c C:\PROGRA~1\REACT2\tools\metaflac.exe %RG_MetaFlac% *.flac
COPY /Y "C:\Music (EAC)\Enya - The Memory Of Trees [1995].log" .
IF %have_cover%==1 COPY /Y "C:\Music (EAC)\The Memory Of Trees.jpg" "folder.jpg"
IF EXIST "C:\Music (EAC)\The Memory Of Trees.[*].cue" COPY /Y "C:\Music (EAC)\The Memory Of Trees.[*].cue" .
POPD
:end_flac_tracks
IF NOT 0==1 GOTO end_wavpack_tracks
SET dest="C:\Music (EAC)\WV\Enya [1995] The Memory Of Trees%trackDir%"
IF NOT EXIST %dest% MKDIR %dest%
PUSHD %dest%
IF 0==1 SET VA_tag=-w $qalbum artist=Various Artists$q
C:\PROGRA~1\REACT2\tools\acdir.exe --overwrite --output "%TrackName%.wv" --pipe "C:\PROGRA~1\REACT2\tools\wavpack.exe -hmy %RG_Wavpack_acdir% %VA_tag% %Disc_Wavpack_acdir% -w artist=$#a -w album=$#T -w title=$#t -w track=$n/$N -w year=$q1995$q -w genre=$qCeltic$q -w comment=$qCreated with EAC/REACT2, 2008-08-04$q -w encodedby=$q%USERNAME%$q -w encodersettings=$qWavpack 4.40 -hmy$q - $#o" "C:\Music (EAC)\Etmp!58)5-react.cue"
IF 1==1 IF 1==0 C:\PROGRA~1\REACT2\tools\wvgain.exe -a *.wv
COPY /Y "C:\Music (EAC)\Enya - The Memory Of Trees [1995].log" "EAClog.txt"
IF %have_cover%==1 COPY /Y "C:\Music (EAC)\The Memory Of Trees.jpg" "folder.jpg"
IF EXIST "C:\Music (EAC)\The Memory Of Trees.[*].cue" COPY /Y "C:\Music (EAC)\The Memory Of Trees.[*].cue" .
POPD
TITLE "The Memory Of Trees"
:end_wavpack_tracks
IF NOT 0==1 GOTO end_tak_tracks
SET dest="C:\Music (EAC)\TAK\Enya [1995] The Memory Of Trees%trackDir%"
IF NOT EXIST %dest% MKDIR %dest%
PUSHD %dest%
IF 0==1 SET VA_tag=-t $qalbum artist=Various Artists$q
C:\PROGRA~1\REACT2\tools\acdir.exe --overwrite --output "%TrackName%.wav" --extract "C:\Music (EAC)\Etmp!58)5-react.cue"
C:\PROGRA~1\REACT2\tools\acdir.exe --exec "C:\PROGRA~1\REACT2\tools\takc.exe -e -overwrite -pN -overwrite $q%TrackName%.wav$q $q%TrackName%.tak$q && C:\PROGRA~1\REACT2\tools\tag.exe %RG_Tak_acdir% %VA_tag% %Disc_Tak_acdir% -t artist=$#a -t album=$#T -t title=$#t -t track=$n/$N -t year=$q1995$q -t genre=$qCeltic$q -t comment=$qCreated with EAC/REACT2, 2008-08-04$q -t encodedby=$q%USERNAME%$q -t encodersettings=$qTAK 1.0.1 -pN -overwrite$q $q%TrackName%.tak$q && DEL $q%TrackName%.wav$q" "C:\Music (EAC)\Etmp!58)5-react.cue"
COPY /Y "C:\Music (EAC)\Enya - The Memory Of Trees [1995].log" "EAClog.txt"
IF %have_cover%==1 COPY /Y "C:\Music (EAC)\The Memory Of Trees.jpg" "folder.jpg"
IF EXIST "C:\Music (EAC)\The Memory Of Trees.[*].cue" COPY /Y "C:\Music (EAC)\The Memory Of Trees.[*].cue" .
POPD
:end_tak_tracks
IF NOT 1==1 GOTO end_lame_tracks
SET dest="C:\Music (EAC)\MP3\Enya - The Memory Of Trees [1995]%trackDir%"
IF NOT EXIST %dest% MKDIR %dest%
PUSHD %dest%
IF 0==1 SET VA_tag=--user-text $q[album artist]Various Artists$q --frame $qTPE2:Various Artists$q
IF %embed_cover%==1 SET Cover_tag=--pict $#x
C:\PROGRA~1\REACT2\tools\acdir.exe --overwrite --output "%TrackName%.mp3" --extra-opt "{3}C:\Music (EAC)\The Memory Of Trees.jpg" --pipe "TITLE $n/$N mp3 $#T & C:\PROGRA~1\REACT2\tools\lame.exe -V4 --vbr-new --noreplaygain --nohist %ApplyAG_Lame% - $#o & C:\PROGRA~1\REACT2\tools\metamp3.exe %Cover_tag% %VA_tag% %Disc_MP3_acdir% --artist $#a --album $#T --title $#t --track $n/$N --year $q1995$q --genre $qCeltic$q --comment $qCreated with EAC/REACT2, 2008-08-04$q --frame TENC:$q%USERNAME%$q --frame TSSE:$qLAME 3.98 -V4 --vbr-new --noreplaygain --nohist$q $#o" "C:\Music (EAC)\Etmp!58)5-react.cue"
IF %add_rg%==1 C:\PROGRA~1\REACT2\tools\metamp3.exe %RG_MetaMP3% *.mp3
IF 1==1 C:\PROGRA~1\REACT2\tools\metamp3.exe %ApplyAG_MetaMP3% *.mp3
COPY /Y "C:\Music (EAC)\Enya - The Memory Of Trees [1995].log" .
IF %have_cover%==1 COPY /Y "C:\Music (EAC)\The Memory Of Trees.jpg" "folder.jpg"
POPD
:end_lame_tracks
IF NOT 0==1 GOTO end_nero_aac_tracks
SET dest="C:\Music (EAC)\AAC\Enya [1995] The Memory Of Trees%trackDir%"
IF NOT EXIST %dest% MKDIR %dest%
PUSHD %dest%
IF 0==1 SET VA_tag=--albumArtist $qVarious Artists$q --compilation true
IF %embed_cover%==1 SET Cover_tag=--artwork $#x
C:\PROGRA~1\REACT2\tools\acdir.exe --overwrite --output "%TrackName%.m4a" --extra-opt "C:\Music (EAC)\The Memory Of Trees.jpg" --pipe "TITLE $n/$N aac $#T & C:\PROGRA~1\REACT2\tools\neroAacEnc.exe -lc -q 0.21 -ignorelength -if - -of $#o & C:\PROGRA~1\REACT2\tools\AtomicParsley.exe $#o -o REACT_tmp.m4a %Cover_tag% %VA_tag% %Disc_NeroAac_acdir% --artist $#a --album $#T --tracknum $n/$N --title $#t --year $q1995$q --genre $qCeltic$q --comment $qCreated with EAC/REACT2, 2008-08-04$q --encodingTool $qneroAacEnc 1.0.0.2 -lc -q 0.21$q & MOVE /Y REACT_tmp.m4a $#o" "C:\Music (EAC)\Etmp!58)5-react.cue"
IF 1==1 C:\PROGRA~1\REACT2\tools\aacgain.exe %ApplyAG_AacGain% *.m4a > gainlog.txt
REM COPY /Y "C:\Music (EAC)\Enya - The Memory Of Trees [1995].log" "EAClog.txt"
IF %have_cover%==1 COPY /Y "C:\Music (EAC)\The Memory Of Trees.jpg" "folder.jpg"
POPD
:end_nero_aac_tracks
IF NOT 1==1 GOTO end_oggenc_tracks
SET dest="C:\Music (EAC)\OGG\Enya - The Memory Of Trees [1995]%trackDir%"
IF NOT EXIST %dest% MKDIR %dest%
PUSHD %dest%
IF 0==1 SET VA_tag=-c $qalbum artist=Various Artists$q
C:\PROGRA~1\REACT2\tools\acdir.exe --overwrite --output "%TrackName%.ogg" --pipe "TITLE $n/$N ogg $#T & C:\PROGRA~1\REACT2\tools\oggenc2.exe -q 6.0 %RG_OggEnc2_acdir% %VA_tag% %Disc_OggEnc2_acdir% -c artist=$#a -c album=$#T -c title=$#t -c tracknumber=$n/$N -c date=$q1995$q -c genre=$qCeltic$q -c comment=$qCreated with EAC/REACT2, 2008-08-04$q -c encoded-by=$q%USERNAME%$q -c encoding=$qOggEnc 2.85 aoTuV b5.5 -q 6.0$q - -o $#o" "C:\Music (EAC)\Etmp!58)5-react.cue"
IF 1==1 IF 1==0 C:\PROGRA~1\REACT2\tools\vorbisgain.exe -a *.ogg
COPY /Y "C:\Music (EAC)\Enya - The Memory Of Trees [1995].log" .
IF %have_cover%==1 COPY /Y "C:\Music (EAC)\The Memory Of Trees.jpg" "folder.jpg"
POPD
:end_oggenc_tracks
REM ================ End Main Script ===================
IF 1==1 (
PAUSE
EXIT
)
REM ** Cleanup
DEL "C:\Music (EAC)\Etmp!58)5.wav"
DEL "C:\Music (EAC)\Enya - The Memory Of Trees [1995].log"
DEL "C:\Music (EAC)\Enya - The Memory Of Trees [1995].cue"
DEL "C:\Music (EAC)\The Memory Of Trees.[*].cue"
DEL "C:\Music (EAC)\The Memory Of Trees.jpg"
REM ** Delete this .bat file:
DEL %0
GOTO :EOF
REM Pause for 2000 milliseconds and return to :CheckForLog
:Pause
@ECHO Waiting for EAC log file...
PING 1.1.1.1 -n 1 -w 2000 >NUL
GOTO CheckForLog
-------------> EAC log file
REM REPLAYGAIN_ALBUM_GAIN -2.18 dB
REM REPLAYGAIN_ALBUM_PEAK 0.97723
REM REPLAYGAIN_ALBUM_SCALE 0.77804
Exact Audio Copy V0.99 prebeta 4 from 23. January 2008
EAC extraction logfile from 4. August 2008, 11:31
Enya / The Memory Of Trees
Used drive : MATSHITAUJDA765aDVD/CDRW Adapter: 0 ID: 1
Read mode : Secure
Utilize accurate stream : Yes
Defeat audio cache : No
Make use of C2 pointers : No
Read offset correction : 102
Overread into Lead-In and Lead-Out : No
Fill up missing offset samples with silence : Yes
Delete leading and trailing silent blocks : No
Null samples used in CRC calculations : No
Used interface : Native Win32 interface for Win NT & 2000
Used output format : User Defined Encoder
Selected bitrate : 1024 kBit/s
Quality : High
Add ID3 tag : No
Command line compressor : C:\Program Files\REACT2\REACT.exe
Additional command line options : REACT %o %s %d "%a" "%g" "%t" "%n" "%x" "%y" "%m" "%e" "%f" "%b" %r
Use compression offset : 0
TOC of the extracted CD
Track | Start | Length | Start sector | End sector
---------------------------------------------------------
1 | 0:00.00 | 4:19.70 | 0 | 19494
2 | 4:19.70 | 3:59.35 | 19495 | 37454
3 | 8:19.30 | 4:59.50 | 37455 | 59929
4 | 13:19.05 | 3:42.07 | 59930 | 76586
5 | 17:01.12 | 2:22.65 | 76587 | 87301
6 | 19:24.02 | 4:49.60 | 87302 | 109036
7 | 24:13.62 | 4:48.48 | 109037 | 130684
8 | 29:02.35 | 2:43.32 | 130685 | 142941
9 | 31:45.67 | 3:18.25 | 142942 | 157816
10 | 35:04.17 | 3:38.18 | 157817 | 174184
11 | 38:42.35 | 5:09.10 | 174185 | 197369
Range status and errors
Selected range
Filename C:\Music (EAC)\Enya - The Memory Of Trees [1995].wav
Peak level 97.7 %
Range quality 99.9 %
Copy CRC 10778AA6
Copy OK
No errors occurred
AccurateRip summary
Track 1 accurately ripped (confidence 144) [54BAC4DF]
Track 2 accurately ripped (confidence 149) [FA619840]
Track 3 accurately ripped (confidence 148) [0738ED88]
Track 4 accurately ripped (confidence 145) [3E31DA7D]
Track 5 accurately ripped (confidence 147) [0DA4164A]
Track 6 accurately ripped (confidence 148) [8D76585A]
Track 7 accurately ripped (confidence 146) [9BDD6555]
Track 8 accurately ripped (confidence 147) [B2FBF93B]
Track 9 accurately ripped (confidence 147) [7215C45E]
Track 10 accurately ripped (confidence 147) [A68A5E24]
Track 11 accurately ripped (confidence 146) [9E8E7206]
All tracks accurately ripped
End of status report
-------------------> REACT.ini
[Settings]
Version=2.0.ssb16
ImageExt=wav
ImageNaming=$artist$ - $album$ [$year$]
ImageHotKey={F10}
TracksHotKey={F4}
TracksHotVal=+{F5}
VA=Various Artists
CreateAllCuesheets=1
RunCoverDownloader=1
CoverDownloader=C:\Program Files\REACT2\coverdownloader\albumart.exe
CoverDownloaderXUI=1
EAC=C:\Program Files\Exact Audio Copy\EAC.exe
Tools=C:\Program Files\REACT2\tools
MinimizeCompressionWindow=1
ProcessPriority=1
Sla_Bks_Col_Qst_Bar_Quo_Ast_Lt_Gt=-|-|-||!|'|#|[|]
Test=0
[UserTrackFormats]
Flac=1
Wavpack=0
Tak=0
LameMP3=1
NeroAac=0
iTunesAac=0
OggEnc2=1
[UserOutputNames]
OutRoot=C:\Music (EAC)
ImageDir_Flac=@OutRoot@\FLAC-images\$cdartist$ - $album$ [$year]
ImageDir_Wavpack=@OutRoot@\WV-images\$cdartist$ [$year] $album$
ImageDir_Tak=@OutRoot@\TAK-images\$cdartist$ [$year] $album$
ImageDir_MP3=@OutRoot@\MP3-images\$cdartist$ [$year] $album$
TrackDir_Flac=@OutRoot@\FLAC\$cdartist$ - $album$ [$year$]
TrackDir_Wavpack=@OutRoot@\WV\$cdartist$ [$year$] $album$
TrackDir_Tak=@OutRoot@\TAK\$cdartist$ [$year$] $album$
TrackDir_MP3=@OutRoot@\MP3\$cdartist$ - $album$ [$year$]
TrackDir_AAC=@OutRoot@\AAC\$cdartist$ [$year$] $album$
TrackDir_OGG=@OutRoot@\OGG\$cdartist$ - $album$ [$year$]
TrackName_SA=$track$. $title$
TrackName_VA=$track$. $title$ [$artist$]
TrackName_SA_acdir=$n - $~t
TrackName_VA_acdir=$n - $~t [$~a]
[UserSettings]
Debug=1
Comment=Created with EAC/REACT2, @curdate@
EmbedCover=1
ReplayGain=1
ApplyAlbumGain=1
AdjustAlbumGain_dB=+3
AddCuesheetAG=1
UseWaveGainAG=1
Opt_Flac=-6 -f
Opt_Wavpack=-hmy
Opt_Tak=-pN -overwrite
Opt_LameMP3=-V4 --vbr-new --noreplaygain --nohist
Opt_NeroAac=-lc -q 0.21
Opt_iTunesAac=-d -s 2000
Opt_OggEnc2=-q 6.0
Ver_Flac=1.2.1
Ver_Wavpack=4.40
Ver_Tak=1.0.1
Ver_LameMP3=3.98
Ver_NeroAac=1.0.0.2
Ver_OggEnc2=2.85 aoTuV b5.5
[DefaultMetaData]
discnumber=1
totaldiscs=1
discname=
--------------> REACT-image.cfg
@ECHO OFF
CHCP 1252 | PROMPT
TITLE "@album@"
REM Copyright © Tycho, 2006
REM
REM ** Ripping to .wav image.
REM **
REM ** To archive a CD as one large "image", you must SET
REM ** ImageExt=... in the REACT.ini file (Press Alt-F2).
REM ** This will set the @ImageExt@ variable. Extensions
REM ** currently supported: flac, wv, mp3. Set to 'wav'
REM ** for no image archiving (default).
REM **
REM ** Also creates tracks by encoding directly to tracks, using ACDIR.
REM **
REM ** Flac requires flac.exe/metaflac.exe (v1.1.3)
REM ** NeroAac requires NeroAacEnc.exe/NeroAacTag.exe/AacGain.exe.
REM ** OggEnc2 requires OggEnc2.exe/VorbisGain.exe.
REM **
REM ** I prefer applying album gain 92dB to get a reasonable
REM ** volume for my DAP. The RG tags are still relative
REM ** to 89dB SPL, i.e. album gain will be about -3.0dB.
REM ============== Begin Main Script ==================
IF @Debug@==1 ECHO ON
IF @various@==0 SET TrackName=@TrackName_SA_acdir@
IF @various@==1 SET TrackName=@TrackName_VA_acdir@
SET add_rg=@ReplayGain@
SET have_cover=0
SET embed_cover=0
IF NOT @ReplayGain@==1 GOTO end_RG
SET RG_Flac=--replay-gain
SET RG_MetaFlac=--add-replay-gain
SET RG_MetaMP3=--replay-gain
:end_RG
IF NOT @ApplyAlbumGain@==1 GOTO end_apply_AG
SET ApplyAG_MetaMP3=--apply-gain album@AdjustAlbumGain_dB@
SET ApplyAG_AacGain=/a /o /c /d @AdjustAlbumGain_dB@
SET add_rg=1
:end_apply_AG
IF EXIST "@cover@" (
SET have_cover=1
SET embed_cover=@EmbedCover@
)
IF @various@==0 (
SET ArtistField=artist
SET MP3Artist=--artist "@artist@"
) else (
SET ArtistField=album artist
SET MP3Artist=--user-text "[album artist]@VA@" --frame "TPE2:@VA@"
)
REM ** Create Disc-related tags if we have a set
REM If a disc name has been provided
IF "@discname@" EQU "" GOTO end_discname
SET discName=discname
SET discName=@%discname%@
IF "@discname@" EQU "%discName%" GOTO end_discname
REM Set tagging switches
SET Disc_Flac=-T "discname=@discname@"
SET Disc_Wavpack=-w "discname=@discname@"
REM SET Disc_MP3=--frame TSST:"@discname@"
SET Disc_MP3=--frame "TXXX[setsubtitle]:@discname@"
SET Disc_OggEnc2=-c "discname=@discname@"
SET Disc_Tak=-t "discname=@discname@"
SET Disc_Flac_acdir=-T $qdiscname=@discname@$q
SET Disc_Wavpack_acdir=-w $qdiscname=@discname@$q
REM SET Disc_MP3_acdir=--frame TSST:$q@discname@$q
SET Disc_MP3_acdir=--frame $qTXXX[setsubtitle]:@discname@$q
SET Disc_OggEnc2_acdir=-c $qdiscname=@discname@$q
SET Disc_Tak_acdir=-t $qdiscname=@discname@$q
REM Add disc name to image and track folder paths
SET imageDir=%imageDir%\$discname$
SET trackDir=%trackDir%\$discname$
GOTO :end_discnumber
:end_discname
REM Ensure that we have numeric values
SET /A discNumber = @discnumber@ + 0
SET /A totalDiscs = @totaldiscs@ + 0
REM IF a valid disc number and total number of discs has been provided
IF %totalDiscs% LEQ 1 GOTO :end_discnumber
IF %discNumber% LEQ 0 GOTO :end_discnumber
REM Set tagging switches
SET Disc_Flac=-T "discnumber=@discnumber@" -T "totaldiscs=@totaldiscs@"
SET Disc_Wavpack=-w "discnumber=@discnumber@" -w "totaldiscs=@totaldiscs@"
SET Disc_MP3=--frame TPOS:"@discnumber@/@totaldiscs@"
SET Disc_NeroAac=--disk "@discnumber@/@totaldiscs@"
SET Disc_OggEnc2=-c "discnumber=@discnumber@" -c "totaldiscs=@totaldiscs@"
SET Disc_Tak=-t "discnumber=@discnumber@" -t "totaldiscs=@totaldiscs@"
SET Disc_Flac_acdir=-T $qdiscnumber=@discnumber@$q -T $qtotaldiscs=@totaldiscs@$q
SET Disc_Wavpack_acdir=-w $qdiscnumber=@discnumber@$q -w $qtotaldiscs=@totaldiscs@$q
SET Disc_MP3_acdir=--frame TPOS:$q@discnumber@/@totaldiscs@$q
SET Disc_NeroAac_acdir=--disk $q@discnumber@/@totaldiscs@$q
SET Disc_OggEnc2_acdir=-c $qdiscnumber=@discnumber@$q -c $qtotaldiscs=@totaldiscs@$q
SET Disc_Tak_acdir=-t $qdiscnumber=@discnumber@$q -t $qtotaldiscs=@totaldiscs@$q
REM Add disc number to image and track folder paths
SET imageDir=%imageDir%\Disc @discnumber@
SET trackDir=%trackDir%\Disc @discnumber@
:end_discnumber
SET run_wavegain=@UseWaveGainAG@
IF @AddCuesheetAG@==1 SET run_wavegain=1
IF %run_wavegain%==0 GOTO end_wavegain
SET wg_tmp=wg_%RANDOM%
@tools@\WaveGain.exe --album "@source@" --exec ECHO '%%ALBUM_GAIN%%'%%ALBUM_PEAK%%'%%ALBUM_NEW_PEAK%%'%%ALBUM_SCALE%%'> %wg_tmp%.txt
FOR /F "usebackq tokens=1-6 delims='" %%a IN (%wg_tmp%.txt) DO (
SET album_gain=%%b
SET album_peak=%%c
SET album_new_peak=%%d
SET album_scale=%%e
)
ECHO REM REPLAYGAIN_ALBUM_GAIN %album_gain% dB> %wg_tmp%.rg
ECHO REM REPLAYGAIN_ALBUM_PEAK %album_peak%>> %wg_tmp%.rg
ECHO REM REPLAYGAIN_ALBUM_SCALE %album_scale%>> %wg_tmp%.rg
REM DEL %wg_tmp%.txt
REM TYPE "@eaclog@" >> %wg_tmp%.rg
REM MOVE /Y %wg_tmp%.rg "@eaclog@"
:end_wavegain
REM ** Transfer RG values from Wavgain calculations, instead of recalculation.
IF @UseWaveGainAG@==1 IF %add_rg%==1 (
SET RG_Flac=-T "replaygain_album_gain=%album_gain% dB" -T "replaygain_album_peak=%album_peak%"
SET RG_MetaFlac=--set-tag="replaygain_album_gain=%album_gain% dB" --set-tag="replaygain_album_peak=%album_peak%"
SET RG_Wavpack=-w "replaygain_album_gain=%album_gain% dB" -w "replaygain_album_peak=%album_peak%"
SET RG_Wavpack_acdir=-w $qreplaygain_album_gain=%album_gain% dB$q -w $qreplaygain_album_peak=%album_peak%$q
SET RG_Tak=-t "replaygain_album_gain=%album_gain% dB" -t "replaygain_album_peak=%album_peak%"
SET RG_Tak_acdir=-t $qreplaygain_album_gain=%album_gain% dB$q -t $qreplaygain_album_peak=%album_peak%$q
SET RG_MetaMP3=--user-text "[replaygain_album_gain]%album_gain% dB" --user-text "[replaygain_album_peak]%album_peak%"
SET RG_OggEnc2_acdir=-c $qreplaygain_album_gain=%album_gain% dB$q -c $qreplaygain_album_peak=%album_peak%$q
)
REM ** Apply AlbumGain by using --scale <factor> computed from WaveGain. Only for MP3 and OGG.
IF @UseWaveGainAG@==1 IF @ApplyAlbumGain@==1 (
SET ApplyAG_Lame=--scale %album_scale%
SET ApplyAG_MetaMP3=--apply-gain @AdjustAlbumGain_dB@
SET RG_MetaMP3=--user-text "[replaygain_album_gain]0.0 dB" --user-text "[replaygain_album_peak]%album_new_peak%"
SET RG_OggEnc2_acdir=--scale %album_scale% -c $qreplaygain_album_gain=0.0 dB$q -c $qreplaygain_album_peak=%album_new_peak%$q
)
REM ---- Image ----
REM Ensure that the EAC log is available
:CheckForLog
IF NOT EXIST "@eaclog@" GOTO Pause
REM Add ReplayGain to front of log file
TYPE "@eaclog@" >> %wg_tmp%.rg
MOVE /Y %wg_tmp%.rg "@eaclog@"
IF NOT @ImageExt@==flac GOTO end_flac_image
SET dest="@ImageDir_Flac@%imageDir%"
IF NOT EXIST %dest% MKDIR %dest%
IF %embed_cover%==1 SET Cover_tag=--picture="|image/jpeg|||@cover@"
@tools@\flac.exe @Opt_Flac@ %RG_Flac% %Cover_tag% %Disc_Flac% -T "%ArtistField%=@cdartist@" -T album="@album@" -T totaltracks="@numtracks@" -T date="@year@" -T genre="@genre@" -T comment="@comment@" -T encoded-by="%USERNAME%" -T encoding="Flac @Ver_Flac@ @Opt_Flac@" --tag-from-file="cuesheet=@cuesheet@" --tag-from-file="eaclog=@eaclog@" "@source@" -o "@image@"
MOVE /Y "@image@" %dest%
MOVE /Y "@cuesheet@" %dest%
IF %have_cover%==1 COPY /Y "@cover@" %dest%\"@basename@.jpg"
:end_flac_image
IF NOT @ImageExt@==wv GOTO end_wavpack_image
SET dest="@ImageDir_Wavpack@%imageDir%"
IF NOT EXIST %dest% MKDIR %dest%
@tools@\wavpack.exe @Opt_Wavpack@ %RG_Wavpack% %Disc_Wavpack% -w "%ArtistField%=@cdartist@" -w album="@album@" -w totaltracks="@numtracks@" -w year="@year@" -w genre="@genre@" -w comment="@comment@" -w encodedby="%USERNAME%" -w encodersettings="Wavpack @Ver_Wavpack@ @Opt_Wavpack@" -w cuesheet="@@cuesheet@" -w eaclog="@@eaclog@" "@source@" "@image@"
IF @ReplayGain@==1 IF @UseWaveGainAG@==0 @tools@\wvgain.exe -a "@image@"
TITLE "@album@"
MOVE /Y "@image@" %dest%
MOVE /Y "@cuesheet@" %dest%
IF %have_cover%==1 COPY /Y "@cover@" %dest%\"@basename@.jpg"
:end_wavpack_image
IF NOT @ImageExt@==tak GOTO end_tak_image
SET dest="@ImageDir_Tak@%imageDir%"
IF NOT EXIST %dest% MKDIR %dest%
@tools@\takc.exe -e @Opt_Tak@ "@source@" "@image@"
@tools@\tag.exe %RG_Tak% %Disc_Tak% -t "%ArtistField%=@cdartist@" -t album="@album@" -t totaltracks="@numtracks@" -t year="@year@" -t genre="@genre@" -t comment="@comment@" -t encodedby="%USERNAME%" -t encodersettings="TAK @Ver_Tak@ @Opt_Tak@" -f cuesheet="@cuesheet@" -f eaclog="@eaclog@" "@image@"
MOVE /Y "@image@" %dest%
MOVE /Y "@cuesheet@" %dest%
IF %have_cover%==1 COPY /Y "@cover@" %dest%\"@basename@.jpg"
:end_tak_image
IF NOT @ImageExt@==mp3 GOTO end_lame_image
SET dest="@ImageDir_MP3@%imageDir%"
IF NOT EXIST %dest% MKDIR %dest%
IF %embed_cover%==1 SET Cover_tag=--pict "{3}@cover@"
@tools@\lame.exe @Opt_LameMP3@ %ApplyAG_Lame% "@source@" "@image@"
@tools@\metamp3.exe %RG_MetaMP3% %Cover_tag% %Disc_MP3% %MP3Artist% --album "@album@" --track @numtracks@ --year "@year@" --genre "@genre@" --comment "@comment@" --frame TENC:"%USERNAME%" --frame TSSE:"LAME @Ver_LameMP3@ @Opt_LameMP3@" "@image@"
IF @ApplyAlbumGain@==1 @tools@\metamp3.exe %ApplyAG_MetaMP3% "@image@"
MOVE /Y "@image@" %dest%
MOVE /Y "@cuesheet@" %dest%
IF %have_cover%==1 COPY /Y "@cover@" %dest%\"@basename@.jpg"
:end_lame_image
REM ---- Tracks ----
IF NOT @Flac@==1 GOTO end_flac_tracks
SET dest="@TrackDir_Flac@%trackDir%"
IF NOT EXIST %dest% MKDIR %dest%
PUSHD %dest%
IF @various@==1 SET VA_tag=-T $qalbum artist=@VA@$q
IF %embed_cover%==1 SET Cover_tag=--picture=$#x
@tools@\acdir.exe --overwrite --output "%TrackName%.flac" --extra-opt "|image/jpeg|||@cover@" --pipe "TITLE $n/$N flac $#T & @tools@\flac.exe @Opt_Flac@ %Cover_tag% %VA_tag% %Disc_Flac_acdir% -T artist=$#a -T album=$#T -T title=$#t -T tracknumber=$n/$N -T date=$q@year@$q -T genre=$q@genre@$q -T comment=$q@comment@$q -T encoded-by=$q%USERNAME%$q -T encoding=$qFlac @Ver_Flac@ @Opt_Flac@$q - -o $#o" "@sourcecuesheet@"
IF %add_rg%==1 @tools@\Glob.exe -v -c @tools@\metaflac.exe %RG_MetaFlac% *.flac
COPY /Y "@eaclog@" .
IF %have_cover%==1 COPY /Y "@cover@" "folder.jpg"
IF EXIST "@albumfile@.[*].cue" COPY /Y "@albumfile@.[*].cue" .
POPD
:end_flac_tracks
IF NOT @Wavpack@==1 GOTO end_wavpack_tracks
SET dest="@TrackDir_Wavpack@%trackDir%"
IF NOT EXIST %dest% MKDIR %dest%
PUSHD %dest%
IF @various@==1 SET VA_tag=-w $qalbum artist=@VA@$q
@tools@\acdir.exe --overwrite --output "%TrackName%.wv" --pipe "@tools@\wavpack.exe @Opt_Wavpack@ %RG_Wavpack_acdir% %VA_tag% %Disc_Wavpack_acdir% -w artist=$#a -w album=$#T -w title=$#t -w track=$n/$N -w year=$q@year@$q -w genre=$q@genre@$q -w comment=$q@comment@$q -w encodedby=$q%USERNAME%$q -w encodersettings=$qWavpack @Ver_Wavpack@ @Opt_Wavpack@$q - $#o" "@sourcecuesheet@"
IF @ReplayGain@==1 IF @UseWaveGainAG@==0 @tools@\wvgain.exe -a *.wv
COPY /Y "@eaclog@" "EAClog.txt"
IF %have_cover%==1 COPY /Y "@cover@" "folder.jpg"
IF EXIST "@albumfile@.[*].cue" COPY /Y "@albumfile@.[*].cue" .
POPD
TITLE "@album@"
:end_wavpack_tracks
IF NOT @Tak@==1 GOTO end_tak_tracks
SET dest="@TrackDir_Tak@%trackDir%"
IF NOT EXIST %dest% MKDIR %dest%
PUSHD %dest%
IF @various@==1 SET VA_tag=-t $qalbum artist=@VA@$q
@tools@\acdir.exe --overwrite --output "%TrackName%.wav" --extract "@sourcecuesheet@"
@tools@\acdir.exe --exec "@tools@\takc.exe -e -overwrite @Opt_Tak@ $q%TrackName%.wav$q $q%TrackName%.tak$q && @tools@\tag.exe %RG_Tak_acdir% %VA_tag% %Disc_Tak_acdir% -t artist=$#a -t album=$#T -t title=$#t -t track=$n/$N -t year=$q@year@$q -t genre=$q@genre@$q -t comment=$q@comment@$q -t encodedby=$q%USERNAME%$q -t encodersettings=$qTAK @Ver_Tak@ @Opt_Tak@$q $q%TrackName%.tak$q && DEL $q%TrackName%.wav$q" "@sourcecuesheet@"
COPY /Y "@eaclog@" "EAClog.txt"
IF %have_cover%==1 COPY /Y "@cover@" "folder.jpg"
IF EXIST "@albumfile@.[*].cue" COPY /Y "@albumfile@.[*].cue" .
POPD
:end_tak_tracks
IF NOT @LameMP3@==1 GOTO end_lame_tracks
SET dest="@TrackDir_MP3@%trackDir%"
IF NOT EXIST %dest% MKDIR %dest%
PUSHD %dest%
IF @various@==1 SET VA_tag=--user-text $q[album artist]@VA@$q --frame $qTPE2:@VA@$q
IF %embed_cover%==1 SET Cover_tag=--pict $#x
@tools@\acdir.exe --overwrite --output "%TrackName%.mp3" --extra-opt "{3}@cover@" --pipe "TITLE $n/$N mp3 $#T & @tools@\lame.exe @Opt_LameMP3@ %ApplyAG_Lame% - $#o & @tools@\metamp3.exe %Cover_tag% %VA_tag% %Disc_MP3_acdir% --artist $#a --album $#T --title $#t --track $n/$N --year $q@year@$q --genre $q@genre@$q --comment $q@comment@$q --frame TENC:$q%USERNAME%$q --frame TSSE:$qLAME @Ver_LameMP3@ @Opt_LameMP3@$q $#o" "@sourcecuesheet@"
IF %add_rg%==1 @tools@\metamp3.exe %RG_MetaMP3% *.mp3
IF @ApplyAlbumGain@==1 @tools@\metamp3.exe %ApplyAG_MetaMP3% *.mp3
COPY /Y "@eaclog@" .
IF %have_cover%==1 COPY /Y "@cover@" "folder.jpg"
POPD
:end_lame_tracks
IF NOT @NeroAac@==1 GOTO end_nero_aac_tracks
SET dest="@TrackDir_AAC@%trackDir%"
IF NOT EXIST %dest% MKDIR %dest%
PUSHD %dest%
IF @various@==1 SET VA_tag=--albumArtist $q@VA@$q --compilation true
IF %embed_cover%==1 SET Cover_tag=--artwork $#x
@tools@\acdir.exe --overwrite --output "%TrackName%.m4a" --extra-opt "@cover@" --pipe "TITLE $n/$N aac $#T & @tools@\neroAacEnc.exe @Opt_NeroAac@ -ignorelength -if - -of $#o & @tools@\AtomicParsley.exe $#o -o REACT_tmp.m4a %Cover_tag% %VA_tag% %Disc_NeroAac_acdir% --artist $#a --album $#T --tracknum $n/$N --title $#t --year $q@year@$q --genre $q@genre@$q --comment $q@comment@$q --encodingTool $qneroAacEnc @Ver_NeroAac@ @Opt_NeroAac@$q & MOVE /Y REACT_tmp.m4a $#o" "@sourcecuesheet@"
IF @ApplyAlbumGain@==1 @tools@\aacgain.exe %ApplyAG_AacGain% *.m4a > gainlog.txt
REM COPY /Y "@eaclog@" "EAClog.txt"
IF %have_cover%==1 COPY /Y "@cover@" "folder.jpg"
POPD
:end_nero_aac_tracks
IF NOT @OggEnc2@==1 GOTO end_oggenc_tracks
SET dest="@TrackDir_OGG@%trackDir%"
IF NOT EXIST %dest% MKDIR %dest%
PUSHD %dest%
IF @various@==1 SET VA_tag=-c $qalbum artist=@VA@$q
@tools@\acdir.exe --overwrite --output "%TrackName%.ogg" --pipe "TITLE $n/$N ogg $#T & @tools@\oggenc2.exe @Opt_OggEnc2@ %RG_OggEnc2_acdir% %VA_tag% %Disc_OggEnc2_acdir% -c artist=$#a -c album=$#T -c title=$#t -c tracknumber=$n/$N -c date=$q@year@$q -c genre=$q@genre@$q -c comment=$q@comment@$q -c encoded-by=$q%USERNAME%$q -c encoding=$qOggEnc @Ver_OggEnc2@ @Opt_OggEnc2@$q - -o $#o" "@sourcecuesheet@"
IF @ReplayGain@==1 IF @UseWaveGainAG@==0 @tools@\vorbisgain.exe -a *.ogg
COPY /Y "@eaclog@" .
IF %have_cover%==1 COPY /Y "@cover@" "folder.jpg"
POPD
:end_oggenc_tracks
REM ================ End Main Script ===================
IF @Debug@==1 (
PAUSE
EXIT
)
REM ** Cleanup
DEL "@source@"
DEL "@eaclog@"
DEL "@cuesheet@"
DEL "@albumfile@.[*].cue"
DEL "@cover@"
REM ** Delete this .bat file:
DEL %0
GOTO :EOF
REM Pause for 2000 milliseconds and return to :CheckForLog
:Pause
@ECHO Waiting for EAC log file...
PING 1.1.1.1 -n 1 -w 2000 >NUL
GOTO CheckForLog