Skip to main content
Topic: A good mmpc foobar display config? (Read 57654 times) previous topic - next topic
0 Members and 1 Guest are viewing this topic.

A good mmpc foobar display config?

Reply #100
well, i just somehow deleted my entire config, which i have never backed up.


gah, time to build it all over from scratch, i suppose!

A good mmpc foobar display config?

Reply #101
alright, its remade

hopefully i got rid of all the bugs and such

so that i never lose this again, here's the code.

Code: [Select]
// Global
// CONFIGURATION ///////////////////////////////////////////

// Album Art
// Use $if and $fileexists if more locations need to be checked
$puts(path.albumart,$replace(%path%,%filename_ext%,folder.jpg))

// Additional info
// addinfo.show: delete the '1' to disable additional info
// addinfo.time: determines how long addinfo is shown
// timeinfo.show: change the '1' to '0' to disable the time codes displayed on the progress bar
$puts(addinfo.show,1)
$puts(addinfo.time,30)
$puts(timeinfo.show,1)

// Positions
// pos.horizon: y-position of the grey horizon gradient
// pos.shadow: increase to see more reflection of the cd-cover
// pos.artx: if changed, further changes will be necessary for text positioning
// pos.arty: change position of album art relative to horizon line
$puts(pos.horizon,$muldiv(%_height%,4,7))
$puts(pos.shadow,100)
$puts(pos.artx,$sub($div(%_width%,2),245))
$puts(pos.artx2,$sub($div(%_width%,2),278))
$puts(pos.arty,$sub($get(pos.horizon),352))

// Fonts
// font.a, font.b: used by addinfo for a) filling text, b) values
$puts(font.track,$font(Calibri,16,,255-255-255))
$puts(font.album,$font(Calibri,8,,255-255-255))
$puts(font.artist,$font(Calibri,12,,255-255-255))
$puts(font.a,$font(Calibri,12,,150-150-150))
$puts(font.b,$font(Calibri,12,,255-255-255))
$puts(font.c,$font(Calibri,9,,127-151-158))
$puts(font.d,$font(Calibri,7,,225-225-225))

// Progress bar
$puts(bar.height,7)
$puts(bar.color,50-50-50)

// END OF CONFIG ///////////////////////////////////////////

// Background
$drawrect(,,,,brushcolor-0-0-0 pencolor-null)
$imageabs(,$get(pos.horizon),/images/drakez/horizon.png,)
$imageabs2(%_width%,%_height%,0,150,%_width%,$get(pos.horizon),0,0,/images/drakez/walls/mountains.jpg,NOKEEPASPECT)

// PerTrack

// PerTrack
// Album Art
$if($fileexists($replace(%path%,%filename_ext%,folder.jpg)),
$imageabs2(490,454,0,0,590,$add(27,$get(pos.shadow)),$get(pos.artx),$add(406,$get(pos.arty)),/images/drakez/case.png,ROTATEFLIP-6)
$imageabs2(400,400,0,0,400,$add(-2,$get(pos.shadow)),$add(63,$get(pos.artx)),$add(406,27,$get(pos.arty)),$get(path.albumart),NOKEEPASPECT ROTATEFLIP-6)
$imageabs($get(pos.artx),$add($get(pos.shadow),263,$get(pos.arty)),/images/drakez/shadow.png,)

$imageabs2(490,454,0,0,490,490,$get(pos.artx),$get(pos.arty),/images/drakez/case.png,)
$imageabs2(400,400,0,0,400,400,$add(63,$get(pos.artx)),$add(27,$get(pos.arty)),$get(path.albumart),NOKEEPASPECT)
,
)
// PerSecond

// Pause Overlay
$if($fileexists($replace(%path%,%filename_ext%,folder.jpg)),
$if(%ispaused%,
$drawrect($add(63,$get(pos.artx)),$add(27,$get(pos.arty)),400,400,pencolor-0-0-0 alpha-150)
$alignabs($add(63,$get(pos.artx)),$add(27,$get(pos.arty)),400,400,center,middle)$font(Webdings,72,,255-255-255)';'
$drawrect($add(63,$get(pos.artx)),$add(405,27,$get(pos.arty)),400,$add(-2,$get(pos.shadow)),pencolor-0-0-0 alpha-150)
)
,
$if(%ispaused%,
$alignabs($add(50,$get(pos.artx)),$add(27,$get(pos.arty)),400,400,center,middle)$font(Webdings,72,,255-255-255)';'
$drawrect($add(63,$get(pos.artx)),$add(405,27,$get(pos.arty)),400,$add(-2,$get(pos.shadow)),pencolor-0-0-0 alpha-150)
)
)$font(Calibri,7,,255-255-255)

// Progress Bar
$ifgreater($muldiv(%playback_time_seconds%,%_width%,%length_seconds%),0,
$drawrect(0,$sub(%_height%,$mul($get(bar.height),3)),$muldiv(%playback_time_seconds%,%_width%,%length_seconds%),$get(bar.height),pencolor-null brushcolor-$get(bar.color))
,)

// Trackinfo
$if(%isplaying%,
$if($fileexists($replace(%path%,%filename_ext%,folder.jpg)),
$if($and($or($greater($get(addinfo.time),%playback_time_seconds%),$greater($get(addinfo.time),%playback_time_remaining_seconds%)),$get(addinfo.show)),

// Detailed
$alignabs($get(pos.artx2),$add($get(pos.arty),433),492,$sub(%_height%,$get(pos.horizon),$get(pos.shadow),140),right,top)
$get(font.album)[%album%]$char(10)
$alignabs($add($sub($get(pos.artx2),$div(%_width%,2)),12),$add($get(pos.horizon),$get(pos.shadow),60),556,$sub(%_height%,$get(pos.horizon),$get(pos.shadow),64),center,bottom)
$get(font.d)'0:00'
$alignabs($sub($add($get(pos.artx2),$div(%_width%,2)),12),$add($get(pos.horizon),$get(pos.shadow),60),556,$sub(%_height%,$get(pos.horizon),$get(pos.shadow),64),center,bottom)
[%length%]
$alignabs(80,$add($get(pos.horizon),$get(pos.shadow),-20),$sub(%_width%,160),$sub(%_height%,$get(pos.horizon),$get(pos.shadow),64),center,bottom)
$get(font.track)[%title%]$char(10)
$get(font.artist)[%artist%]
$char(10)$font(Arial,10,,0-0-0) $char(10)
$if(%last_played%,$get(font.a)Played $get(font.b)%play_count%$get(font.a) time'('s')'', 'last on $get(font.b)$substr(%last_played%,9,10) $select($substr(%last_played%,6,7),January,February,March,April,May,June,July,August,September,October,November,December) $substr(%last_played%,1,4)$get(font.a).$char(10))
$if(%playback_time_seconds%,$get(font.a) $if(%album%,From the album $get(font.b)%album%$get(font.a)))$if(%date%,', 'published in $get(font.b)%date%$get(font.a) )$if(%publisher%,by $get(font.b)%publisher%$get(font.a))
,
// Default
$alignabs($get(pos.artx2),$add($get(pos.arty),433),492,$sub(%_height%,$get(pos.horizon),$get(pos.shadow),140),right,top)
$get(font.album)[%album%]$char(10)
$alignabs($get(pos.artx2),$add($get(pos.horizon),$get(pos.shadow),-20),556,$sub(%_height%,$get(pos.horizon),$get(pos.shadow),64),center,bottom)
$get(font.track)[%title%]$char(10)
$get(font.artist)[%artist%]
)
,
$if($and($or($greater($get(addinfo.time),%playback_time_seconds%),$greater($get(addinfo.time),%playback_time_remaining_seconds%)),$get(addinfo.show)),

// Detailed
$alignabs($add($sub($get(pos.artx2),$div(%_width%,2)),12),$add($get(pos.horizon),$get(pos.shadow),60),556,$sub(%_height%,$get(pos.horizon),$get(pos.shadow),64),center,bottom)
$get(font.d)'0:00'
$alignabs($sub($add($get(pos.artx2),$div(%_width%,2)),12),$add($get(pos.horizon),$get(pos.shadow),60),556,$sub(%_height%,$get(pos.horizon),$get(pos.shadow),64),center,bottom)
[%length%]
$alignabs(80,$add($get(pos.horizon),$get(pos.shadow),-20),$sub(%_width%,160),$sub(%_height%,$get(pos.horizon),$get(pos.shadow),64),center,bottom)
$get(font.track)[%title%]$char(10)
$get(font.artist)[%album%]$char(10)
[%artist%]
$char(10)$font(Arial,10,,0-0-0) $char(10)
$if(%last_played%,$get(font.a)Played $get(font.b)%play_count%$get(font.a) time'('s')'', 'last on $get(font.b)$substr(%last_played%,9,10) $select($substr(%last_played%,6,7),January,February,March,April,May,June,July,August,September,October,November,December) $substr(%last_played%,1,4)$get(font.a).$char(10))
$if(%playback_time_seconds%,$get(font.a) $if(%album%,From the album $get(font.b)%album%$get(font.a)))$if(%date%,', 'published in $get(font.b)%date%$get(font.a) )$if(%publisher%,by $get(font.b)%publisher%$get(font.a))
,
// Default
$alignabs($get(pos.artx2),$add($get(pos.horizon),$get(pos.shadow),-150),556,$sub(%_height%,$get(pos.horizon),$get(pos.shadow),64),center,bottom)
$get(font.artist)[%artist%]
$get(font.c)' // '
$get(font.track)[%title%]
$get(font.c)' // '
$get(font.artist)[%album%]
)),)

//time codes
$if(%isplaying%,
$if($greater($get(timeinfo.show),0),$alignabs($add($sub($get(pos.artx2),$div(%_width%,2)),12),$add($get(pos.horizon),$get(pos.shadow),60),556,$sub(%_height%,$get(pos.horizon),$get(pos.shadow),64),center,bottom)
$get(font.d)'0:00',)
$alignabs($sub($add($get(pos.artx2),$div(%_width%,2)),12),$add($get(pos.horizon),$get(pos.shadow),60),556,$sub(%_height%,$get(pos.horizon),$get(pos.shadow),64),center,bottom)
[%length%]
$alignabs($add($sub($get(pos.artx2),$div(%_width%,2)),$muldiv(%playback_time_seconds%,%_width%,%length_seconds%),-11),$add($get(pos.horizon),$get(pos.shadow),51),556,$sub(%_height%,$get(pos.horizon),$get(pos.shadow),64),center,bottom)
$get(font.d)[%playback_time% ]
$alignabs($add($sub($get(pos.artx2),$div(%_width%,2)),$muldiv(%playback_time_seconds%,%_width%,%length_seconds%),13),$add($get(pos.horizon),$get(pos.shadow),51),556,$sub(%_height%,$get(pos.horizon),$get(pos.shadow),64),center,bottom)
$get(font.d)[ -%playback_time_remaining%],)

row height: 18
group rows: 2
group by: %album%
background: 70-70-70
item display:
Code: [Select]
$drawrect(145,,,,brushcolor-78-78-78 pencolor-null)
$drawrect(145,,,1,brushcolor-90-90-90 pencolor-null)
$drawrect(145,17,,1,brushcolor-60-60-60 pencolor-null)

$imageabs2(105,105,0,$add(-18,$mul(%_itemindex%,18)),,,5,0,images\shadcover.png,)
$if($fileexists($replace(%path%,%filename_ext%,folder.jpg)),
$if($greater(%_itemcount%,3),
$imageabs2($if($greater(10,%_itemcount%),$mul(%_itemcount%,15),135),$if($greater(10,%_itemcount%),$mul(%_itemcount%,15),135),0,$add(-19,$mul(%_itemindex%,18)),,,6,0,$replace(%path%,%filename_ext%,folder.jpg),)
,)
,)
$font(Calibri,9,,234-238-246)
$puts(text,[%title%])
$puts(charWidth,$div($calcwidth($get(text)),$len($get(text))))
$puts(width,$sub(%_width%,210))
$if(%_selected%,$drawrect(145,,$sub(%_width%,145),,brushcolor-100-100-100 pencolor-60-124-188),)
$if(%isplaying%,$drawrect(145,,$sub(%_width%,145),,brushcolor-100-100-100 pencolor-100-164-228)$drawrect(146,1,$add(1,$div($mul($sub(%_width%,146),%_time_elapsed_seconds%),%length_seconds%)),16,brushcolor-127-151-158 pencolor-null),)


$if($strcmp(%album artist%,%artist%),
$alignabs(149,0,$sub(%_width%,149),16,left,middle)$if(%isplaying%,$font(Calibri,9,,234-238-246),$font(Calibri,9,,134-138-146))[%track%.  ]$if(%isplaying%,$font(Calibri,9,,234-238-246),$font(Calibri,9,,154-158-166))$ifgreater($calcwidth($get(text)),$get(width),
$cut($get(text),$sub($div($get(width),$get(charWidth)),3))'...'
,$get(text)),
$alignabs(149,0,$sub(%_width%,149),16,left,middle)$if(%isplaying%,$font(Calibri,9,,234-238-246),$font(Calibri,9,,134-138-146))[%track%.  ]$if(%isplaying%,$font(Calibri,9,,234-238-246),$font(Calibri,9,,154-158-166))%title%  - %artist%)

$if(%isplaying%,
$alignabs(349,0,$sub(%_width%,353),16,right,top)$if(%isplaying%,$font(Calibri,9,,234-238-246),$font(Calibri,9,,134-138-146))%playback_time%' / '%length%,
$alignabs(349,0,$sub(%_width%,353),16,right,top)$if(%isplaying%,$font(Calibri,9,,234-238-246),$font(Calibri,9,,134-138-146))%length%))

group display:
Code: [Select]
$font(Calibri,18,bold,124-128-126)
$puts(text,[%album%])
$puts(textwidth,$calcwidth($get(text)))
$puts(textlength,$len($get(text)))
$puts(charWidth,$div($get(textwidth),$get(textlength)))
$font(Calibri,16,uppercase,104-108-116)
$puts(artisa,[%artist%])
$puts(artisttextwidth,$calcwidth($get(artisa)))
$puts(artisalength,$len($get(artisa)))
$puts(archarWidth,$div($get(artisttextwidth),$get(artisalength)))
$puts(totaltextwidth,$add($get(textwidth),$get(artisttextwidth)))
$puts(width,$if($greater(%_width%,300),$sub(%_width%,300),0))


$drawrect(,,,,brushcolor-70-70-70 pencolor-null)
$drawrect(,1,,1,brushcolor-90-90-90 pencolor-null)
$drawrect(,2,,1,brushcolor-80-80-80 pencolor-null)
$drawrect(,34,,1,brushcolor-60-60-60 pencolor-null)
$drawrect(,35,,1,brushcolor-50-50-50 pencolor-null)
$align(left,)
$font(Calibri,18,bold,124-128-126)
'  '$ifgreater($get(textwidth),$get(width),
$cut($get(text),$sub($div($get(width),$get(charWidth)),$div($get(artisttextwidth),$get(archarWidth))))'...'
,$get(text))
$font(Calibri,14,,127-151-158)' // '
$font(Calibri,16,uppercase,104-108-116)[%artist% ]
$align(right,middle)
$font(Calibri,8,,104-108-116)
[%genre% ]['['%date%']'', ']
$font(Calibri,7,,94-98-106)
[%__codec% ][%__tool% ][%__codec_profile% / ][%bitrate%Kbps][ / RG: %__replaygain_album_gain%][Source: $meta(SOURCE)]
$char(10)
$drawrect(20,29,$sub(%_width%,40),1,brushcolor-50-50-58 pencolor-null)


A good mmpc foobar display config?

Reply #103

alright, its remade

hopefully i got rid of all the bugs and such

so that i never lose this again, here's the code.

[a lot of code]


I want to see screenshots!

same as this:


slight updates:

made album art smaller
added background image

and also this:
alright, here's my essentially complete config:

now playing window:


scpl:



a lot of the code handles what to do if there's no album art. all it does is move the infotext up to a more central location, and display it as "artist // trackname // album", removes the pauseoverlay when there's no album art, etc.

A good mmpc foobar display config?

Reply #104
Drake,

I'm using your trackinfomod and SCPL code from above and was wondering if I could get your images from your most recent update. I'm using your trackinfomod from the second page of this thread and the aspect ratio doesn't seem right, and my album art gets cut off. The SCPL code works and looks excellent... thanks a lot for the code.

A good mmpc foobar display config?

Reply #105
A bit OT. You're all using album art. Is there a way to get album art (half)automatically?

A good mmpc foobar display config?

Reply #106
A bit OT. You're all using album art. Is there a way to get album art (half)automatically?

Yeah use iTunes heh... It downloads album art in .itc files (which are actually just a wrapped jpg). Use jpgextractor to get the jpg.
Can't wait for a HD-AAC encoder :P

A good mmpc foobar display config?

Reply #107
My single column config :

row height: 25
group rows: 1
group by: %album%
background: 235-235-235

item display:
Code: [Select]
$if($strcmp($mod(%_playlist_number%,2),1),
$drawrect(,,,,brushcolor-245-245-245 pencolor-null))

$ifgreater(%_itemcount%,5,
$imageabs2(142,142,0,$add(-3,$mul(%_itemindex%,25)),,,2,0,C:\Program Files\foobar2000\images\albumborder.png,NOKEEPASPECT)
$imageabs2(142,142,0,$add(-3,$mul(%_itemindex%,25)),,,2,0,$replace(%path%,%filename_ext%,*cover*.*),NOKEEPASPECT)
$imageabs2(142,142,0,$add(-3,$mul(%_itemindex%,25)),,,2,0,$replace(%path%,%filename_ext%,*front*.*),NOKEEPASPECT)
$imageabs2(142,142,0,$add(-3,$mul(%_itemindex%,25)),,,2,0,$replace(%path%,%filename_ext%,folder.*),NOKEEPASPECT)
$if(%_selected%,$drawrect(146,,,,brushcolor- 212-212-212 pencolor-null),)
$alignabs(146,0,%_width%,%_height%,,)$font(calibri bold,9,,26-51-138)
$if(%isplaying%,$font(calibri bold,9,,255-0-128))
$replace([ %tracknumber%  - ][%title%],'(',$font(,,bold italic,20-40-120)'(')
$if(%isplaying%,$font(calibri bold,9,,255-0-128))
$alignabs(146,14,%_width%,%_height%,,)$font(CubicFive10,6,nocleartype,26-51-138)
$if(%isplaying%,$font(,7,,255-0-128)%playback_time% - )
    [%length% |   ][%bitrate% kbps |   ][%codec%]
$alignabs(0,10,$sub(%_width%,2),%_height%,right,)
$font(Wingdings,9,glow-190-190-190 glowexpand-1,250-250-250)
$repeat(«,%rating%)
,
$imageabs2($add(22,$mul(24,%_itemcount%)),$add(22,$mul(24,%_itemcount%)),0,$add(-3,$mul(%_itemindex%,25)),,,2,0,C:\Program Files\foobar2000\images\albumborder.png,NOKEEPASPECT)
$imageabs2($add(22,$mul(24,%_itemcount%)),$add(22,$mul(24,%_itemcount%)),0,$add(-3,$mul(%_itemindex%,25)),,,2,0,$replace(%path%,%filename_ext%,*cover*.*),NOKEEPASPECT)
$imageabs2($add(22,$mul(24,%_itemcount%)),$add(22,$mul(24,%_itemcount%)),0,$add(-3,$mul(%_itemindex%,25)),,,2,0,$replace(%path%,%filename_ext%,*front*.*),NOKEEPASPECT)
$imageabs2($add(22,$mul(24,%_itemcount%)),$add(22,$mul(24,%_itemcount%)),0,$add(-3,$mul(%_itemindex%,25)),,,2,0,$replace(%path%,%filename_ext%,folder.*),NOKEEPASPECT)
$if(%_selected%,$drawrect($add(22,$mul(24,%_itemcount%)),,,,brushcolor- 212-212-212 pencolor-null),)
$alignabs($add(26,$mul(24,%_itemcount%)),0,%_width%,%_height%,,)$font(calibri bold,9,,26-51-138)
$if(%isplaying%,$font(calibri bold,9,,255-0-128))
$replace([ %tracknumber%  - ][%title%],'(',$font(,,bold italic,20-40-120)'(')
$if(%isplaying%,$font(calibri bold,9,,255-0-128))
$alignabs($add(26,$mul(24,%_itemcount%)),14,%_width%,%_height%,,)$font(CubicFive10,6,nocleartype,26-51-138)
$if(%isplaying%,$font(,7,,255-0-128)%playback_time% - )
    [%length% |   ][%bitrate% kbps |   ][%codec%]
$alignabs(0,10,$sub(%_width%,2),%_height%,right,)
$font(Wingdings,9,glow-190-190-190 glowexpand-1,250-250-250)
$repeat(«,%rating%)
)


group display:
Code: [Select]
$padding(1,0)
$drawrect(,,,,brushcolor-230-230-230 pencolor-51-191-238)$padding(4,1)
$align(right,center)$font(,,bold,0-0-0)
%artist%
$puts(ar_w,$calcwidth(%artist%))
$drawrect($sub(%_width%,$get(ar_w),18),-1,3,%_height%,brushcolor-51-191-238 pencolor-null)
$drawrect($sub(%_width%,$get(ar_w),17),-1,1,%_height%,brushcolor-250-250-250 pencolor-null)



$ifgreater(%_itemcount%,5,
$imageabs2(142,142,,$add(0,$mul(%_itemindex%,29)),,,2,2,C:\Program Files\foobar2000\images\albumborder.png,NOKEEPASPECT)
$imageabs2(142,142,,$add(0,$mul(%_itemindex%,29)),,,2,2,$replace(%path%,%filename_ext%,*cover*.*),NOKEEPASPECT)
$imageabs2(142,142,,$add(0,$mul(%_itemindex%,29)),,,2,2,$replace(%path%,%filename_ext%,*front*.*),NOKEEPASPECT)
$imageabs2(142,142,,$add(0,$mul(%_itemindex%,29)),,,2,2,$replace(%path%,%filename_ext%,folder.*),NOKEEPASPECT)
$alignabs(146,0,%_width%,%_height%,,)$font(calibri bold,9,,255-255-255)
$font(,,bold glow-18-173-224 glowexpand-1,)
%album%
$alignabs(146,14,%_width%,%_height%,,)$font(CubicFive12,6,nocleartype,18-173-224)
[%date% | ][%genre%]
$drawrect(138,-1,3,%_height%,brushcolor-51-191-238 pencolor-null)
$drawrect(139,-1,1,%_height%,brushcolor-250-250-250 pencolor-null)
,
$imageabs2($add(22,$mul(24,%_itemcount%)),$add(22,$mul(24,%_itemcount%)),,$add(0,$mul(%_itemindex%,29)),,,2,2,C:\Program Files\foobar2000\images\albumborder.png,NOKEEPASPECT)
$imageabs2($add(22,$mul(24,%_itemcount%)),$add(22,$mul(24,%_itemcount%)),,$add(0,$mul(%_itemindex%,29)),,,2,2,$replace(%path%,%filename_ext%,*cover*.*),NOKEEPASPECT)
$imageabs2($add(22,$mul(24,%_itemcount%)),$add(22,$mul(24,%_itemcount%)),,$add(0,$mul(%_itemindex%,29)),,,2,2,$replace(%path%,%filename_ext%,*front*.*),NOKEEPASPECT)
$imageabs2($add(22,$mul(24,%_itemcount%)),$add(22,$mul(24,%_itemcount%)),,$add(0,$mul(%_itemindex%,29)),,,2,2,$replace(%path%,%filename_ext%,folder.*),NOKEEPASPECT)
$alignabs($add(26,$mul(24,%_itemcount%)),0,%_width%,%_height%,,)$font(calibri bold,9,,255-255-255)
$font($add(26,$mul(24,%_itemcount%)),,bold glow-18-173-224 glowexpand-1,)
%album%
$alignabs($add(26,$mul(24,%_itemcount%)),14,%_width%,%_height%,,)$font(CubicFive12,6,nocleartype,18-173-224)
[%date% | ][%genre%]
$drawrect($add(18,$mul(24,%_itemcount%)),-1,3,%_height%,brushcolor-51-191-238 pencolor-null)
$drawrect($add(19,$mul(24,%_itemcount%)),-1,1,%_height%,brushcolor-250-250-250 pencolor-null)
)



This code adapt cover about number of track,
exemple : a small cover picture when just one track
a stronger for two ...

A good mmpc foobar display config?

Reply #108
I'm kind of determined to get this to work but, it's not. 

If it matters my music is arranged by G:/My Music/Arist Name/[Year] Album Title/Music Files+folder.jpg/.png/.gif

Artist Pictures are from directory: G:/My Music/Art/artist name.jpg
And still aren't showing up.

And the album art is in that folder. Was wondering if I could use about the same thing as in my Album Art panel:
Code: [Select]
[foo_uie_albumart]
$replace(%path%,%filename_ext%,)folder.jpg
-$replace(%path%,%filename_ext%,)folder.png
-$replace(%path%,%filename_ext%,)folder.gif
--components\default.*
-$replace(%_path%,%_filename_ext%,)*.png
-$replace(%_path%,%_filename_ext%,)*.jpg
-$replace(%_path%,%_filename_ext%,)*.bmp
-$replace(%_path%,%_filename_ext%,)*.gif
-components\*$rand(10).png
[End]


So, help? Pretty please.

Here's me code:
Code: [Select]
// Global
$puts(path.library,'G:\My Music')
$puts(art.h,$sub(%_height%,351))
$puts(pos.x1,71)
$puts(pos.y1,$add(-134,$get(art.h)))
$puts(pos.y2,86)
// - Fonts used for additional info
$puts(font.a,$font(Gentium,20,glow-19-19-19 glowexpand-1 glowblur-8,160-160-160))
$puts(font.b,$font(Gentium,20,bold glow-19-19-19 glowexpand-1 glowblur-8,220-210-210))

// Background
$drawrect(,,,,brushcolor-19-19-19 pencolor-null)


// PerTrack
// Artist photo
$if(%isplaying%,$if($fileexists(G:\My Music\Art\%artist%.jpg),$imageabs2(1280,671,0,0,1280,671,0,0,M:\Art\%artist%.jpg,nokeepaspect),$imageabs2(1280,671,0,0,1280,671,0,0,M:\Art\%genre%.jpg,nokeepaspect)),)
$if(%isplaying%,$imageabs2(1280,672,0,0,1280,672,0,0,images\htpc1\artist-overlay2.png,nokeepaspect),)

// Album art
$imageabs($get(pos.x1),$get(pos.y1),images\htpc1\cd.png,)
$imageabs($get(pos.x1),$get(pos.y1),images\htpc1\case.png,)
$if($fileexists($replace(%path%,$if(%disc%,$directory(%path%,1)\)%filename_ext%,)folder.jpg),
$imageabs2(300,300,0,0,300,300,$add(44,$get(pos.x1)),$add(18,$get(pos.y1)),$replace(%path%,$if(%disc%,$directory(%path%,1)\)%filename_ext%,)folder.jpg,nokeepaspect),
)
$imageabs($get(pos.x1),$get(pos.y1),images\htpc1\gloss.png,)
$if(%disc%,$imageabs($get(pos.x1),$get(pos.y1),images\htpc1\2cd.png,))

// Title - Artist
$alignabs($add($get(pos.x1),500),$add($get(pos.y1),136),$sub(%_width%,$get(pos.x1),500,82),200,right,middle)
$font(Gentium,36,glow-100-100-100 glowblur-38 glowexpand-1,205-191-171)
[%title%]$char(10)
$font(Gentium,24,glow-80-80-80 glowblur-20 glowexpand-1,190-175-155)
[%artist%]

// PerSecond
// Progress bar
$ifgreater(%playback_time_seconds%,0,
$drawrect(0,$sub(%_height%,$get(pos.y2)),$add(23,$muldiv(%playback_time_seconds%,%_width%,%length_seconds%)),4,pencolor-null brushcolor-0-128-255)
$imageabs($muldiv(%playback_time_seconds%,%_width%,%length_seconds%),$sub(%_height%,$get(pos.y2)),images\htpc1\progress2.png,)
,)
$alignabs($add($get(pos.x1),566),$add($get(pos.y1),323),$sub(%_width%,$get(pos.x1),500,82),200,right,middle)
$font(Segoe UI,14,glow-100-100-100 glowblur-38 glowexpand-1,205-191-171)
$if($greater(6,%playback_time_remaining_seconds%),$if(%isplaying%,Crossfading$char(10),),[-%_time_remaining%]$char(10))

// Additional info
$if($or($greater(30,%playback_time_seconds%),$greater(30,%playback_time_remaining_seconds%)),
$alignabs($sub(%_width%,$get(pos.x1),500),$add($get(pos.y1),-100),500,200,right,bottom)
$if(%playback_time_seconds%,$get(font.a)From $if(%date%,the $get(font.b)%date%$get(font.a) )$if(%album%,album $get(font.b)%album%$get(font.a)).)
)

// Pause overlay
$if(%ispaused%,
$drawrect($add(44,$get(pos.x1)),$add(18,$get(pos.y1)),300,300,pencolor-0-0-0 alpha-150)
$alignabs($add(44,$get(pos.x1)),$add(18,$get(pos.y1)),300,300,center,middle)$font(Webdings,72,,255-255-255)';'
)
Lighten up, it's just foobar.

A good mmpc foobar display config?

Reply #109
$if($fileexists($replace(%path%,%filename_ext%,folder.jpg)),
$imageabs2(300,300,0,0,300,300,$add(44,$get(pos.x1)),$add(18,$get(pos.y1)),$replace(%path%,%filename_ext%,folder.jpg),nokeepaspect)
,
$if($fileexists($replace(%path%,%filename_ext%,folder.png)),
$imageabs2(300,300,0,0,300,300,$add(44,$get(pos.x1)),$add(18,$get(pos.y1)),$replace(%path%,%filename_ext%,folder.png),nokeepaspect)
,
$if($fileexists($replace(%path%,%filename_ext%,folder.gif)),
$imageabs2(300,300,0,0,300,300,$add(44,$get(pos.x1)),$add(18,$get(pos.y1)),$replace(%path%,%filename_ext%,folder.gif),nokeepaspect)
,
)))


any new place you want to check, just copy/paste 3 of those lines (text, text, comma) and paste them at the end, then change folder.jpg or whatever to the new item you want to check for, then add an ending parentheses to where there are already 3.

that could probably be simplified with if3, but im more comfortable with standard if commands.

Drake,

I'm using your trackinfomod and SCPL code from above and was wondering if I could get your images from your most recent update. I'm using your trackinfomod from the second page of this thread and the aspect ratio doesn't seem right, and my album art gets cut off. The SCPL code works and looks excellent... thanks a lot for the code.
[a href=\"http://img468.imageshack.us/my.php?image=foobarkb1.jpg\" target=\"_blank\"]

A good mmpc foobar display config?

Reply #110
i'm tweaking a bit the fantastic code of ojdo and i will like ask something:
in my old fb2k config i use this code (don't remember who, i think it was spex04) for a track info mod.

Code: [Select]
$puts(str1,"%title%"[ by %artist%][ / %album%][ '('%genre%[, %date%]')'])
$puts(str2,$upper($replace(%filename_ext%,%filename%.,)) $if(%__bitrate_nominal%,VBR '('%__bitrate%kbps average')' at %bitrate%kbps,[%codec_profile% $if($or($strstr(%codec_profile%,VBR),$strstr(%codec_profile%,ABR)),'('%__bitrate%kbps average')' )]at %bitrate%kbps)',' %samplerate%Hz / $cwb_splitnum($div($muldiv(%filesize%,1000,1024),1000),',')kb)
$puts(str3,$if(%play_count%,Played: %play_count% time$if($stricmp(%play_count%,1),,s),Never Played)$if(%last_played%,$puts(lpdiff,$cwb_datediff(%last_played%,%cwb_systemdatetime%))',' Last Played: $ifgreater(1,$get(lpdiff),Today,$ifgreater(2,$get(lpdiff),Yesterday,$get(lpdiff) days ago '('$num($substr(%last_played%,9,10),1)-$num($substr(%last_played%,6,7),1)-$substr(%last_played%,1,4)')')),)$if(%first_played%,$puts(fpm,$substr(%first_played%,9,10)) / First Played: $num($get(fpm),1)$ifgreater(2,$get(fpm),st,$ifgreater(3,$get(fpm),nd,$ifgreater(4,$get(fpm),rd,th))) of $select($substr(%first_played%,6,7),January,February,March,April,May,June,July,Auguest,September,October,November,December)',' $substr(%first_played%,1,4)))
$puts(panelbg,245-245-245)
$puts(imagedir,'C:\Archivos de programa\foobar2000\images\')

// background
$drawrect(,,,,brushcolor-$get(panelbg) pencolor-null)
$imageabs2(,,,,,,0,3,$get(imagedir)trackinfo1.png,)

// audioscrobbler
$if($or($greater($muldiv(%playback_time_seconds%,100,%length_seconds%),49),$greater(%playback_time_seconds%,239)),$imageabs2(,,,,,,$sub(%_width%,88),3,$get(imagedir)as.png,))

// curved edges
$drawrect(0,3,1,1,brushcolor-$get(panelbg) pencolor-null)
$drawrect($sub(%_width%,1),3,1,1,brushcolor-$get(panelbg) pencolor-null)
$drawrect(0,57,1,1,brushcolor-$get(panelbg) pencolor-null)
$drawrect($sub(%_width%,1),57,1,1,brushcolor-$get(panelbg) pencolor-null)

$if(%isplaying%,

// progress bar
$drawrect($muldiv(%_width%,15,100),41,$muldiv(%_width%,70,100),9,brushcolor-null pencolor-240-240-240)
$drawrect($add($muldiv(%_width%,15,100),2),43,$ifgreater($muldiv($sub($muldiv(%_width%,70,100),4),%playback_time_seconds%,%length_seconds%),0,$muldiv($sub($muldiv(%_width%,70,100),4),%playback_time_seconds%,%length_seconds%),1),5,brushcolor-240-240-240 pencolor-null)
$alignabs($sub($muldiv(%_width%,15,100),35),38,35,14,center,middle)$font(calibri,8,bold,240-240-240)$if2(%playback_time%,0:00)
$alignabs($muldiv(%_width%,85,100),38,35,14,center,middle)$font(calibri,8,bold,240-240-240)$if2(%length%,0:00)
$alignabs(20,9,$sub(%_width%,40),14,center,middle)$font(calibri,9,bold,240-240-240)

// interchanging text
$select($add($mod(%playback_time_seconds%,15),1),
$get(str1),$get(str1),$get(str1),$get(str1),$get(str1),
$get(str2),$get(str2),$get(str2),$get(str2),$get(str2),
$get(str3),$get(str3),$get(str3),$get(str3),$get(str3))

// autorating system
$if(%rating%,$puts(rating,%rating%),$puts(rating,$sub(%play_counter%,$div($cwb_datediff(%cwb_systemdatetime%,%first_played%),28))))
$if($greater($get(rating),5),$puts(rating,5))
$if($greater(0,$get(rating)),$puts(rating,0))
$imageabs2(,,,,,,$div($sub(%_width%,58),2),26,$get(imagedir)r$get(rating).png,)

// properties & open dir
$button($sub(%_width%,15),26,0,0,9,9,$get(imagedir)info.png,$get(imagedir)infoh.png,properties,)
$button(6,26,0,0,9,9,$get(imagedir)dir.png,$get(imagedir)dirh.png,open directory,)

,

// not playing..
$alignabs($div($sub(%_width%,50),2),6,50,48,center,middle)
$font(wingdings,25,bold,230-230-230)v

)


i really like how it shows the never played, last played, first played ... etc...

and my question is simple, i think:

can someone help me to edit the ojdo code (in particular) when it shows the playback statistic?

thanks in advance...sorry my english
more or less, minus is best

A good mmpc foobar display config?

Reply #111
Hey drake, where can i get the code of your beautifull foobar, and maybe the images too? i can't find any release of your config...
Chaintech AV-710 Wolfson DAC - Carver CM1065 - JBL LX770

A good mmpc foobar display config?

Reply #112
thanks guys for posting all this code - its really starting to coe together for me.

anyway, I have a seperate layout preset as my Now Playing screen (i assume whats what you do).  whats the easiest way to switch from my broswer view to my now palying view.  for some reason when i enter the now playing view, all keyboard commands stop working.  any help?

nevermind i got something working

A good mmpc foobar display config?

Reply #113
Wow this post has grown since i last checked it, please consider me a noob(if it wasn't already obvious)when its comes to foobar configs so go easy on me :-).

I love the look of ojdo foobar

http://www.hydrogenaudio.org/forums/index....st&p=467427

Could someone please tell me what plugins i would need and maybe if someone could supply a foobar config file i could just import.

Thanks for any info/tips.

A good mmpc foobar display config?

Reply #114
Hey drake, where can i get the code of your beautifull foobar, and maybe the images too? i can't find any release of your config...

it should all be in my post at the top of the screen ( http://www.hydrogenaudio.org/forums/index....st&p=469791 )

the background image is here: http://www.pixelgirlpresents.com/images/de...adual_right.jpg

if you need anything more, just ask me

A good mmpc foobar display config?

Reply #115
I don't know if anyone is still interested in fullscreen track display codes. I still use them in combination with Columns UI. Here is the config I use ATM (yes, quite some inspirations are taken from other board members' contributions):
htpc6

Features
  • works without any additional pictures (apart from album and artist art)
  • uses font BigNoodle Titling, available at dafont.com
  • progress bar around album art
  • works well with resolutions of 1280x1024 and above (smaller screens need manual adjustments in font size and positions)
Preview


Additional info + artist art is shown only at beginning and end of track


Bars show %rating% (orange) and %mood% (green)


How it looks in the middle of a track

The Code

Paste this in the code box of a panels_ui track display panel:
Code: [Select]
// HTPC6
// A fullscreen track display code

// Global

// Colors
$puts(col.bg,5-5-5)
$puts(col.border.rating,255-128-0)
$puts(col.border.mood,0-255-0)
$puts(col.imgborder,66-66-66)
$puts(col.progress,$if(%_ispaused%,180-180-180,$if($strstr(%cwb_playback_order%,Shuffle),96-32-255,32-128-255)))
$puts(col.info.basic,222-210-200)
$puts(col.info.additional,180-180-180)

// Positions
$puts(pos.img.a,500)
$puts(pos.img.x,$eval(%_width%/2-$get(pos.img.a)/2))
$puts(pos.img.y,$eval(%_height%/2-$get(pos.img.a)/2))

$puts(EndIsNear,$if($or($greater(35,%_time_elapsed_seconds%),$greater(35,%_time_remaining_seconds%)),1))

/////////////////////////////////////////
// RELATIVE TIMESTAMPS
// formerly known as natural language timestamps
// by topdownjimmy - v0.5.c - May 6, 2007
/////////////////////////////////////////

// calculate days since last play
$puts(dayssince,$cwb_datediff(%cwb_systemdate%,%last_played%))

// correct "dayssince" to consider early AM to be an extension of previous day
$puts(dayssince,$sub($get(dayssince),$if($and($greater(7,$substr(%cwb_systemdatetime%,12,13)),$greater($substr(%last_played%,12,13),6)),1,0)))
$if($and($greater($substr(%cwb_systemdatetime%,12,13),6),$greater(7,$substr(%last_played%,12,13))),$puts(dayssince,$add($get(dayssince),1)),)

// calculate day of week of last play
$puts(calcdayofweek,$add(1,$mod($add($substr(%last_played%,3,4),$div($substr(%last_played%,3,4),4),$select($substr(%last_played%,6,7),6,2,2,5,0,3,5,1,4,6,2,4),$substr(%last_played%,9,10)),7)))

// correct day of week to consider early AM to be an extension of previous day
$puts(calcdayofweek,$sub($get(calcdayofweek),$ifgreater(7,$substr(%last_played%,12,13),1,0)))
$if($strcmp($get(calcdayofweek),0),$puts(calcdayofweek,7),)

// calculate period of day of last play (night, morning, etc.)
$puts(dayperiod,$select($add(1,$substr(%last_played% ,12,13)),Night,Night,Night,Night,Night,Night,Night,Morning,Morning,Morning,Morning,Morning,Afternoon
,Afternoon,Afternoon,Afternoon,Afternoon,Evening,Evening,Evening,Evening,Night,Night,Night))

// calculate natural language timestamp
$if(%last_played%,$puts(rel_timestamp,$ifgreater($get(dayssince),0,$ifgreater($get(dayssince),1,$ifgreater($get(dayssince),6,$if($and($greater($get(dayssince),21),$not($strcmp($left(%cwb_systemdate%,7),$left(%last_played%,7)))),$if($not($strcmp($left(%cwb_systemdate%,4),$substr(%last_played%,1,4))),$select($substr(%last_played%,6,7),January,February,March,April,May,June,July,August,September,October,November,December)' '$ifgreater($get(dayssince),334,$substr(%last_played%,1,4),),$ifgreater(2,$sub($substr(%cwb_systemdate%,6,7),$substr(%last_played%,6,7)),'Last Month',$select($substr(%last_played%,6,7),January,February,March,April,May,June,July,August,September,October,November,December))),$ifgreater($div($add($get(dayssince),4),7),1,$div($add($get(dayssince),4),7)' Weeks Ago',Last Week)),$select($get(calcdayofweek),Sunday,Monday,Tuesday,Wednesday,Thursday,Friday,Saturday)' '$get(dayperiod)),$if($strcmp($get(dayperiod),Night),Last,Yesterday)' '$get(dayperiod)),$if($strcmp($get(dayperiod),Night),Tonight,This $get(dayperiod)))),$puts(rel_timestamp,Never))



// ------------------------------------------------------------------------------------------------------------------

// Background

$drawrect(0,0,0,0,pencolor-null brushcolor-$get(col.bg))
$drawrect(0,$eval(%_height%/100*75+1),%_width%,1,pencolor-99-99-99)
$drawrect(
$eval($get(pos.img.x)-5),
$eval($get(pos.img.y)-5),
$eval($get(pos.img.a)+10),
$eval($get(pos.img.a)+10),
brushcolor-$get(col.bg) pencolor-$get(col.bg) alpha-200
)
$drawrect(
$eval($get(pos.img.x)-3),
$eval($get(pos.img.y)-3),
$eval($get(pos.img.a)+6),
$eval($get(pos.img.a)+6),
brushcolor-null pencolor-$get(col.imgborder)
)

// ------------------------------------------------------------------------------------------------------------------

// PerTrack

// Album Art
$if($get(coverPath),
$imageabs2(
$eval($get(pos.img.a)-50),
$eval($get(pos.img.a)-50),
0,0,
$eval($get(pos.img.a)-50),
$eval($get(pos.img.a)-50),
$eval($get(pos.img.x)+25),
$eval($get(pos.img.y)+25),
$get(coverPath),
NOKEEPASPECT)
)

// Basic trackinfo
$alignabs(
0,
$eval($get(pos.img.y)+$get(pos.img.a)+10),
%_width%,
$eval(%_height%-$get(pos.img.y)-$get(pos.img.a)-20),
center,
middle
)
$font(BigNoodleTitling,40,,$get(col.info.basic))
[' '%title%' ']
$char(10)
$font(Florencesans,8,,$get(col.info.basic))
' '$char(10)
$font(BigNoodleTitling,24,,$get(col.info.basic))
[' '%artist%' ']

// Rating
$if(%rating%,
$puts(rw,$muldiv(%rating%,$eval($get(pos.img.x)-5),5))
$ifgreater($get(rw),0,
$drawrect(
0,
$eval(%_height%/100*75+1-1),
$get(rw),
3,
brushcolor-null pencolor-$get(col.border.rating)
)
,)
)

// Mood
$if(%mood%,
$puts(mw,$muldiv(%mood%,$eval($get(pos.img.x)-5),3))
$ifgreater($get(mw),0,
$drawrect(
$eval(%_width%-$get(mw)),
$eval(%_height%/100*75+1-1),
$get(mw),
3,
brushcolor-null pencolor-$get(col.border.mood)
)
,)
)

// ------------------------------------------------------------------------------------------------------------------

// PerSecond

// Pause overlay
$if(%_ispaused%,
$drawrect(
$eval($get(pos.img.x)),
$eval($get(pos.img.y)),
$eval($get(pos.img.a)),
$eval($get(pos.img.a)),
brushcolor-$get(col.bg) pencolor-$get(col.bg) alpha-150
)
)

// Progress bar

$puts(prog.milli,$muldiv( %playback_time_seconds%,1000,%length_seconds%))
$ifgreater($get(prog.milli),0,
$puts(lw,$muldiv($min(250,$eval($get(prog.milli)-0)),$eval($get(pos.img.a)+6),250))
$drawrect(
$eval($get(pos.img.x)-3),
$eval($get(pos.img.y)-3-1),
$get(lw),
3,
brushcolor-null pencolor-$get(col.progress)
)
,)

$ifgreater($get(prog.milli),250,
$puts(lw,$muldiv($min(250,$eval($get(prog.milli)-250)),$eval($get(pos.img.a)+6),250))
$drawrect(
$eval($get(pos.img.x)+$get(pos.img.a)+2-1),
$eval($get(pos.img.y)-3-1),
3,
$get(lw),
brushcolor-null pencolor-$get(col.progress)
)
,)
$ifgreater($get(prog.milli),500,
$puts(lw,$muldiv($min(250,$eval($get(prog.milli)-500)),$eval($get(pos.img.a)+6),250))
$drawrect(
$eval($get(pos.img.x)+$get(pos.img.a)+3-$get(lw)+1),
$eval($get(pos.img.y)+$get(pos.img.a)+2-1),
$get(lw),
3,
brushcolor-null pencolor-$get(col.progress)
)
,)
$ifgreater($get(prog.milli),750,
$puts(lw,$muldiv($min(250,$eval($get(prog.milli)-750)),$eval($get(pos.img.a)+6),250))
$drawrect(
$eval($get(pos.img.x)-3-1),
$eval($get(pos.img.y)+$get(pos.img.a)+3-$get(lw)+1),
3,
$get(lw),
brushcolor-null pencolor-$get(col.progress)
)
,)





// Additional Info
$if($and($get(EndIsNear),%_isplaying%),

// Artist Art
$if($get(artistPath),
$drawrect($eval(%_width%/2-80-5),$eval($get(pos.img.y)+$get(pos.img.a)-80-5),170,130,pencolor-$get(col.bg) brushcolor-$get(col.bg) alpha-200)
$drawrect($eval(%_width%/2-80-5),$eval($get(pos.img.y)+$get(pos.img.a)-80-5),170,130,pencolor-$get(col.imgborder) brushcolor-null)
$imageabs2(160,120,0,0,160,120,$eval(%_width%/2-80),$eval($get(pos.img.y)+$get(pos.img.a)-80),$get(artistPath),NOKEEPASPECT)
)

$drawrect(
-1,
$eval(%_height%-80),
$eval(%_width%/5),
80,
brushcolor-null pencolor-$get(col.imgborder)
)
$alignabs(
-1,
$eval(%_height%-80),
$eval(%_width%/5-10),
80,
right,
middle
)
$font(BigNoodleTitling,19,,$get(col.info.additional))
[' '%album% ['('%date%')']' ']

$drawrect(
$eval(%_width%*4/5+1),
$eval(%_height%-80),
$eval(%_width%/5),
80,
brushcolor-null pencolor-$get(col.imgborder)
)
$alignabs(
$eval(%_width%*4/5+1+10),
$eval(%_height%-80),
$eval(%_width%/5-10),
80,
left,
middle
)
$font(BigNoodleTitling,19,,$get(col.info.additional))
Last time played:' '$char(10)$get(rel_timestamp)' '
)

 
SimplePortal 1.0.0 RC1 © 2008-2019