alright, here it goes:
EDIT: Fixed my errors. will post if any more come up
http://stashbox.org/11073/01_30_2007-01_48...s-Oceansize.png
additional info on, timecodes off
http://stashbox.org/11074/01_30_2007-01_48...s-Oceansize.png
addinfo on (not currently displaying), timecodes on
http://stashbox.org/11075/01_30_2007-01_50...s-Oceansize.png
addinfo on (not currently displaying), timecodes off
basically, if addinfo on forces total times to display during the first and last 30 seconds (when the addinfo is displaying)
timecodes on force all time information to display at all times
REQUEST: only display the album title (if you look in the "working" pic, you can see it under the bottom right of the album art) if there is no album art.
anyway, here's the code.
// Global
// CONFIGURATION ///////////////////////////////////////////
// Album Art
// Use $if and $fileexists if more locations need to be checked
$puts(path.albumart,$replace(%path%,$if(%disc%,$directory(%path%,1)\)%filename_ext%,folder.jpg))
// Additional info
// addinfo.show: delete the '1' to disable additional info
// addinfo.time: determines how long addinfo is shown
// timeinfo.show: change the '1' to '0' to disable the time codes displayed on the progress bar
$puts(addinfo.show,1)
$puts(addinfo.time,30)
$puts(timeinfo.show,0)
// Positions
// pos.horizon: y-position of the grey horizon gradient
// pos.shadow: increase to see more reflection of the cd-cover
// pos.artx: if changed, further changes will be necessary for text positioning
// pos.arty: change position of album art relative to horizon line
$puts(pos.horizon,$muldiv(%_height%,4,7))
$puts(pos.shadow,120)
$puts(pos.artx,$sub($div(%_width%,2),278))
$puts(pos.arty,$sub($get(pos.horizon),400))
// Fonts
// font.a, font.b: used by addinfo for a) filling text, b) values
$puts(font.track,$font(Calibri,16,,255-255-255))
$puts(font.album,$font(Calibri,8,,255-255-255))
$puts(font.artist,$font(Calibri,12,,255-255-255))
$puts(font.a,$font(Calibri,12,,150-150-150))
$puts(font.b,$font(Calibri,12,,255-255-255))
$puts(font.c,$font(Calibri,7,,255-255-255))
$puts(font.d,$font(Calibri,7,,225-225-225))
// Progress bar
$puts(bar.height,7)
$puts(bar.color,50-50-50)
// END OF CONFIG ///////////////////////////////////////////
// Background
$drawrect(,,,,brushcolor-0-0-0 pencolor-null)
$imageabs(,$get(pos.horizon),/images/htpc2/horizon.png,)
// PerTrack
// Album Art
$imageabs2(556,516,0,0,556,$add(29,$get(pos.shadow)),$get(pos.artx),$add(460,$get(pos.arty)),/images/htpc2/case.png,ROTATEFLIP-6)
$imageabs2(454,454,0,0,454,$add(-2,$get(pos.shadow)),$add(71,$get(pos.artx)),$add(460,31,$get(pos.arty)),$get(path.albumart),NOKEEPASPECT ROTATEFLIP-6)
$imageabs($get(pos.artx),$add($get(pos.shadow),299,$get(pos.arty)),/images/htpc2/shadow.png,)
$imageabs($get(pos.artx),$get(pos.arty),/images/htpc2/case.png,)
$imageabs2(454,454,0,0,454,454,$add(71,$get(pos.artx)),$add(31,$get(pos.arty)),$get(path.albumart),NOKEEPASPECT)
// PerSecond
// Pause Overlay
$if(%ispaused%,
$drawrect($add(71,$get(pos.artx)),$add(31,$get(pos.arty)),454,454,pencolor-0-0-0 alpha-150)
$alignabs($add(71,$get(pos.artx)),$add(31,$get(pos.arty)),454,454,center,middle)$font(Webdings,72,,255-255-255)';'
$drawrect($add(71,$get(pos.artx)),$add(460,31,$get(pos.arty)),454,$add(-2,$get(pos.shadow)),pencolor-0-0-0 alpha-150)
)
// Progress Bar
$ifgreater($muldiv(%playback_time_seconds%,%_width%,%length_seconds%),0,
$drawrect(0,$sub(%_height%,$mul($get(bar.height),3)),$muldiv(%playback_time_seconds%,%_width%,%length_seconds%),$get(bar.height),pencolor-null brushcolor-$get(bar.color))
,)
// Trackinfo
$if($and($or($greater($get(addinfo.time),%playback_time_seconds%),$greater($get(addinfo.time),%playback_time_remaining_seconds%)),$get(addinfo.show)),
// Detailed
$alignabs($get(pos.artx),$add($get(pos.arty),493),522,$sub(%_height%,$get(pos.horizon),$get(pos.shadow),140),right,top)
$get(font.album)[%album%]$char(10)
$alignabs($add($sub($get(pos.artx),$div(%_width%,2)),12),$add($get(pos.horizon),$get(pos.shadow),60),556,$sub(%_height%,$get(pos.horizon),$get(pos.shadow),64),center,bottom)
$get(font.c)'0:00'
$alignabs($sub($add($get(pos.artx),$div(%_width%,2)),12),$add($get(pos.horizon),$get(pos.shadow),60),556,$sub(%_height%,$get(pos.horizon),$get(pos.shadow),64),center,bottom)
[%length%]
$alignabs(80,$add($get(pos.horizon),$get(pos.shadow)),$sub(%_width%,160),$sub(%_height%,$get(pos.horizon),$get(pos.shadow),64),center,bottom)
$get(font.track)$if2(%title%,%filename%)$char(10)
$get(font.artist)[%artist%]
$char(10)$font(Arial,10,,0-0-0) $char(10)
$if(%last_played%,$get(font.a)Played $get(font.b)%play_counter%$get(font.a) time'('s')'', 'last on $get(font.b)$substr(%last_played%,9,10) $select($substr(%last_played%,6,7),January,February,March,April,May,June,July,August,September,October,November,December) $substr(%last_played%,1,4)$get(font.a).$char(10))
$if(%playback_time_seconds%,$get(font.a) $if(%album%,From the album $get(font.b)%album%$get(font.a)))$if(%date%,', 'published in $get(font.b)%date%$get(font.a) )$if(%publisher%,by $get(font.b)%publisher%$get(font.a))
,
// Default
$alignabs($get(pos.artx),$add($get(pos.arty),493),522,$sub(%_height%,$get(pos.horizon),$get(pos.shadow),140),right,top)
$get(font.album)[%album%]$char(10)
$alignabs($get(pos.artx),$add($get(pos.horizon),$get(pos.shadow)),556,$sub(%_height%,$get(pos.horizon),$get(pos.shadow),64),center,bottom)
$get(font.track)$if2(%title%,%filename%)$char(10)
$get(font.artist)[%artist%]
)
//time codes
$if($greater($get(timeinfo.show),0),$alignabs($add($sub($get(pos.artx),$div(%_width%,2)),12),$add($get(pos.horizon),$get(pos.shadow),60),556,$sub(%_height%,$get(pos.horizon),$get(pos.shadow),64),center,bottom)
$get(font.c)'0:00'
$alignabs($sub($add($get(pos.artx),$div(%_width%,2)),12),$add($get(pos.horizon),$get(pos.shadow),60),556,$sub(%_height%,$get(pos.horizon),$get(pos.shadow),64),center,bottom)
[%length%]
$alignabs($add($sub($get(pos.artx),$div(%_width%,2)),$muldiv(%playback_time_seconds%,%_width%,%length_seconds%),-11),$add($get(pos.horizon),$get(pos.shadow),51),556,$sub(%_height%,$get(pos.horizon),$get(pos.shadow),64),center,bottom)
$get(font.d)[%playback_time% ]
$alignabs($add($sub($get(pos.artx),$div(%_width%,2)),$muldiv(%playback_time_seconds%,%_width%,%length_seconds%),13),$add($get(pos.horizon),$get(pos.shadow),51),556,$sub(%_height%,$get(pos.horizon),$get(pos.shadow),64),center,bottom)
$get(font.c)[ -%playback_time_remaining%],)