Quote from: nago on 2007-11-16 00:28:42

Sorry if you're really going to start hating me here, I do have another question sad.gif. in the official version of react, I could set the @outroot@ variable to something like %userprofile%\desktop\ripped and when it was written to the batchfile, @outroot@ would literally be %userprofile%\desktop\ripped so when it was actually processed windows would pick up the variable. In your modified version, I'm finding it's getting written as %%userprofile%% -- is this a symptom of escaping illegal characters? if so, can I ... unescape them somehow?

You are correct, this was to resolve other issues.  I can't think of a workaround, but I will think some more on it.

Quote from: Akkurat on 2007-11-14 15:07:57

5. Eaclog filename wrong (and var pointing to it). Not copied to dest. folder.

Replicated.  When naming the log file in track mode EAC uses the format "<artist> - <album>" with any illegal characters replaced with a space.  REACT thought it was emulating this; however EAC treats the apostrophe as an illegal character also, which REACT did not.  I have now changed this, so that the REACT variable should match the name that EAC creates when an apostrophe is in the filename (artist and/or album name).

IF %add_rg%==1 (
    SETLOCAL ENABLEDELAYEDEXPANSION
    SET flacfiles=
    FOR %%f IN (*.flac) DO SET flacfiles=!flacfiles! "%%f"
    "@Tools@\metaflac.exe" %RG_MetaFlac% !flacfiles!
    SETLOCAL DISABLEDELAYEDEXPANSION
)

REM ** Get flac version
SET Ver_Flac=
FOR /F "delims=" %%i IN ('"@Tools@\flac.exe" --version') DO SET Ver_Flac=%%i

REM ** Read the REAL last AUDIO track number from cuesheet. Number is zero-padded.
SET LastTrackNum=
IF EXIST "@albumfile@.[mg].cue" (
    FOR /F "tokens=2 delims= " %%i IN ('FINDSTR /R "TRACK.[0-9][0-9].AUDIO" "@albumfile@.[mg].cue"') DO SET LastTrackNum=%%i
) ELSE (
    SET LastTrackNum=@numtracks@
)

REM ** Get EAC (from cuesheet) & REACT (from REACT.ini) versions
SET EacVer=
IF EXIST "@albumfile@.[mg].cue" (
    SETLOCAL ENABLEDELAYEDEXPANSION
    FOR /F "tokens=4 delims= " %%i IN ('FINDSTR /R "REM.COMMENT..ExactAudioCopy.*" "@albumfile@.[mg].cue"') DO SET EacVer=%%i
    REM ** Remove trailing quote char
    SET EacVer=!EacVer:"=!
    SETLOCAL DISABLEDELAYEDEXPANSION
)
SET Ripper=EAC %EacVer% / REACT @ReactVersion@

I do sense a little hostility (maybe a little too agressive word choice) towards me.. hmm, don't know if I'm interpreting your posts wrongly Synthetic Soul.. but I know that I got an unwanted guest feeling at the moment.  Let's make it clear; I do not want to argue or raise any bad feelings whatsoever here. I just came here to share because I thought that I had something to give to the REACT development. I'm sorry if I have caused harm. It's sometimes hard to be clear and concise when you want to keep the post size down and at the same time you're trying to describe your problems/whatever understandably.. and of course there's the language barrier too (english is not my mother language).

Well, in any case, I honestly think that you, Synthetic Soul, should (if you want to) take over the REACT development with blessing from Tycho. You've been the real "driver" for a long time now. I really would like to see REACT progress, now the development is at stand still (well almost if you don't count your inputs to your mod).

In any case, it may be that either your first suggestion or your second would work! How do I go about setting the internal temp names to per-track? Not a big coding expert but don't mind playing around with the cfg files if that's what's needed...

I was able to fix this simply by changing the name of the batchfile that is written to include the tracknumber, REACT by default deletes the batchfile before it starts each track to get a clean slate each time, so this can mess up parallel stuff.

Here's the modded EXE, based strictly on ssb16k: React2.0ssb16k+n1

to Synthetic-Soul: I only changed one line where;

Code: [Select]

$g_batfile = $g_logfile & ".bat"

to

Code: [Select]

$g_batfile = $g_logfile & "[" & $g_track & "].bat"

REM ** Ensure that all other compression threads are closed before starting post-processing
:CheckForMultipleBatFiles
SET BatFilesCount=0
SETLOCAL ENABLEDELAYEDEXPANSION
FOR %%f IN (*.bat) DO SET /A BatFilesCount=!BatFilesCount!+1
SETLOCAL DISABLEDELAYEDEXPANSION
IF NOT %BatFilesCount%==1 GOTO Pause

GOTO :EOF

REM Pause for 10000 milliseconds and return to :CheckForMultipleBatFiles
:Pause
@ECHO Waiting for all the other compression threads to finish...
PING 1.1.1.1 -n 1 -w 10000 >NUL
GOTO CheckForMultipleBatFiles

NB: You may want to take a look at 2.0.ssb16k. I have actually, I believe, improved the code that deals with creating and renaming the cuesheets.  REACT will now ensure that the main window is active before sending the key presses or menu commands, and (less importantly) I have changed the function that looks to move the cuesheets to wait for up to five seconds or the closure of the "Analyzing" dialogue.

ssb16k & ssb16i
	(variable values taken from dos window, removed dir paths)
	
	@albumfile@.[mg].cue = Kiss Of Life (CDS)&%     '   äåö.[mg].cue
	FILENAME             = Kiss Of Life (CDS)&%         äåö.[mg].cue

	@cover@  = Kiss Of Life (CDS)&%     '   äåö.jpg
	FILENAME = Kiss Of Life (CDS)&%         äåö.jpg

	@eaclog@ = Supergrass&%     '   äåö - Kiss Of Life (CDS)&%     '   äåö.log
	FILENAME = Supergrass&%         äåö - Kiss Of Life (CDS)&%         äåö.log
	
	FILENAME = Supergrass&%     '   äåö - Kiss Of Life (CDS)&%     '   äåö.bat
		Doesn't make a difference what filename this has...?

ssb16j
	
	@albumfile@.[mg].cue = Kiss Of Life (CDS)&%         äåö.[mg].cue
	FILENAME             = Kiss Of Life (CDS)&%         äåö.[mg].cue

	@cover@  = Kiss Of Life (CDS)&%         äåö.jpg
	FILENAME = Kiss Of Life (CDS)&%         äåö.jpg (Would be this if albumart.exe would run properly)

	@eaclog@ = Supergrass&%         äåö - Kiss Of Life (CDS)&%         äåö.log
	FILENAME = Supergrass&%         äåö - Kiss Of Life (CDS)&%         äåö.log
	
	FILENAME = Supergrass&%         äåö - Kiss Of Life (CDS)&%         äåö.bat
		Doesn't make a difference what filename this has...?

TRACK MODE:
    RunCoverDownloader=1 ... waits (OK)
    RunCoverDownloader=2 ... waits / doesn't wait (NOT OK!) I'm puzzled, sometimes waits, sometimes not, tried many different methods to reproduce the bug (start EAC, run image rip first then track, close EAC, start it, run track rip, then image, and then track again.. etc.) but it just works randomly. Don't know what can be done to it.. or should?
    RunCoverDownloader=3 ... waits (NOT OK!)
    RunCoverDownloader=4 ... doesn't wait (OK)

IMAGE MODE:
    RunCoverDownloader=1 ... doesn't wait (OK)
    RunCoverDownloader=2 ... waits (OK)
    RunCoverDownloader=3 ... waits (OK)
    RunCoverDownloader=4 ... doesn't wait (OK)

(at the very start)
if not exist working[@track@].tmp (
  echo "we're busy!" > working[@track@].tmp
)

(end of regular processing, just after tracks processing)
del working[@track@].tmp


(at beginning of post-processing, after if tracks==totaltracks)
:checktmp
  if exist working[*].tmp goto allProcsClear
  PING 1.1.1.1 -n 1 -w 10000 >NUL
  goto checktmp
)
:allProcsClear

(post processing)

I'm sorry to bring you bad news, the escape fixes you did for ssb16j version are reverted back to the buggy behaviour like in the ssb16i version (I guess that you already knew this).

• The log file name is generated in two places in the code - once for the wrapper instance of REACT and once for the processing instance.
• I forgot that EAC converts double quotes to apostrophes.  It wasn't apostrophes in the artist or album name that were causing the issue, but double-bloody-quotes again.

• Record the true value from the wrapper instance (grabbed directly from the main dialogue) in the INI to read later.  This may have issues when considering the compression queue or dual processors.
• Trawl the working directory for any ".log" file - if there's only one assume it is ours.  If there's more than one use an algorithm to detirmine which is most likely ours.  Yuck.
• Maybe the processing instance can re-grab the value from the EAC dialogue... unsure.  Yuck II.
• I'm sure  had another one, but it's gone...

"RunCoverDownloader" setting doesn't work properly in track rips.

[Settings]
Version=2.0
ImageExt=wav
ImageNaming=$artist$ - [$year$] $album$
ImageHotKey={F10}
TracksHotKey={F4}
TracksHotVal=+{F5}
VA=Various Artists
CreateAllCuesheets=0
RunCoverDownloader=1
CoverDownloader=C:\Program Files\REACT2\coverdownloader\albumart.exe
EAC=C:\Program Files\Exact Audio Copy\EAC.exe
Tools=C:\Program Files\REACT2\tools
MinimizeCompressionWindow=1
ProcessPriority=5
Sla_Bks_Col_Qst_Bar_Quo_Ast_Lt_Gt=-|-|-||!|'|#|[|]

[UserTrackFormats]
Flac=1
Wavpack=0
LameMP3=1
NeroAac=0
iTunesAac=0
OggEnc2=0

[UserOutputNames]
OutRoot=D:\Music
ImageDir_Flac=@OutRoot@\FLAC-images\$cdartist$
ImageDir_Wavpack=@OutRoot@\WV-images\$cdartist$
ImageDir_MP3=@OutRoot@\MP3-images\$cdartist$
TrackDir_Flac=@OutRoot@\FLAC\$cdartist$\$album$
TrackDir_Wavpack=@OutRoot@\WV\$cdartist$\[$year$] $album$
TrackDir_MP3=@OutRoot@\MP3\$cdartist$\$album$
TrackDir_AAC=@OutRoot@\AAC\$cdartist$\[$year$] $album$
TrackDir_OGG=@OutRoot@\OGG\$cdartist$\[$year$] $album$
TrackName_SA=$track$ - $title$
TrackName_VA=$track$ - $artist$ - $title$
TrackName_SA_acdir=$n - $~t
TrackName_VA_acdir=$n - $~t [$~a]

[UserSettings]
Debug=0
Comment=Created with EAC/REACT2, @curdate@
EmbedCover=1
ReplayGain=1
ApplyAlbumGain=0
AdjustAlbumGain_dB=+3.0
AddCuesheetAG=0
UseWaveGainAG=0
Opt_Flac=-8 -V --replay-gain
Opt_Wavpack=-hmy
Opt_LameMP3=-V0 --vbr-new --replaygain --nohist
Opt_NeroAac=-lc -q 0.21
Opt_iTunesAac=-d -s 2000
Opt_OggEnc2=-q 3.0
Ver_Flac=1.1.3
Ver_Wavpack=4.40
Ver_LameMP3=3.97
Ver_NeroAac=1.0.0.2
Ver_OggEnc2=2.83 Lancer aoTuV b5


[DefaultMetaData]
discnumber=1
totaldiscs=1
discname=

@ECHO OFF
CHCP 1252 | PROMPT
TITLE @track@/@numtracks@ - "@album@"

REM Copyright © Tycho, 2006
REM
REM ** Create compressed audio tracks from ripped .wav tracks.
REM **
REM ** You may consider using image mode (F10)
REM ** as it supports creating tracks via acdir.exe,
REM ** and post-processing will always work (see below).
REM **
REM ** Flac requires flac.exe/metaflac.exe (v1.1.3)
REM ** NeroAac requires NeroAacEnc.exe/NeroAacTag.exe/AacGain.exe.
REM ** OggEnc2 requires OggEnc2.exe/VorbisGain.exe.
REM **
REM ** I prefer applying album gain 92dB to get a reasonable
REM ** volume for my DAP. The RG tags are still relative
REM ** to 89dB SPL, i.e. album gain will be about -3.0dB.


REM ============== Begin Main Script ==================


IF @Debug@==1 ECHO ON
REM ** Workaround for multi-processing, added by nago.
echo > processing[@track@].tmp
REM ** Create Disc-related tags if we have a set

REM If a disc name has been provided
IF "@discname@" EQU "" GOTO end_discname
SET discName=discname
SET discName=@%discname%@
IF "@discname@" EQU "%discName%" GOTO end_discname

	REM Set tagging switches
	SET Disc_Flac=-T "discname=@discname@"
	SET Disc_Wavpack=-w "discname=@discname@"
	REM SET Disc_MP3=--frame TSST:"@discname@"
	SET Disc_MP3=--frame "TXXX[setsubtitle]:@discname@"
	SET Disc_OggEnc2=-c "discname=@discname@"
	SET Disc_Tak=-t "discname=@discname@"

	REM Add disc name to folder path
	SET trackDir=%trackDir%\$discname$

	GOTO :end_discnumber

:end_discname

REM Ensure that we have numeric values
SET /A discNumber = @discnumber@ + 0
SET /A totalDiscs = @totaldiscs@ + 0

REM IF a valid disc number and total number of discs has been provided
IF %totalDiscs% LEQ 1 GOTO :end_discnumber
IF %discNumber% LEQ 0 GOTO :end_discnumber

	REM Set tagging switches
	SET Disc_Flac=-T "discnumber=@discnumber@" -T "totaldiscs=@totaldiscs@"
	SET Disc_Wavpack=-w "discnumber=@discnumber@" -w "totaldiscs=@totaldiscs@"
	SET Disc_MP3=--frame TPOS:"@discnumber@/@totaldiscs@"
	SET Disc_NeroAac=--disk "@discnumber@/@totaldiscs@"
	SET Disc_OggEnc2=-c "discnumber=@discnumber@" -c "totaldiscs=@totaldiscs@"
	SET Disc_Tak=-t "discnumber=@discnumber@" -t "totaldiscs=@totaldiscs@"

	REM Add disc number to folder path
	SET trackDir=%trackDir%\Disc @discnumber@

:end_discnumber


SET TrackDir_Flac="@TrackDir_Flac@%trackDir%"
SET TrackDir_Wavpack="@TrackDir_Wavpack@%trackDir%"
SET TrackDir_MP3="@TrackDir_MP3@%trackDir%"
SET TrackDir_AAC="@TrackDir_AAC@%trackDir%"
SET TrackDir_OGG="@TrackDir_OGG@%trackDir%"
SET TrackDir_Tak="@TrackDir_Tak@%trackDir%"


SET TrackName=@trackname@

SET have_cover=0
SET embed_cover=0

IF EXIST "@cover@" (
	SET have_cover=1
	SET embed_cover=@EmbedCover@
)




REM ---- Track ----


IF NOT @Flac@==1 GOTO end_flac_tracks
	IF NOT EXIST %TrackDir_Flac% MKDIR %TrackDir_Flac%
	PUSHD %TrackDir_Flac%
		IF @various@==1 SET VA_tag=-T "album artist=@VA@"
		IF %embed_cover%==1 SET Cover_tag=--picture="|image/jpeg|||@cover@"
		ECHO ON
		@tools@\flac.exe @Opt_Flac@ %Cover_tag% %VA_tag% %Disc_Flac% -T artist="@artist@" -T album="@album@" -T tracknumber="@track@/@numtracks@" -T title="@title@" -T date="@year@" -T genre="@genre@" -T comment="@comment@" -T encoded-by="%USERNAME%" -T encoding="Flac @Ver_Flac@ @Opt_Flac@" "@source@" -o "%TrackName%.flac"
		@ECHO OFF
		IF %have_cover%==1 IF NOT EXIST folder.jpg COPY "@cover@" folder.jpg
	POPD
:end_flac_tracks


IF NOT @Wavpack@==1 GOTO end_wavpack_tracks
	IF NOT EXIST %TrackDir_Wavpack% MKDIR %TrackDir_Wavpack%
	PUSHD %TrackDir_Wavpack%
		IF @various@==1 SET VA_tag=-w "album artist=@VA@"
		ECHO ON
		@tools@\wavpack.exe @Opt_Wavpack@ %VA_tag% %Disc_Wavpack% -w artist="@artist@" -w album="@album@" -w track="@track@/@numtracks@" -w title="@title@" -w year="@year@" -w genre="@genre@" -w comment="@comment@" -w encodedby="%USERNAME%" -w encodersettings="Wavpack @Ver_Wavpack@ @Opt_Wavpack@" "@source@" "%TrackName%.wv"
		@ECHO OFF
		IF %have_cover%==1 IF NOT EXIST folder.jpg COPY "@cover@" folder.jpg
		TITLE @track@/@numtracks@ - "@album@"
	POPD
:end_wavpack_tracks


IF NOT @Tak@==1 GOTO end_tak_tracks
	IF NOT EXIST %TrackDir_Tak% MKDIR %TrackDir_Tak%
	PUSHD %TrackDir_Tak%
		IF @various@==1 SET VA_tag=-t "album artist=@VA@"
		ECHO ON
		@tools@\takc.exe -e -overwrite @Opt_Tak@ "@source@" "%TrackName%.tak"
		@tools@\tag.exe %VA_tag% %Disc_Tak% -t artist="@artist@" -t album="@album@" -t track="@track@/@numtracks@" -t title="@title@" -t year="@year@" -t genre="@genre@" -t comment="@comment@" -t encodedby="%USERNAME%" -t encodersettings="TAK @Ver_Tak@ @Opt_Tak@" "%TrackName%.tak"
		@ECHO OFF
		IF %have_cover%==1 IF NOT EXIST folder.jpg COPY "@cover@" folder.jpg
		TITLE @track@/@numtracks@ - "@album@"
	POPD
:end_tak_tracks


IF NOT @LameMP3@==1 GOTO end_lame_tracks
	IF NOT EXIST %TrackDir_MP3% MKDIR %TrackDir_MP3%
	PUSHD %TrackDir_MP3%
		IF @various@==1 SET VA_tag=--user-text "[album artist]@VA@" --frame "TPE2:@VA@"
		IF %embed_cover%==1 SET Cover_tag=--pict "{3}@cover@"
		ECHO ON
		@tools@\lame.exe @Opt_LameMP3@ "@source@" "%TrackName%.mp3"
		@tools@\metamp3.exe %Cover_tag% %VA_tag% %Disc_MP3% --artist "@artist@" --album "@album@" --track @track@/@numtracks@ --title "@title@" --year "@year@" --genre "@genre@" --comment "@comment@" --frame TENC:"%USERNAME%" --frame TSSE:"LAME @Ver_LameMP3@ @Opt_LameMP3@" "%TrackName%.mp3"
		@ECHO OFF
		IF %have_cover%==1 IF NOT EXIST folder.jpg COPY "@cover@" folder.jpg
	POPD
:end_lame_tracks


IF NOT @iTunesAac@==1 GOTO end_itunes_aac_tracks
	IF NOT EXIST %TrackDir_AAC% MKDIR %TrackDir_AAC%
	PUSHD %TrackDir_AAC%
		IF %embed_cover%==1 SET Cover_tag=-r "@cover@"
		ECHO ON
		@tools@\iTunesEncode.exe @Opt_iTunesAac@ -e "AAC Encoder" %Cover_tag% -x @various@ -a "@artist@" -l "@album@" -n "@track@" -m "@numtracks@" -t "@title@" -y "@year@" -g "@genre@" -c "@comment@" -i "@source@" -o "%TrackName%.m4a"
		@ECHO OFF
		IF %have_cover%==1 IF NOT EXIST folder.jpg COPY "@cover@" folder.jpg
	POPD
	GOTO end_nero_aac_tracks
:end_itunes_aac_tracks

IF NOT @NeroAac@==1 GOTO end_nero_aac_tracks
	IF NOT EXIST %TrackDir_AAC% MKDIR %TrackDir_AAC%
	PUSHD %TrackDir_AAC%
		IF @various@==1 SET VA_tag=--albumArtist "@VA@" --compilation true
		IF %embed_cover%==1 SET Cover_tag=--artwork "@cover@"
		ECHO ON
		@tools@\neroAacEnc.exe @Opt_NeroAac@ -if "@source@" -of "%TrackName%.m4a"
		@tools@\AtomicParsley.exe "%TrackName%.m4a" -o REACT_tmp.m4a %Cover_tag% %VA_tag% %Disc_NeroAac% --artist "@artist@" --album "@album@" --tracknum "@track@/@numtracks@" --title "@title@" --year "@year@" --genre "@genre@" --comment "@comment@" --encodingTool "neroAacEnc @Ver_NeroAac@ @Opt_NeroAac@"
		@ECHO OFF
		MOVE /Y REACT_tmp.m4a "%TrackName%.m4a"
		IF %have_cover%==1 IF NOT EXIST folder.jpg COPY "@cover@" folder.jpg
	POPD
:end_nero_aac_tracks


IF NOT @OggEnc2@==1 GOTO end_oggenc_tracks
	IF NOT EXIST %TrackDir_OGG% MKDIR %TrackDir_OGG%
	PUSHD %TrackDir_OGG%
		IF @various@==1 SET VA_tag=-c "album artist=@VA@"
		ECHO ON
		@tools@\oggenc2.exe @Opt_OggEnc2@ %VA_tag% %Disc_OggEnc2% -c artist="@artist@" -c album="@album@" -c tracknumber="@track@/@numtracks@" -c title="@title@" -c date="@year@" -c genre="@genre@" -c comment="@comment@" -c encoded-by="%USERNAME%" -c encoding="OggEnc @Ver_OggEnc2@ @Opt_OggEnc2@" "@source@" -o "%TrackName%.ogg"
		@ECHO OFF
		IF %have_cover%==1 IF NOT EXIST folder.jpg COPY "@cover@" folder.jpg
	POPD
:end_oggenc_tracks


REM ** Delete the source .wav
DEL "@source@"
REM ** More multiprocessing workaround --nago
DEL "processing[@track@].tmp"

REM ---- Post-processing ----


rem ** Scan and compute ReplayGain and add cover picture for supported formats.
rem ** NB: The following will only work if at least the last track is selected,
rem ** and it is a regular audio track.

IF NOT @track@==@numtracks@ GOTO end_post_process
	REM ** More multiprocessing. Last edit. --nago
	:checktmp
	if not exist processing[*].tmp goto allProcsClear
	  echo Waiting for all other processes to clear... If program hangs here and there are no other tracks being encoded, delete all processing[#].tmp files in your @source@ directory.
	  PING 1.1.1.1 -n 1 -w 10000 >NUL
	goto checktmp
	:allProcsClear

	SET add_rg=@ReplayGain@
	SET aac_enc=@NeroAac@
	IF @iTunesAac@==1 SET aac_enc=1

	IF NOT @ReplayGain@==1 GOTO end_RG
		SET RG_MetaFlac=--add-replay-gain
		SET RG_MetaMP3=--replay-gain
	:end_RG

	IF NOT @ApplyAlbumGain@==1 GOTO end_apply_AG
		SET RG_MetaMP3=--apply-gain album@AdjustAlbumGain_dB@
		SET RG_AacGain=/a /o /c /d @AdjustAlbumGain_dB@
		SET add_rg=1
	:end_apply_AG


	REM ** Audio Formats:

	IF @Flac@==1 (
		PUSHD %TrackDir_Flac%
			IF %add_rg%==1 @tools@\Glob.exe -v -c @tools@\metaflac.exe %RG_MetaFlac% *.flac
			REM COPY /Y "@eaclog@" "EAClog.txt"
		POPD
	)

	IF @Wavpack@==1 (
		PUSHD %TrackDir_Wavpack%
			IF %add_rg%==1 @tools@\wvgain.exe -a *.wv
			REM COPY /Y "@eaclog@" "EAClog.txt"
		POPD
	)

	IF @LameMP3@==1 (
		PUSHD %TrackDir_MP3%
			IF %add_rg%==1 @tools@\metamp3.exe %RG_MetaMP3% *.mp3
			REM COPY /Y "@eaclog@" "EAClog.txt"
		POPD
	)

	IF %aac_enc%==1 (
		PUSHD %TrackDir_AAC%
			IF %add_rg%==1 @tools@\aacgain.exe %RG_AacGain% *.m4a > "gainlog.txt"
			REM COPY /Y "@eaclog@" "EAClog.txt"
		POPD
	)

	IF @OggEnc2@==1 (
		PUSHD %TrackDir_OGG%
			IF %add_rg%==1 @tools@\vorbisgain.exe -a *.ogg
			REM COPY /Y "@eaclog@" "EAClog.txt"
		POPD
	)


	REM ** Cleanup

	DEL "@eaclog@"
	DEL "@albumfile@.[*].cue"
	DEL "@cover@"

:end_post_process


REM ================ End Main Script ===================


IF @Debug@==1 (
	PAUSE
	EXIT
)

REM ** Delete this .bat file:
DEL %0

I am currently thinking of a few options:

• Record the true value from the wrapper instance (grabbed directly from the main dialogue) in the INI to read later.  This may have issues when considering the compression queue or dual processors.
• Trawl the working directory for any ".log" file - if there's only one assume it is ours.  If there's more than one use an algorithm to detirmine which is most likely ours.  Yuck.
• Maybe the processing instance can re-grab the value from the EAC dialogue... unsure.  Yuck II.
• I'm sure  had another one, but it's gone...

Synthetic 'Saddo' Soul

  Synthetic [ ']Saddo[ '] Soul

Quote from: Synthetic Soul on 2007-11-17 08:53:11

I am currently thinking of a few options:

• Record the true value from the wrapper instance (grabbed directly from the main dialogue) in the INI to read later.  This may have issues when considering the compression queue or dual processors.
• Trawl the working directory for any ".log" file - if there's only one assume it is ours.  If there's more than one use an algorithm to detirmine which is most likely ours.  Yuck.
• Maybe the processing instance can re-grab the value from the EAC dialogue... unsure.  Yuck II.
• I'm sure  had another one, but it's gone...

I think I remember #4, and it's the likely candidate at the moment.

Currently, due to the change in log file naming EAC introduced in 0.99 the code checks for both expected formats in a loop, and exits when one is found.  Using a couple of loops I could check each permutation of the filename with apostrophes replaced or not replaced.  If a match is found we have a winner.  Alternatively, and preferably, I would hope that I should be able to use a regular expression to match the filename, replacing ' with [' ], e.g.:

Code: [Select]

Synthetic 'Saddo' Soul

... to:

Code: [Select]

  Synthetic [ ']Saddo[ '] Soul

I'll let you know how I get on.

Your first post: This is an interesting concept for how to do this, but this wouldn't work properly with debug mode, since debug doesn't delete the batch files. It'd sit around and wait forever...

Okay. I've made a quick fix for MarkE's error (no support for multiple processes at all) as well as a fix for Akkurat's multiple processes "Surprise Feature", wherein if the last track finishes before another track, post-processing gets messed up.

The end result is that now you should be able to run two or more processes safely. I do not know how well iTunesEnc will handle this, but any of the general command line tools should probably work OK.

The fixes are located in a new .cfg and .exe based strictly off of the ssb16k version, with a list of all edits included within. You can get ssb16k+n2 here.

REM ** Compression threads workaround. Ensures that all compression threads are closed before starting post-processing.
:checkTmp
IF NOT EXIST processing[*].tmp GOTO allProcsClear
    ECHO.
    ECHO Waiting for all other processes to clear... If program hangs here and there are no other tracks being encoded, delete all processing[#].tmp files in your "@sourcedir@" directory.
    ECHO.
    REM ** Pause for 10000 milliseconds
    PING 1.1.1.1 -n 1 -w 10000 >NUL
    GOTO checkTmp
:allProcsClear