Issue #1: Text Color
Above, all we played around with were the background colors, but text color can be manipulated very similarly.
Pick some colors and add them to your global variables like we did before:
// Text
$set_global(color.txt.single,$rgb(0,0,0))
$set_global(color.txt.album,$rgb(0,0,0))
$set_global(color.txt.playing,$rgb(233,233,233))
$set_global(color.txt.selected,$rgb(233,233,233))
// Backgrounds
$set_global(color.bg.single,$rgb(166,202,240))
$set_global(color.bg.album,$rgb(140,186,236))
$set_global(color.bg.playing,$rgb(58,110,165))
$set_global(color.bg.selected,$rgb(10,36,106))
A note about the style tab, the code in there is the default code which you can see the effect of in your existing "number" column. We are overriding these settings with our display style. When you have everything set up the way you like you may want to clear out the style tab, or you may wish to leave it as the default for any future columns. Or, you can copy/paste one of the individual column style tabs into the global style tab so that your new settings become the default for all columns.
Basically, all columns use the style defined in the global style tab unless you check the box for "use custom style spec" for the column.. in which case it uses the style defined in it's own tab.
Now that we have defined some text colors we need to go back to the column style tabs and set the styles to use the colors. Similar to before we can add code like this:
// Text
$set_style(text,
$if(%isplaying%,$get_global(color.txt.playing),
$if(%tracknumber%,$get_global(color.txt.album),$get_global(color.txt.single))
),
$get_global(color.txt.selected)
)
// Backgrounds
$set_style(back,
$if(%isplaying%,$get_global(color.bg.playing),
$if(%tracknumber%,$get_global(color.bg.album),$get_global(color.bg.single))
),
$get_global(color.bg.selected)
)
Issue #2: Number 77
I suspect the reason item number 77 is appearing with a lighter color is because the code I have given includes the ability to color tracks differently depending on wether or not they have a track number defined in their tag. Right click on number 77 and select properties, I think you will find that it has no track number. The reason I did this is because with a proper sorting string you can group tracks together that belong to albums and have those albums colored differently to set them apart from loose single tracks. Many people use this method and I am actually helping another user accomplish that.
If you do not wish to utilize this behavior replace the lines of code that look like this:
$if(%tracknumber%,$get_global(color.bg.album),$get_global(color.bg.single))
with something that simply sets the color like this:
$get_global(color.bg.single)
or if you like the alternating line colors like the default style:
$ifequal($mod(%_playlist_number%,2),0,$get_global(color.bg.single),$get_global(color.bg.album))
As always feel free to change those colors to anything you like, the colors I have given you are from a blue color scheme I used before I switchd to foo_uie_single_column_playlist.. because that's the code I have laying around in my columnsui playlist config.