foo_uie_trackinfo

Topic: foo_uie_trackinfo (Read 816140 times) previous topic - next topic

0 Members and 2 Guests are viewing this topic.

foo_uie_trackinfo

Reply #175 – 2005-01-25 13:24:19

Quote

Thank you!

Is it possible to put left and right parenthesis next to the text? I tried, but i failed...
disc 1 -> (Disc 1)
[a href="index.php?act=findpost&pid=267926"][{POST_SNAPBACK}][/a]

New version:

Code: [Select]

'Album: '$get(c_t1b)$replace($meta(album),'(',$get(c_3)'(',')',')'$get(c_t1b),'[',$get(c_3)'[',']',']'$get(c_t1b))FFFFFF|FFFFFF$if(%disc%,' (Disc '%disc%')',$ifgreater($len($tracknumber()),2,' (Disc '$left($tracknumber(),1)')',))[' '''$meta(discname)'']$char(10)

foo_uie_trackinfo

Reply #176 – 2005-01-26 05:00:28

Quote

@war59312

Hmh, could you maybe explain to me what your last two posts have to do with foo_uie_trackinfo?

Could be I overlooked something, but I somehow fail to see the connection.
[a href="index.php?act=findpost&pid=267786"][{POST_SNAPBACK}][/a]

Well srry someone had said something so I was just replying about it. But fine with drop it and start a new topic if need be.

foo_uie_trackinfo

Reply #177 – 2005-01-26 07:39:45

Quote

Can author add to plugin features, like read info from some file (Ex: *txt, etc).

Ex: I not needed on tagz on foo_ui_trackinfo. I can read tagz from playlist and statusbar.

4what: read lyric from file.txt for curent song, or album(group,artist) history(biography,etc).

PS: Ex - example
[{POST_SNAPBACK}][/a]

Oh.. It's some sort of [a href="http://www.hydrogenaudio.org/forums/index.php?showtopic=30855&hl=]Lyrics Panel[/url] requested by eliazu?

Good idea. However, how should the trackinfo works? When to display track information and when to display lyrics? You can have both displayed but you need a large panel space on foobar UI.

foo_uie_trackinfo

Reply #178 – 2005-01-26 15:06:53

I have a few requests

Would it be possible to have multiple info panels with multiple configurations?
For example, one panel for the infos about the track, another for displaying the lyrics, another for the review of the CD...

And how about reading content from external file? (for those who use evillyrics for example)

anyway thanks for the plugin

foo_uie_trackinfo

Reply #179 – 2005-01-29 00:27:49

does anybody know how to get the filesize to work like the %_time_elapsed%.

e.g when the time is at zero then the filesize is also zero, but when it starts to play the filesize starts to count up in MB's as the seconds go by, and finishes at the acutal size of the file.

also is there anyway of stopping CBR mp3's showing when using %__dynamic_bitrate%

This is the string i'm using

Code: [Select]

'AVG Bitrate: '$get(c_t1b)%__bitrate% kbps$if(%__bitrate_dynamic%,$char(10)'VBR Bitrate: '$get(c_t1b)%__bitrate_dynamic% kbps,) $char(10)

It only needs to work with MP3,MPC and WV

foo_uie_trackinfo

Reply #180 – 2005-01-29 01:44:30

1. $muldiv(%_filesize%,%_time_elapsed_seconds%,%_time_total_seconds%)
(then wrap that in the bytes->MB code)

edit: code was borken

foo_uie_trackinfo

Reply #181 – 2005-01-29 02:06:54

2. $if($and(%__mp3_stereo_mode%,$not(%__extrainfo%)),MP3 CBR,OTHER)

foo_uie_trackinfo

Reply #182 – 2005-01-29 02:12:13

Phi
Just wanted to say thx for this plug in....its just what I needed....its an integral part of my Foo.
Keep up the good work
Mr E

foo_uie_trackinfo

Reply #183 – 2005-01-29 02:24:54

Quote

1. $muldiv(%_filesize%,%time_elapsed_seconds%,%time_total_seconds)
(then wrap that in the bytes->MB code)
[a href="index.php?act=findpost&pid=269053"][{POST_SNAPBACK}][/a]

That doesn't seem to work,it just stays at zero, i added this to it

Code: [Select]

$div($muldiv(%_filesize%,%time_elapsed_seconds%,%time_total_seconds),1048576)

i think i've had too much caffiene because this one seems to work

Code: [Select]

$left($div($mul($muldiv(%__bitrate%,1000,8),%_time_elapsed_seconds%),1048576),2).$right($div($mul($muldiv(%__bitrate%,1000,8),%_time_elapsed_seconds%),10485.76),2)

foo_uie_trackinfo

Reply #184 – 2005-01-29 02:40:39

Quote

2. $if($and(%__mp3_stereo_mode%,$not(%__extrainfo%)),MP3 CBR,OTHER)
[a href="index.php?act=findpost&pid=269059"][{POST_SNAPBACK}][/a]

Thanks that works a treat

Code: [Select]

'AVG Bitrate: '$get(c_t1b)%__bitrate% kbps
$if($and(%__mp3_stereo_mode%,$not(%__extrainfo%)),$char(10),$if(%__bitrate_dynamic%,$char(10)'VBR Bitrate: '$get(c_t1b)%__bitrate_dynamic% kbps,) $char(10))

Whoops, i should have just edited my post above, sorry.

foo_uie_trackinfo

Reply #185 – 2005-01-29 02:43:11

edit: nevermind (you sorted it out on your own)

foo_uie_trackinfo

Reply #186 – 2005-01-29 03:03:18

Quote

1. %_time... instead of %time... and one % is missing
[a href="index.php?act=findpost&pid=269066"][{POST_SNAPBACK}][/a]

ahh, now it works,

Code: [Select]

$div($muldiv(%_filesize%,%_time_elapsed_seconds%,%_time_total_seconds%),1048576)

this does the same as the one i made, either one or the other is out by a little bit

Code: [Select]

$left($div($muldiv(%_filesize%,%_time_elapsed_seconds%,%_time_total_seconds%),1048576),2).$right($div($muldiv(%_filesize%,%_time_elapsed_seconds%,%_time_total_seconds%),10485.76),2)

Thanks for your help

foo_uie_trackinfo

Reply #187 – 2005-01-29 08:35:58

Ooops.

@MrEnergizer
No problem. Thanks.

foo_uie_trackinfo

Reply #188 – 2005-01-29 11:51:58

Quote

New version:

Code: [Select]

'Album: '$get(c_t1b)$replace($meta(album),'(',$get(c_3)'(',')',')'$get(c_t1b),'[',$get(c_3)'[',']',']'$get(c_t1b))FFFFFF|FFFFFF$if(%disc%,' (Disc '%disc%')',$ifgreater($len($tracknumber()),2,' (Disc '$left($tracknumber(),1)')',))[' '''$meta(discname)'']$char(10)

[a href="index.php?act=findpost&pid=267930"][{POST_SNAPBACK}][/a]

Thank you very much, it works flawlessly.

foo_uie_trackinfo

Reply #189 – 2005-01-31 04:34:53

how can i get strings to truncate with ... instead of continuing on the next line. i made it happen once but i dont know how.

foo_uie_trackinfo

Reply #190 – 2005-01-31 04:55:30

A couple of pages back:
http://www.hydrogenaudio.org/forums/index....ndpost&p=263954

Its not a perfect solution though.

foo_uie_trackinfo

Reply #191 – 2005-01-31 05:23:40

Quote

A couple of pages back:
http://www.hydrogenaudio.org/forums/index....ndpost&p=263954

Its not a perfect solution though.
[a href="index.php?act=findpost&pid=269592"][{POST_SNAPBACK}][/a]

nope, not with non fixt width characters. but i used $rep(38,W) to get a figure for the wrapping and it works perfect. i only have 3 lines that would have strings over 38 chars neways.

thx man

foo_uie_trackinfo

Reply #192 – 2005-01-31 21:54:46

Phi: I started using ColumnsUI about two weeks ago and it was lacking something until I tried this component. It works awesome, just what I needed! Thanks.

foo_uie_trackinfo

Reply #193 – 2005-02-01 08:45:25

foo_uie_trackinfo

Reply #194 – 2005-02-01 09:39:29

Quote

i created a little string for the info box today that i think looks pretty sweet. i made it easy enough to configure the colors and such. i might work on it a bit more latter but for the most part i think its finished. tell me what u guys think.

Code: [Select]


//////////////////////////////////////////////////////////////////////////////////////////////
////  About:
////  A simple formatting script for foo_uie_trackinfo. 
////  It will work with the following tags:
////  %RATING%, %PLAY_COUNTER%, %PLAY_TIME%, 
////  %LABEL% and/or %PUBLISHER%.
////  Best viewed in Arial 8pt Bold
////  Created by: korsairr@cogeco.ca
////  Date: Jan 31, 2005
/////////////////////////////////////////////////////////////////////////////////////////////

////////////////////////////////
//Colors, etc.
////////////////////////////////

$puts(default_color,d4d4d4)
$puts(rating_color_1,5357EF)
$puts(rating_color_2,042573)
$puts(rating_symbol,♫)
$puts(is_playing_color,5357EF)
$puts(tag_missing_color,757575)
$puts(heading_color_l,ffb00d)
$puts(heading_color_r,000000)
$puts(is_playing_color,5357EF)

////////////////////////////////
//Code
////////////////////////////////


////////////////////////////////
///////Song Info
////////////////////////////////
$transition(----- Song Info ----------------------------------------,$get(heading_color_l),$get(heading_color_r))

$char(10)$get(default_color) 

$if(%title%,$if(%_isplaying%,
$get(is_playing_color)$iflonger(%title%,36,$cut(%title%,33)...,%title%),
$iflonger(%title%,36,$trim($cut(%title%,33))...,%title%)),
$if(%_isplaying%,
$get(is_playing_color)$iflonger(%_filename_ext%,36,$cut(%_filename_ext%,33)...,%_filename_ext%),
$iflonger(%_filename_ext%,36,$trim($cut(%_filename_ext%,33))...,%_filename_ext%)))

$char(10)$get(default_color)  

$if(%artist%,
$iflonger(%artist%,36,$cut(%artist%,33)...,%artist%),
$get(tag_missing_color)no artist info)

$char(10)$get(default_color)  

$if(%album%,
$iflonger(%album%,36,$cut(%album%,33)...,%album%),
$get(tag_missing_color)no album info)

$char(10)$get(default_color)  

$if($or(%publisher%.%label%,%date%),$if($or(%publisher%,%label%),© ,)%date%$if($or(%publisher%,%label%),'. ',)[%publisher% ][label],
$get(tag_missing_color)no date or copyright info)

$char(10)$get(default_color)  

$if(%rating%,
$repeat($get(rating_color_1)$get(rating_symbol) ,%rating%)$repeat($get(rating_color_2)$get(rating_symbol) ,$sub(5,%rating%)) ,)
$get(default_color)$if(%genre%,%genre%,$get(tag_missing_color)no genre info)

$char(10)$char(10)

////////////////////////////////
///////Statistics
////////////////////////////////

$transition(----- Statistics -----------------------------------------,$get(heading_color_l),$get(heading_color_r))

$char(10)$get(default_color)  

$if(%play_date%,
$puts(month,$left(%play_date%,2))
$puts(day,$substr(%play_date%,4,5))
$puts(year,$right(%play_date%,2))
$puts(month_name,$select($get(month),
Jan,Feb,March,April,May,June,July,Aug,Sept,Oct,Nov,Dec))
$if($strcmp($right($get(day),1),1),$puts(xx,st),
$if($strcmp($right($get(day),1),2),$puts(xx,nd),
$if($strcmp($right($get(day),1),3),$puts(xx,rd),
$puts(xx,th)))))
$puts(time_of_year,$get(month_name) $get(day)$get(xx) 20$get(year))

$if(%play_counter%,Played $if($strcmp(%play_counter%,1),
once','$if(%play_date%, on $get(time_of_year)),
%play_counter% times$if(%play_date%,
$char(10)  Last played on $get(time_of_year))),This song has not played before)

$ifgreater(%play_counter%,1,,$char(10))

$char(10)$char(10)

////////////////////////////////
///////Tech Info
////////////////////////////////

$transition(----- Tech Info -----------------------------------------,$get(heading_color_l),$get(heading_color_r))

$char(10)$get(default_color)  

%__codec% 
$if(%__bitrate_dynamic%,%__bitrate_dynamic%,%__bitrate%)kbps 
$if($stricmp(%__codec%,mp3),$if($stricmp(%__extrainfo%,vbr),VBR,CBR)) 
$if($strcmp(%__channels%,1),Mono,Stereo)

$char(10)$get(default_color)  

[%_time_elapsed%/][%_length%][  -%_time_remaining%]
$if(%_isplaying%,  
$muldiv(%_time_elapsed_seconds%,100,%_time_total_seconds%)'%',)  
$div(%_filesize%,1048576).
$left($num($muldiv($mod(%_filesize%,1048576),1000,1048576),3),2)' MB'

$char(10)$get(default_color)  

$if($or(%__replaygain_track_gain%,%__replaygain_album_gain%),
['['Tg']' %__replaygain_track_gain% ]['['Ag']' %__replaygain_album_gain%],
$get(tag_missing_color)there is no gain)

[a href=\"index.php?act=findpost&pid=269971\"][{POST_SNAPBACK}][/a]

Can we sue you for not using codebox?
Good config if you ask me, still a few things to iron out imo:
- a little bug in the counter (played once,)
- I think you should use variables for the pannel width, instead of 33 and 36, because everyone uses a different one.
- There are no separator between codec, bitrate and channels, is it intentional?
- $if($strcmp(%__channels%,1),Mono,Stereo) isn't AC3 5.1 friendly... Edit: I'd use $if($stricmp($codec(),MP3),%__mp3_stereo_mode%,$channels())

foo_uie_trackinfo

Reply #195 – 2005-02-01 10:06:16

Quote

Can we sue you for not using codebox?
Good config if you ask me, still a few things to iron out imo:
- a little bug in the counter (played once,)
- I think you should use variables for the pannel width, instead of 33 and 36, because everyone uses a different one.
- There are no separator between codec, bitrate and channels, is it intentional?
- $if($strcmp(%__channels%,1),Mono,Stereo) isn't AC3 5.1 friendly... Edit: I'd use $if($stricmp($codec(),MP3),%__mp3_stereo_mode%,$channels())
[a href="index.php?act=findpost&pid=269983"][{POST_SNAPBACK}][/a]

I didnt any seperators because im using a small window. the comma is not a typo, its to emphasize the track was played once. not once on that day. i will get around to making it size friendly soon, and ive already replaced your codec string

btw i didnt know about [ / codebox] thanks for the heads up.

Edit: you can now specify a size for the infobox.

foo_uie_trackinfo

Reply #196 – 2005-02-01 10:24:15

Quote

the comma is not a typo, its to emphasize the track was played once. not once on that day.[a href="index.php?act=findpost&pid=269992"][{POST_SNAPBACK}][/a]

Oh ok, it's because I use only the %playcounter% tag, so it's all I can see in the stats section, perhaps you could include the comma into $if(%play_date%
Besides that, I like the layout, good work.

foo_uie_trackinfo

Reply #197 – 2005-02-01 10:32:50

Quote

Quote
the comma is not a typo, its to emphasize the track was played once. not once on that day.[a href="index.php?act=findpost&pid=269992"][{POST_SNAPBACK}][/a]

Oh ok, it's because I use only the %playcounter% tag, so it's all I can see in the stats section, perhaps you could include the comma into $if(%play_date%
Besides that, I like the layout, good work.
[a href="index.php?act=findpost&pid=269996"][{POST_SNAPBACK}][/a]

i see what you mean now. i didnt notice i left that in there if there is no play time. fixt

foo_uie_trackinfo

Reply #198 – 2005-02-03 16:52:34

Quote

Hey guys,

I did another code for track info panel. Highly customizeable I guess. Look at the config part.

Code: [Select]

// Highly customizeable track information made by Lycox

// Credits:
// Peter Pawlowski for great fb2k
// Free - for great progressbar
// upNorth - for filesize string
// Looks quite good with Arial, 8pt bold

// ==============================================
// Global Config Part //

// Shows Song Info in track info panel
// 0 = No, 1 = Yes
$puts(show_songinfo,1)

// Show various informations in Song Info
// 0 = No, 1 = Yes
$puts(title,1)
$puts(artist,1)
$puts(mixartist,1)
$puts(band,1)
$puts(album,1)
$puts(tracknumber,1)
$puts(genre,1)
$puts(bpm,1)
$puts(date,1)
$puts(copyright,1)


// Shows Additional Info in track info panel
// 0 = No, 1 = Yes
$puts(show_additionalinfo,1)

// Show various informations in Additional Info
// 0 = No, 1 = Yes
$puts(comment,1)
$puts(wwwartist,1)
$puts(publisher,1)
$puts(language,1)
$puts(composer,1)
$puts(lyricist,1)
$puts(conductor,1)
$puts(recordingdates,1)
$puts(fileowner,1)


// Shows Technical Info in track info panel
// 0 = No, 1 = Yes
$puts(show_techinfo,1)

// Show various informations in Tech Info
// 0 = No, 1 = Yes
$puts(codec,1)
$puts(bitrate,1)
$puts(samplerate,1)
$puts(channels,1)
$puts(time_elapsed_total,1)
$puts(trackgain,1)
$puts(albumgain,1)
$puts(rating,1)
$puts(play_counter,1)
$puts(play_date,1)
$puts(encodedby,1)
$puts(encodersettings,1)
$puts(filesize,1)
// hidden, because not really needed
$puts(filename_ext,0)
$puts(mediatype,0)
$puts(size,0)
$puts(songlen,0)
$puts(time,0)


// Shows Web Info in track info panel
// 0 = No, 1 = Yes
$puts(show_webinfo,1)

// Shows Web Related Infos in Web Info
// 0 = No, 1 = Yes
$puts(show_webrelated,1)

// Show various informations in Web Info
// 0 = No, 1 = Yes
$puts(wwwaudiofile,1)
$puts(wwwcopyright,1)
$puts(wwwcommercialinfo,1)
$puts(wwwpayment,1)
$puts(wwwpublisher,1)
$puts(wwwuser,1)

// Shows NetRadio Info in Web Info
// 0 = No, 1 = Yes
$puts(show_netradioinfo,1)

// Show various informations in NetRadio Info
// 0 = No, 1 = Yes
$puts(wwwradiopage,1)
$puts(netradioowner,1)
$puts(netradiostation,1)


// Shows Misc Info in track info panel
// 0 = No, 1 = Yes
$puts(show_miscinfo,1)

// Show various informations in Misc Info
// 0 = No, 1 = Yes
$puts(subtitle,1)
$puts(involvedpeople,1)
$puts(playlistdelay,0)
$puts(initialkey,0)
$puts(isrc,0)
$puts(partinset,0)


// Shows Original Info in track info panel
// 0 = No, 1 = Yes
$puts(show_originalinfo,1)

// Show various informations in Original Info
// 0 = No, 1 = Yes
$puts(origartist,1)
$puts(origyear,1)
$puts(origlyricist,1)
$puts(origfilename,1)

// Spacer
$puts(spacer,d6d6d6------------------------------------------------------------------------------------------$char(10))

// color codes
$puts(headline,256d3d)
$puts(info,ec9184)
$puts(text,000000)
$puts(grayed,c8c8c8)

// chars
$puts(rating_char,♪)
$puts(progress_char,●)

// End Global Config
// ==============================================


DCAE8DMode: %_trackinfo_mode%$char(10)$if(%_trackinfo_notrack%,No track,

// progressbar config
$puts(theme,1)
$puts(progress_length,18)

$if($strcmp($get(theme),1),
$puts(progress_color1,ff6d66)
$puts(progress_color2,ffe1df)
)


// PREPARE COLOR-STRINGS
// =========================================
$puts(progress_color1a,$blend($get(progress_color1),000000,1,4.5))
$puts(progress_color2a,$blend($get(progress_color2),000000,1,5.7))
// progressbar
$puts(progressbar,
$if(%_length_seconds%,

$puts(progress,$muldiv(%_time_elapsed_seconds%,$get(progress_length),%_length_seconds%))
$transition($repeat($get(progress_char),$get(progress)),$get(progress_color1a),$get(progress_color1))
$transition($repeat($get(progress_char),$sub($get(progress_length),$get(progress))),$get(progress_color2a),$get(progress_color2))
$pad_right($muldiv(%_time_elapsed_seconds%,100,%_length_seconds%),3)'%'
,streaming...
))

$get(progressbar))$char(10)

// Song Info
$if($strcmp(1,$get(show_songinfo)),
$get(spacer)
$char(1)C$get(headline)Song Info$char(10)
$if($strcmp(1,$get(title)),$get(info)Title: $get(text)$if(%title%,%title%,$get(grayed)'['No Title']')$char(10))
$if($strcmp(1,$get(artist)),$get(info)Artist: $get(text)$if(%artist%,%artist%,$get(grayed)'['Unknown Artist']')$char(10))
$if($strcmp(1,$get(mixartist))
	|$strcmp(1,$get(band))
	,
$if($strcmp(1,$get(mixartist)),$if(%mixartist%,$get(info)MixArtist: $get(text)%mixartist%$char(10)))
$if($strcmp(1,$get(band)),$if(%band%,$get(info)Band: $get(text)%band%$char(10))))
$if($strcmp(1,$get(album)),$if(%album%,$get(info)Album: $get(text)%album%$char(10)))
$if($strcmp(1,$get(tracknumber)),$if(%tracknumber%,$get(info)Track: $get(text)%tracknumber%$char(10)))
$if($strcmp(1,$get(genre)),$if(%genre%,$get(info)Genre: $get(text)%genre%$char(10)))
$if($strcmp(1,$get(bpm)),$if(%bpm%,$get(info)bpm: $get(text)%bpm%$char(10)))
$if($strcmp(1,$get(date)),$if(%date%,$get(info)Date: $get(text)%date%$char(10)))
$if($strcmp(1,$get(copyright)),$if(%copyright%,$get(info)© $get(text)%copyright%$char(10)))
)
// End Song Info

// Additional Info
$if($strcmp(1,$get(show_additionalinfo)),
$if($if(%comment%,$and($strcmp(1,$get(comment))))
	|$if(%wwwartist%,$and($strcmp(1,$get(wwwartist))))
	|$if(%publisher%,$and($strcmp(1,$get(publisher))))
	|$if(%language%,$and($strcmp(1,$get(language))))
	|$if(%composer%,$and($strcmp(1,$get(composer))))
	|$if(%lyricist%,$and($strcmp(1,$get(lyricist))))
	|$if(%conductor%,$and($strcmp(1,$get(conductor))))
	|$if(%recordingdates%,$and($strcmp(1,$get(recordingdates))))
	|$if(%fileowner%,$and($strcmp(1,$get(fileowner))))
,$get(spacer)
$char(1)C$get(headline)Additional Info$char(10)
$if($strcmp(1,$get(comment)),$if(%comment%,$get(info)Comment: $get(text)%comment%$char(10)))
$if($strcmp(1,$get(wwwartist)),$if(%wwwartist%,$get(info)Web: $get(text)%wwwartist%$char(10)))
$if($strcmp(1,$get(publisher)),$if(%publisher%,$get(info)Publisher: $get(text)%publisher%$char(10)))
$if($strcmp(1,$get(language)),$if(%language%,$get(info)Language: $get(text)%language%$char(10)))
$if($strcmp(1,$get(composer)),$if(%composer%,$get(info)Composer: $get(text)%composer%$char(10)))
$if($strcmp(1,$get(lyricist)),$if(%lyricist%,$get(info)Lyricist: $get(text)%lyricist%$char(10)))
$if($strcmp(1,$get(conductor)),$if(%conductor%,$get(info)Conductor: $get(text)%conductor%$char(10)))
$if($strcmp(1,$get(contentgroup)),$if(%contentgroup%,$get(info)Group: $get(text)%contentgroup%$char(10)))
$if($strcmp(1,$get(recordingdates)),$if(%recordingdates%,$get(info)Rec. Date: $get(text)%recordingdates%$char(10)))
$if($strcmp(1,$get(fileowner)),$if(%fileowner%,$get(info)Owner: $get(text)%fileowner%$char(10)))
))
// End Additional Info

// Tech Info
$if($strcmp(1,$get(show_techinfo)),
$get(spacer)
$char(1)C$get(headline)Tech Info$char(10)
$if($strcmp(1,$get(codec)),$get(info)Codec: $get(text)%__codec%$char(10))
$if($strcmp(1,$get(bitrate)),$get(info)Bitrate: $get(text)%__bitrate% Kbit/s$char(10))
$if($strcmp(1,$get(samplerate)),$get(info)Samplerate: $get(text)%__samplerate% Hz$char(10))
$if($strcmp(1,$get(channels)),$get(info)Channels: $get(text)$if(%__channels%,$ifgreater(%__channels%,2,%__channels%ch,$ifgreater(%__channels%,1,' 'Stereo,''Mono)),)$char(10))
$if($strcmp(1,$get(time_elapsed_total)),$get(info)Time: $get(text)%_time_elapsed% / %_time_total%$char(10))

$puts(size,5)
$if($strcmp(1,$get(trackgain)),$if(%__replaygain_track_gain%,$get(info)RG Track: $get(text)$cut(%__replaygain_track_gain%,$get(size)) dB$char(10)))
$if($strcmp(1,$get(albumgain)),$if(%__replaygain_album_gain%,$get(info)RG Album: $get(text)$cut(%__replaygain_album_gain%,$get(size)) dB$char(10)))

$puts(rating,1)
$puts(_rating,$repeat($get(rating_char),%rating%))
$if($strcmp(1,$get(rating)),$if(%rating%,$get(info)Rating: $get(text) $get(_rating) $get(grayed)'('%rating%')'$char(10)))

$if($strcmp(1,$get(play_counter)),$if(%play_counter%,$get(info)Played $get(text)%play_counter%$get(info) times.$char(10)))
$if($strcmp(1,$get(play_date)),$if(%play_date%,$get(info)Last played: $get(text)%play_date%$char(10)))
$if($strcmp(1,$get(encodedby)),$if(%encodedby%,$get(info)Encoded by: $get(text)%encodedby%$char(10)))
$if($strcmp(1,$get(encodersettings)),$if(%encodersettings%,$get(info)Encoder Settings: $get(text)%encodersettings%$char(10)))

// formating filesize string by upNorth
$if($strcmp(1,$get(filesize)),$get(info)Filesize: $get(text)$div(%_filesize%,1048576).$left($num($muldiv($mod(%_filesize%,1048576),1000,1048576),3),2)' MB'$char(10))
$if($strcmp(1,$get(filename_ext)),$get(info)File: $get(text)%_filename_ext%$char(10))
$if($strcmp(1,$get(mediatype)),$if(%mediatype%,$get(info)Mediatype: $get(text)%mediatype%$char(10)))
$if($strcmp(1,$get(size)),$if(%size%,$get(info)Size: $get(text)%size%$char(10)))
$if($strcmp(1,$get(songlen)),$if(%songlen%,$get(info)Length: $get(text)%songlen%$char(10)))
$if($strcmp(1,$get(time)),$if(%time%,$get(info)Time: $get(text)%time%$char(10)))
)
// End Tech Info

// Web Info
$if($strcmp(1,$get(show_webinfo)),
$if($if(%wwwaudiofile%,$and($strcmp(1,$get(wwwaudiofile))))
	|$if(%wwwcopyright%,$and($strcmp(1,$get(wwwcopyright))))
	|$if(%wwwcommercialinfo%,$and($strcmp(1,$get(wwwcommercialinfo))))
	|$if(%wwwpayment%,$and($strcmp(1,$get(wwwpayment))))
	|$if(%wwwpublisher%,$and($strcmp(1,$get(wwwpublisher))))
	|$if(%wwwuser%,$and($strcmp(1,$get(wwwuser))))
	|$if(%wwwradiopage%,$and($strcmp(1,$get(wwwradiopage))))
	|$if(%netradioowner%,$and($strcmp(1,$get(netradioowner))))
	|$if(%netradiostation%,$and($strcmp(1,$get(netradiostation))))
,$get(spacer)

// Web Related
$if($strcmp(1,$get(show_webrelated)),
$if($if(%wwwaudiofile%,$and($strcmp(1,$get(wwwaudiofile))))
	|$if(%wwwcopyright%,$and($strcmp(1,$get(wwwcopyright))))
	|$if(%wwwcommercialinfo%,$and($strcmp(1,$get(wwwcommercialinfo))))
	|$if(%wwwpayment%,$and($strcmp(1,$get(wwwpayment))))
	|$if(%wwwpublisher%,$and($strcmp(1,$get(wwwpublisher))))
	|$if(%wwwuser%,$and($strcmp(1,$get(wwwuser))))
	,
$char(1)C$get(headline)Web Info$char(10)
$if($strcmp(1,$get(wwwaudiofile)),$if(%wwwaudiofile%,$get(info)File: $get(text)%wwwaudiofile%$char(10)))
$if($strcmp(1,$get(wwwcopyright)),$if(%wwwcopyright%,$get(info)© $get(text)%wwwcopyright%$char(10)))
$if($strcmp(1,$get(wwwaudiosource)),$if(%wwwaudiosource%,$get(info)Source: $get(text)%wwwaudiosource%$char(10)))
$if($strcmp(1,$get(wwwcommercialinfo)),$if(%wwwcommercialinfo%,$get(info)Info: $get(text)%wwwcommercialinfo%$char(10)))
$if($strcmp(1,$get(wwwpayment)),$if(%wwwpayment%,$get(info)Payment: $get(text)%wwwpayment%$char(10)))
$if($strcmp(1,$get(wwwpublisher)),$if(%wwwpublisher%,$get(info)Publisher: $get(text)%wwwpublisher%$char(10)))
$if($strcmp(1,$get(wwwuser)),$if(%wwwuser%,$get(info)User: $get(text)%wwwuser%$char(10)))
$char(10))
)
// End Web Info

// Net Radio Ifno
$if($strcmp(1,$get(show_netradioinfo)),

$if($if(%wwwradiopage%,$and($strcmp(1,$get(wwwradiopage))))
	|$if(%netradioowner%,$and($strcmp(1,$get(netradioowner))))
	|$if(%netradiostation%,$and($strcmp(1,$get(netradiostation))))
,$char(1)C$get(headline)NetRadio Info$char(10)
$if($strcmp(1,$get(wwwradiopage)),$if(%wwwradiopage%,$get(info)Page: $get(text)%wwwradiopage%$char(10)))
$if($strcmp(1,$get(netradioowner)),$if(%netradioowner%,$get(info)Owner: $get(text)%netradioowner%$char(10)))
$if($strcmp(1,$get(netradiostation)),$if(%netradiostation%,$get(info)Station: $get(text)%netradiostation%$char(10))))
)))
// End - Web Related

// Misc Info
$if($strcmp(1,$get(show_miscinfo)),
$if($if(%subtitle%,$and($strcmp(1,$get(subtitle))))
	|$if(%involvedpeople%,$and($strcmp(1,$get(involvedpeople))))
	|$if(%playlistdelay%,$and($strcmp(1,$get(playlistdelay))))
	|$if(%initialkey%,$and($strcmp(1,$get(initialkey))))
	|$if(%isrc%,$and($strcmp(1,$get(isrc))))
	|$if(%partinset%,$and($strcmp(1,$get(partinset))))
,$get(spacer)
$char(1)C$get(headline)Misc Info$char(10)
$if($strcmp(1,$get(subtitle)),$if(%subtitle%,$get(info)Subtitle: $get(text)%subtitle%$char(10)))
$if($strcmp(1,$get(involvedpeople)),$if(%involvedpeople%,$get(info)Involved People: $get(text)%involvedpeople%$char(10)))
$if($strcmp(1,$get(playlistdelay)),$if(%playlistdelay%,$get(info)Playlistdelay: $get(text)%playlistdelay%$char(10)))
$if($strcmp(1,$get(initialkey)),$if(%initialkey%,$get(info)Initialkey: $get(text)%initialkey%$char(10)))
$if($strcmp(1,$get(isrc)),$if(%isrc%,$get(info)ISRC: $get(text)%isrc%$char(10)))
$if($strcmp(1,$get(partinset)),$if(%partinset%,$get(info)Partinset: $get(text)%partinset%$char(10)))
))
// End Misc Info

// Original Info
$if($strcmp(1,$get(show_originalinfo)),
$if($if(%origartist%,$and($strcmp(1,$get(origartist))))
	|$if(%origyear%,$and($strcmp(1,$get(origyear))))
	|$if(%origlyricist%,$and($strcmp(1,$get(origlyricist))))
	|$if(%origfilename%,$and($strcmp(1,$get(origfilename))))
,$get(spacer)
$char(1)C$get(headline)Original Info$char(10)
$if($strcmp(1,$get(origartist)),$if(%origartist%,$get(info)Artist: $get(text)%origartist%$char(10)))
$if($strcmp(1,$get(origyear)),$if(%origyear%,$get(info)Year: $get(text)%origyear%$char(10)))
$if($strcmp(1,$get(origlyricist)),$if(%origlyricist%,$get(info)Lyricist: $get(text)%origlyricist%$char(10)))
$if($strcmp(1,$get(origfilename)),$if(%origfilename%,$get(info)Filename: $get(text)%origfilename%$char(10)))
))

Screenshot:

Let me know what you think about it (and any bugs too).
Lycox

moderation: changed [ code ] into [ codebox ]
[a href=\"index.php?act=findpost&pid=266314\"][{POST_SNAPBACK}][/a]

i used your code but no info show. What i made wrong?? And when i use UpNorth code everything works fine:)

foo_uie_trackinfo

Reply #199 – 2005-02-03 17:52:08

Hmm it seems to work for me, are you sure you copied the whole stuff?
A little thing though, there are a couple of unnecessary quotation marks at:
$if($strcmp(1,$get(channels)),$get(info)Channels: $get(text)$if(%__channels%,$ifgreater(%__channels%,2,%__channels%ch,$ifgreater(%__channels%,1,' 'Stereo,''Mono)),)$char(10))

Notice