I'm back, this time with a few changes, a nicer colour scheme, and some bugfixing etc.
http://toolplusplus.com/stuffs/foobar2000_toolehv2.1_1.jpg
This is it normally.
http://toolplusplus.com/stuffs/foobar2000_toolehv2.1_2.jpg
This is it when you mouseover the sidebar (which you need to create yourself =P ).
Download link? Download toolehv2.1
Track Info box code?
//%title%$char(10)$char(10)$char(10)
//$if(%_trackinfo_notrack%,No track,%artist%$char(10)Album: %album%)
//$char(10)$char(10)
//%__bitrate%kbps // %__samplerate%Hz
//$char(10)$char(10)$char(10)$char(10)
//Mode: %_trackinfo_mode%
//Track-info code by Neil K (not all original)
//COLOR CODES
//blue color that is used a LOT
$puts(color1,5454A9)
//grey color that is also used a LOT
$puts(color2,$rgb(150,150,150))
//green color for word 'Original' for tracks with %origartist%, %origalbum% or %origyear%
$puts(orig_color,$rgb(116,175,170))
//light blue color for %origartist% and %origalbum%
$puts(orig_color2,$rgb(155,180,197))
//scrolling path color
$puts(scroll_color,$rgb(160,160,160))
$if(%_trackinfo_nowplaying%,
//color for 'SONG INFO' if in now-playing mode
$puts(transition_color,$rgb(255,255,255)),
//color for 'SONG INFO' if in follow-cursor mode
$puts(transition_color,$rgb(170,0,0)))
//// END OF COLOR CODES
$if(%_trackinfo_notrack%,No track playing,
//'SONG INFO' transitions
$char(1)C$transition(>>>>>>,333333,888888) $transition(S O N G,888888,$get(transition_color)) $transition(X I N F O,$get(transition_color),888888) $transition(<<<<<<,888888,333333)
$char(10)
$if(%_isplaying%,
$ifgreater(%_time_elapsed_seconds%,240,'[scrobblered]',
$ifgreater(%_time_elapsed_seconds%,$div(%_time_total_seconds%,2),'[scrobblered]',)))
//ARTIST, TITLE, ALBUM info
$char(10)Artist:$char(10)$char(1)C$rgb(255,255,255)$caps2(%artist%)$char(10)$char(10)
Title:$char(10)$char(1)C$get(color2)$if(%_isplaying%,$if(%_ispaused%,-,+),)$rgb(255,255,255)$caps2($replace(%title%,'(',ffffff'(',')',')','[',ffffff'[',']',']'))$char(10)$char(10)
$if(%album%,Album:$char(10)$char(1)C$rgb(255,255,255)$caps2(%album%) $get(color2)[ '['%date%']']$char(10),)
//displays info if there is an %origartist%, %origalbum% or %origyear% tag
$if($or(%origartist%,%origalbum%,%origyear%),
$get(orig_color)Original:$char(10)
$get(orig_color2)[%origartist%$char(10)]
$get(orig_color2)$if2(%origalbum%,)
$get(color2)[ '['%origyear%']']$char(10),)
// PROGRESS BAR
$if(%_trackinfo_nowplaying%,
$char(10)
$char(1)C$puts(len,$muldiv(%_time_elapsed_seconds%,43,%_time_total_seconds%))
$transition($repeat(█,$get(len)),4C4C99,4C4C99)
$repeat(█,$sub(43,$get(len)))
$char(10),)
$char(1)R $get(color1)[%_time_elapsed% / ][%_length%$char(10)
//TIME
$get(color1)$if($stricmp(%__codec%,Windows Media Audio V7/V8),WMA,%__codec%) @ %__bitrate% kb/s / $puts(fsize,$div(%_filesize%,1048576).$num($div($mul($mod(%_filesize%,1048576),100),1048576),2) $get(anno)MB)
$get(color1)$get(fsize)$char(10)
]
//SCROLLING PATH
$if(%_trackinfo_nowplaying%,
$char(10)
$get(scroll_color)$puts(padding,$char(160)$char(160)•$char(160)$char(160))
$puts(size,34)
$puts(title,$replace(%_path%, ,$char(160)))
$ifgreater($len2($get(title)),$get(size),
// scroll text
$puts(title,$get(title)$get(padding))
$puts(start,$add(1,$mod( %_time_elapsed_seconds%,$len($get(title)))))
$puts(display,
$cut(
$substr($get(title)$get(title),
$get(start),
$add(
$get(start),
$get(size)
)
)
,$add($get(size),1))
)
$get(display)$ifgreater($len2($get(display)),$get(size),,$char(160)),
// normal display
$get(title)
),))
Now go enjoy self.
[span style=\'font-size:8pt;line-height:100%\']moderation: code was exceedingly wide. converted to [ codebox ][/span]