Skip to main content

Notice

Please note that most of the software linked on this forum is likely to be safe to use. If you are unsure, feel free to ask in the relevant topics, or send a private message to an administrator or moderator. To help curb the problems of false positives, or in the event that you do find actual malware, you can contribute through the article linked here.
Topic: REACT 2 Released (Read 1264787 times) previous topic - next topic
0 Members and 1 Guest are viewing this topic.

REACT 2 Released

Reply #50
The line sets both the BAND and a custom user text field with "album artists" as description to "Various", when and only when the CD is Various Artists. The v2.0 Final adds a key VA in the REACT.ini file (default VA=Various Artists). This will be the value of @cdartist@ for VA albums, otherwise @cdartist@ equals @artist@. I.e. you won't need the "set AlbumArtist" lines in the final release, but for now I believe you will.

If I don't want BAND set do I just remove VA_tag_MP3=--frame TPE2:$q$cdartist$$q? I only want to use this field for classical recordings and would prefer it be blank for nonclassical for query purposes. Thanks.

REACT 2 Released

Reply #51
Correct.

REACT 2 Released

Reply #52
I have found React 2 to work flawlessly.  I just have a couple of questions.  Just for background, I am encoding flac and Lame tracks. 

1. Can you explain the default settings for replay gain int the tracks config.  I am pretty sure that album replay gain is applied.  Is this correct?  Is the gain adjusted +3db and what is the advantage of doing this?

2.  When I looked at my flac files with foobar the cover art was present.  I did not see cover art when playing mp3 files with foobar.  I added a section to copy the cover art to my mp3/artist/album folder (see below).  Is this necessary?  Why was cover art not present orginally?  Thanks for your hard work. This really makes ripping and multiformat encoding much easier. 

Code: [Select]
if %LameMP3%==1 (
pushd "%MP3_TrackDir%"
copy "@eaclog@" "EAClog.txt"
if %add_meta%==1 @tools@\metamp3.exe %MetaMP3_RG% %MetaMP3_cover% *.mp3
if %add_cover%==1 copy "@cover@" "folder.jpg"
popd

REACT 2 Released

Reply #53
2.  When I looked at my flac files with foobar the cover art was present.  I did not see cover art when playing mp3 files with foobar.  I added a section to copy the cover art to my mp3/artist/album folder (see below).  Is this necessary?  Why was cover art not present orginally?  Thanks for your hard work. This really makes ripping and multiformat encoding much easier. 

Code: [Select]
if %LameMP3%==1 (
pushd "%MP3_TrackDir%"
copy "@eaclog@" "EAClog.txt"
if %add_meta%==1 @tools@\metamp3.exe %MetaMP3_RG% %MetaMP3_cover% *.mp3
if %add_cover%==1 copy "@cover@" "folder.jpg"
popd
foo_uie_albumart does not support embedded album art which is what the default REACT settings provide. What you have now should embed an image and copy folder.jpg to the album's directory.

REACT 2 Released

Reply #54
Quote
1. Can you explain the default settings for replay gain int the tracks config. I am pretty sure that album replay gain is applied. Is this correct? Is the gain adjusted +3db and what is the advantage of doing this?

Yes, on MP3's and M4A's, album gain is *applied*, and adjusted by +3dB to 93dB. I do this because it gives a consistent loudness between the albums. The +3dB is done because it increases the volume of my iPod a little, so I don't have to put the volume near max. Setting volme to (near) max, increases noise and distortions.

REACT 2 Released

Reply #55
I keep running into issues and I think it's some conflicting app but haven't figured out which one. This time around I was ripping Ottmar Liebert's "Poets & Angels". Debug showed that it couldn't create the album directory, apparently because of the ampersand. I don't recall having this probelm before.

Also, with both computers, I'm getting duplicate comments.

Lastly, on the "good" PC
Code: [Select]
IF @various@==1 SET --user-text $q[album artist]@cdartist@$q

doesn't set the Album Artist field at all.

REACT 2 Released

Reply #56
Lastly, on the "good" PC
Code: [Select]
IF @various@==1 SET --user-text $q[album artist]@cdartist@$q

doesn't set the Album Artist field at all.
I haven't really been following all this, but the above looks horribly wrong.  I think you are after something like:

Code: [Select]
IF @various@==1 SET userText=--user-text $q[album artist]@cdartist@$q
...
FLAC.EXE ... %userText% ...

This will include --user-text $q[album artist]@cdartist@$q in your FLAC command line, only if the album is VA.
I'm on a horse.

 

REACT 2 Released

Reply #57
Lastly, on the "good" PC
Code: [Select]
IF @various@==1 SET --user-text $q[album artist]@cdartist@$q

doesn't set the Album Artist field at all.
I haven't really been following all this, but the above looks horribly wrong.  I think you are after something like:

Code: [Select]
IF @various@==1 SET userText=--user-text $q[album artist]@cdartist@$q
...
FLAC.EXE ... %userText% ...

This will include --user-text $q[album artist]@cdartist@$q in your FLAC command line, only if the album is VA.


Yes, that is part of the problem. However because there are no real quotes (") around the artist name (only $q), the '&' is taken to be DOS command separator, and it is therefore failing. I will try to release the final version without these problems. I've just  added the WaveGain + --scale features that martin H requested, so it should not be too far away.

REACT 2 Released

Reply #58
Lastly, on the "good" PC
Code: [Select]
IF @various@==1 SET --user-text $q[album artist]@cdartist@$q

doesn't set the Album Artist field at all.
I haven't really been following all this, but the above looks horribly wrong.  I think you are after something like:

Code: [Select]
IF @various@==1 SET userText=--user-text $q[album artist]@cdartist@$q
...
FLAC.EXE ... %userText% ...

This will include --user-text $q[album artist]@cdartist@$q in your FLAC command line, only if the album is VA.

I'm only doing MP3s with image.cfg (to get AG & TG).
Yes, that is part of the problem. However because there are no real quotes (") around the artist name (only $q), the '&' is taken to be DOS command separator, and it is therefore failing. I will try to release the final version without these problems. I've just  added the WaveGain + --scale features that martin H requested, so it should not be too far away.

Except this is the ALBUM field, not the ARTIST.

I may have found one more quirk. I have an AutoPlaylist to check for tracks missing TG (AG is assumed) and 2 tracks ripped with REACT 2 show up. Both are initials are just initials, S.O.S. and V.F.D.

REACT 2 Released

Reply #59
[...] I've just  added the WaveGain + --scale features that martin H requested [...]

Thank you very much tycho  I really appreciate it

CU, Martin.

REACT 2 Released

Reply #60
I'm only doing MP3s with image.cfg (to get AG & TG).
OK, sorry, I'm not familiar with the configs yet (no time to rip CDs).

The basic idea is that you use the line:

Code: [Select]
IF @various@==1 SET userText=--user-text $q[album artist]@cdartist@$q

.. and then add %userText% to whatever command line you are running, where the switch should appear (if relevant).

I guess this relies on tycho's amends to cope with command symbols, like ampersand, outside of quotes.
I'm on a horse.

REACT 2 Released

Reply #61
The basic idea is that you use the line:

Code: [Select]
IF @various@==1 SET userText=--user-text $q[album artist]@cdartist@$q

.. and then add %userText% to whatever command line you are running, where the switch should appear (if relevant).

I guess this relies on tycho's amends to cope with command symbols, like ampersand, outside of quotes.

I was hoping I could do something like
Code: [Select]
SET userText=--user-text $q[album artist]%AlbumArtist%$q

since AlbumArtist is set at the beginning of the config with
Code: [Select]
if @various@==0 set AlbumArtist=$cdartist$
if @various@==1 set AlbumArtist=Various Artists

but it doesn't seem to work.

REACT 2 Released

Reply #62
It should work, unless your variable AlbumArtist contains a command symbol (like "&") as previously discussed.

Code: [Select]
SET var1=fghij
SET var2=abcde%var1%klmno
ECHO %var2%

... should result in:

abcdefghijklmno
I'm on a horse.

REACT 2 Released

Reply #63
It should work, unless your variable AlbumArtist contains a command symbol (like "&") as previously discussed.

Code: [Select]
SET var1=fghij
SET var2=abcde%var1%klmno
ECHO %var2%

... should result in:

abcdefghijklmno

The ampersand problem was in the ALBUM not ARTIST. I tested this with a compilation and it didn't work for me. I'm a bit confused about the variables since cdartist uses @ and AlbumArtist uses % but not where it's being set.

REACT 2 Released

Reply #64
I'm a bit confused about the variables since cdartist uses @ and AlbumArtist uses % but not where it's being set.
The @ parts are REACT's.  They're more tokens, or placeholders, than variables.  Those tokens are replaced by actual values before your config even runs.

The % variables are true DOS variables.  In DOS you use SET myvar=x to set a variable, and %myvar% to retrieve the value of the variable.  You need to use these DOS variables in your config to execute conditionally, whereas the @ REACT tokens will only ever return the value that REACT sets for them.

Without seeing your whole config, and even then perhaps, I can't tell you why your code is not working.  I provided the code above to prove to you that the concept is correct.  If you save the following code as a bat file and double click it you will see it in action:

Code: [Select]
@ECHO OFF
SET AlbumArtist=Test Artist
SET userText=--user-text $q[album artist]%AlbumArtist%$q
ECHO %userText%
ECHO.
PAUSE

With this in mind something else must be adversely affecting your config.
I'm on a horse.

REACT 2 Released

Reply #65
If you save the following code as a bat file and double click it you will see it in action:

Code: [Select]
@ECHO OFF
SET AlbumArtist=Test Artist
SET userText=--user-text $q[album artist]%AlbumArtist%$q
ECHO %userText%
ECHO.
PAUSE
With this in mind something else must be adversely affecting your config.
This works as expected so I assume it's a config problem. Here's the entire config just in case.

Code: [Select]
@echo off
chcp 1252
title REACT - "@album@"


REM ================== USER SETTINGS ======================


rem ** To archive a CD as one large "image", you must set
rem ** ImageExt=... in the REACT.ini file (Press Alt-F2).
rem ** This will set the @imageext@ variable. Extensions
rem ** currently supported:  flac, wv, mp3. Set to 'wav'
rem ** for no image archiving (default).

REM ---- Enable/disable additional track formats:

rem ** Splits the wav-image into tracks during encoding, using ACDIR.
rem ** Flac requires flac.exe/metaflac.exe (v1.1.3)
rem ** NeroAac requires NeroAacEnc.exe/NeroAacTag.exe/AacGain.exe.
rem ** OggEnc2 requires OggEnc2.exe/VorbisGain.exe.

set Flac=0
set Wavpack=0
set LameMP3=1
set NeroAac=0
set OggEnc2=0

REM ---- General settings ----

set Debug=0

rem ** I prefer applying album gain 92dB to get a reasonable
rem ** volume for my DAP. The RG tags are still relative
rem ** to 89dB SPL, i.e. album gain will be about -3.0dB.

set ReplayGain=1
set ApplyMp3AacAlbumGain=1
set AdjustMp3AacAlbumGain_dB=+0.0

REM ---- Encoder options ----

set Flac_opt=-5 -f
set Wavpack_opt=-hmy
set LameMP3_opt=-V4 --vbr-new --noreplaygain --nohist
rem ** Nero LC-AAC @ ~ 90kbps - great for e.g. iPods:
set NeroAac_opt=-lc -q 0.22
set OggEnc2_opt=-q 3.0

set Flac_ver=1.1.3b2
set LameMP3_ver=3.97
set NeroAac_ver=1.0.0.2

REM ---- Output directories and track names ----

set OutRoot=H:\TAGZ

if @various@==0 set AlbumArtist=$cdartist$
if @various@==1 set AlbumArtist=Various Artists

rem ** Image dirs:
set Flac_ImageDir=%OutRoot%\Flac-Images\%AlbumArtist%
set Wavpack_ImageDir=%OutRoot%\Wavpack-Images\%AlbumArtist%
set MP3_ImageDir=%OutRoot%\MP3-Images\%AlbumArtist%

rem ** Track dirs:
set Flac_TrackDir=%OutRoot%\Flac\%AlbumArtist%\[$year$] $album$
set Wavpack_TrackDir=%OutRoot%\Wavpack\%AlbumArtist%\[$year$] $album$
REM set MP3_TrackDir=%OutRoot%\MP3\%AlbumArtist%\[$year$] $album$
set AAC_TrackDir=%OutRoot%\AAC\%AlbumArtist%\[$year$] $album$
set OGG_TrackDir=%OutRoot%\OGG\%AlbumArtist%\[$year$] $album$

REM set ** MP3_TrackDir
IF @various@==1 GOTO Various
REM CD is not VA
SET MP3_TrackDir=%OutRoot%\$cdartist$\$album$
GOTO Complete
:Various
IF @genre@==Soundtrack GOTO Soundtrack
REM CD is VA but not a soundtrack
SET MP3_TrackDir=%OutRoot%\Various Artists\Collections\$album$
GOTO Complete
:Soundtrack
REM CD is both VA and a soundtrack
SET MP3_TrackDir=%OutRoot%\Various Artists\Soundtracks\$album$
:Complete

rem ** Track names (for ACDIR):
if @various@==0 set TrackName=[$n] $~t
if @various@==1 set TrackName=[$n] $~t ($~a)


REM ============== BEGIN MAIN SCRIPT ==================


if %Debug%==1 echo on

set add_rg=%ReplayGain%
set add_meta=%add_rg%
set add_cover=0

if %ReplayGain%==0 goto end_RG
set Flac_RG=--replay-gain
set MetaFlac_RG=--add-replay-gain
set MetaMp3_RG=--replay-gain
:end_RG

if %ApplyMp3AacAlbumGain%==0 goto end_apply_AG
set AacGain_RG=/a /o /c /d %AdjustMp3AacAlbumGain_dB%
set MetaMP3_RG=--apply-gain album%AdjustMp3AacAlbumGain_dB%
set add_rg=1
set add_meta=1
:end_apply_AG

if not exist "@cover@" goto end_cover
set Flac_cover=--picture="|image/jpeg|||@cover@"
set MetaFlac_cover=--import-picture="|image/jpeg|||@cover@"
set MetaMP3_cover=--pict "{3}@cover@"
set AacTag_cover=-add-cover:front:"@cover@"
set add_cover=1
set add_meta=1
:end_cover

if @various@==0 (
set ArtistField=artist
set MP3ArtistField=TPE1
) else (
set ArtistField=album artist
set MP3ArtistField=TPE2
)


REM ---- Image ----


if not "@imageext@"=="flac" goto end_flac_image
set dest=%Flac_ImageDir%
if not exist "%dest%" mkdir "%dest%"
@tools@\flac.exe %Flac_opt% %Flac_RG% %Flac_cover% -T "%ArtistField%=@cdartist@" -T "album=@album@" -T "totaltracks=@numtracks@" -T "date=@year@" -T "genre=@genre@" -T "comment=Ripped with EAC/REACT" -T encoded-by="%USERNAME%" --tag-from-file="cuesheet=@cuesheet@" --tag-from-file="eaclog=@eaclog@" "@source@" -o "@image@"
move "@image@" "%dest%"
copy "@cuesheet@" "%dest%"
if %add_cover%==1 copy "@cover@" "%dest%\@basename@.jpg"
:end_flac_image


if not "@imageext@"=="wv" goto end_wavpack_image
set dest=%Wavpack_ImageDir%
if not exist "%dest%" mkdir "%dest%"
@tools@\wavpack.exe %Wavpack_opt% -w "%ArtistField%=@cdartist@" -w "album=@album@" -w "totaltracks=@numtracks@" -w "year=@year@" -w "genre=@genre@" -w "comment=Ripped with EAC/REACT" -w "cuesheet=@@cuesheet@" -w "eaclog=@@eaclog@" "@source@" "@image@"
if %ReplayGain%==1 @tools@\wvgain.exe -a "@image@"
title REACT - "@album@"
move "@image@" "%dest%"
copy "@cuesheet@" "%dest%"
if %add_cover%==1 copy "@cover@" "%dest%\@basename@.jpg"
:end_wavpack_image


if not "@imageext@"=="mp3" goto end_mp3_image
set dest=%MP3_ImageDir%
if not exist "%dest%" mkdir "%dest%"
@tools@\lame.exe %LameMP3_opt% "@source@" "@image@"
@tools@\metamp3.exe %MetaMP3_RG% %MetaMP3_cover% --frame %MP3ArtistField%:"@cdartist@" --album "@album@" --track @numtracks@ --year "@year@" --genre "@genre@" --comment "Ripped with EAC/REACT" --frame TENC:"%USERNAME%" --frame TSSE:"LAME %LameMP3_ver% %LameMP3_opt%" "@image@"
move "@image@" "%dest%"
copy "@cuesheet@" "%dest%"
if %add_cover%==1 copy "@cover@" "%dest%\@basename@.jpg"
:end_mp3_image



REM ---- Tracks ----


if %Flac%==0 goto end_flac_tracks
set dest=%Flac_TrackDir%
if @various@==1 set Flac_VA_tag=-T $qalbum artist=%AlbumArtist%$q
@tools@\acdir.exe --overwrite --output "%dest%\%TrackName%.flac" --pipe "title $n/$N flac $#T & @tools@\flac.exe %Flac_opt% %Flac_VA_tag% -T artist=$#a -T album=$#T -T title=$#t -T tracknumber=$n/$N -T date=$q@year@$q -T genre=$q@genre@$q -T comment=$qRipped with EAC/REACT$q -T encoded-by=$q%USERNAME%$q - -o $#o" "@sourcecuesheet@"
pushd "%dest%"
if %add_meta%==1 @tools@\Glob.exe -v -c @tools@\metaflac.exe %MetaFlac_RG% %MetaFlac_cover% *.flac
copy "@eaclog@" "EAClog.txt"
if %add_cover%==1 copy "@cover@" "folder.jpg"
if exist "@albumfile@.[*].cue" copy "@albumfile@.[*].cue" .
popd
:end_flac_tracks


if %Wavpack%==0 goto end_wavpack_tracks
set dest=%Wavpack_TrackDir%
if @various@==1 set Wavpack_VA_tag=-w $qalbum artist=%AlbumArtist%$q
@tools@\acdir.exe --overwrite --output "%dest%\%TrackName%.wv" --pipe "@tools@\wavpack.exe %Wavpack_opt% %Wavpack_VA_tag% -w artist=$#a -w album=$#T -w title=$#t -w track=$n/$N -w year=$q@year@$q -w genre=$q@genre@$q -w comment=$qRipped with EAC/REACT$q - $#o" "@sourcecuesheet@"
pushd "%dest%"
if %ReplayGain%==1 @tools@\wvgain.exe -a *.wv
copy "@eaclog@" "EAClog.txt"
if %add_cover%==1 copy "@cover@" "folder.jpg"
if exist "@albumfile@.[*].cue" copy "@albumfile@.[*].cue" .
popd
title REACT - "@album@"
:end_wavpack_tracks


if %LameMP3%==0 goto end_mp3_tracks
set dest=%MP3_TrackDir%
REM if @various@==1 set MP3_VA_tag=--frame TPE2:$q%AlbumArtist%$q
SET userText=--user-text $q[album artist]%AlbumArtist%$q
@tools@\acdir.exe --overwrite --output "%dest%\%TrackName%.mp3" --pipe "title $n/$N mp3 $#T & @tools@\lame.exe %LameMP3_opt% - $#o & @tools@\metamp3.exe %MP3_VA_tag% --artist $#a --album $#T --title $#t --track $n/$N --year $q@year@$q --genre $q@genre@$q --comment $qRipped with EAC/REACT$q --frame TENC:$q%USERNAME%$q --frame TSSE:$qLAME %LameMP3_ver% %LameMP3_opt%$q $#o" "@sourcecuesheet@"
pushd "%dest%"
if %add_meta%==1 @tools@\metamp3.exe %MetaMP3_RG% *.mp3
REM copy "@eaclog@" "EAClog.txt"
if %add_cover%==1 copy "@cover@" "folder.jpg"
popd
:end_mp3_tracks


if %NeroAac%==0 goto end_aac_tracks
set dest=%AAC_TrackDir%
@tools@\acdir.exe --overwrite --output "%dest%\%TrackName%.m4a" --pipe "title $n/$N aac $#T & @tools@\neroAacEnc.exe %NeroAac_opt% -if - -of $#o & @tools@\neroAacTag.exe $#o -meta:artist=$#a -meta:album=$#T -meta:title=$#t -meta:track=$n -meta:totaltracks=$N -meta:year=$q@year@$q -meta:genre=$q@genre@$q -meta:comment=$qRipped with EAC/REACT$q" "@sourcecuesheet@"
pushd "%dest%"
if %add_cover%==1 for %%i in (*.m4a) do @tools@\neroAacTag.exe "%%i" %AacTag_cover%
if %add_rg%==1 @tools@\aacgain.exe %AacGain_RG% *.m4a > gainlog.txt
REM copy "@eaclog@" "EAClog.txt"
REM if %add_cover%==1 copy "@cover@" "folder.jpg"
popd
:end_aac_tracks


if %OggEnc2%==0 goto end_ogg_tracks
set dest=%OGG_TrackDir%
@tools@\acdir.exe --overwrite --output "%dest%\%TrackName%.ogg" --pipe "title $n/$N ogg $#T & @tools@\oggenc2.exe %OggEnc2_opt% -c artist=$#a -c album=$#T -c title=$#t -c tracknumber=$n/$N -c date=$q@year@$q -c genre=$q@genre@$q -c comment=$qRipped with EAC/REACT$q -c encoded-by=$q%USERNAME%$q - -o $#o" "@sourcecuesheet@"
pushd "%dest%"
if %ReplayGain%==1 @tools@\vorbisgain.exe -a *.ogg
REM copy "@eaclog@" "EAClog.txt"
REM if %add_cover%==1 copy "@cover@" "folder.jpg"
popd
:end_ogg_tracks


REM ================ END MAIN SCRIPT ===================

if %Debug%==1 (
pause
REM exit
)

rem ** Cleanup

del "@source@"
del "@eaclog@"
del "@cuesheet@"
del "@albumfile@.[*].cue"
del "@cover@"

rem ** Delete this .bat file:
del %0

I just had a thought. Does --user-text need to be added to?
Code: [Select]
@tools@\acdir.exe --overwrite --output "%dest%\%TrackName%.mp3" --pipe "title $n/$N mp3 $#T & @tools@\lame.exe %LameMP3_opt% - $#o & @tools@\metamp3.exe %MP3_VA_tag% --artist $#a --album $#T --title $#t --track $n/$N --year $q@year@$q --genre $q@genre@$q --comment $qRipped with EAC/REACT$q --frame TENC:$q%USERNAME%$q --frame TSSE:$qLAME %LameMP3_ver% %LameMP3_opt%$q $#o" "@sourcecuesheet@"

REACT 2 Released

Reply #66
I just had a thought. Does --user-text need to be added to?
...
Yes.

Also, on an unrelated note, on line 89 I think it should be:

Code: [Select]
if @various@==1 set TrackName=[$n] $~t ^($~a^)

... but I may be wrong.

I have still yet to actually use REACT 2, so I can't really advise on configs.
I'm on a horse.

REACT 2 Released

Reply #67
I just had a thought. Does --user-text need to be added to?
...
Yes.

Well adding it by itself doesn't work. In fact most of the tags are now blank. I guess it is expecting some sort of arguement like
Code: [Select]
--user-text $q[album artist]%AlbumArtist%$q

which seemingly makes the previous line:
Code: [Select]
SET userText=--user-text $q[album artist]%AlbumArtist%$q

unnecessary but I'm not really sure if that is correct or the syntax is right.
Also, on an unrelated note, on line 89 I think it should be:

Code: [Select]
if @various@==1 set TrackName=[$n] $~t ^($~a^)

... but I may be wrong.

I have still yet to actually use REACT 2, so I can't really advise on configs.

This part works fine actually.

REACT 2 Released

Reply #68
I'm sorry, I should have been more clear: you need to add %userText% to the command line.

Code: [Select]
@tools@\acdir.exe --overwrite --output "%dest%\%TrackName%.mp3" --pipe "title $n/$N mp3 $#T & @tools@\lame.exe %LameMP3_opt% - $#o & @tools@\metamp3.exe %MP3_VA_tag% %userText% --artist $#a --album $#T --title $#t --track $n/$N --year $q@year@$q --genre $q@genre@$q --comment $qRipped with EAC/REACT$q --frame TENC:$q%USERNAME%$q --frame TSSE:$qLAME %LameMP3_ver% %LameMP3_opt%$q $#o" "@sourcecuesheet@"

This part works fine actually.
Yes, on thinking about it, I think I had to do that previously as I had the line already in brackets.  Sorry for confusing the issue.
I'm on a horse.

REACT 2 Released

Reply #69
I'm sorry, I should have been more clear: you need to add %userText% to the command line.

Code: [Select]
@tools@\acdir.exe --overwrite --output "%dest%\%TrackName%.mp3" --pipe "title $n/$N mp3 $#T & @tools@\lame.exe %LameMP3_opt% - $#o & @tools@\metamp3.exe %MP3_VA_tag% %userText% --artist $#a --album $#T --title $#t --track $n/$N --year $q@year@$q --genre $q@genre@$q --comment $qRipped with EAC/REACT$q --frame TENC:$q%USERNAME%$q --frame TSSE:$qLAME %LameMP3_ver% %LameMP3_opt%$q $#o" "@sourcecuesheet@"

YEAH! That worked. Thanks SS.

REACT 2 Released

Reply #70
Thanks Tycho for creating REACT. I'm finding it very useful! And thanks to Synthetic Soul for the tech help. What an improvement for Various Artist albums! Excellent.

I tried the previous version for the first time about a month ago, and worked my way through the forum threads until I had a basic understanding - and a good Test & Copy Flac tracks routine.
Now, with REACTv2, I've added AAC tracks to my Test & Copy Flac tracks. It's all working well, except for one minor thing - I'd like to save CRC values in the FLAC tags, but I'm not getting the code right.

Code: [Select]
if %Flac%==0 goto end_flac_tracks
    set dest=%Flac_TrackDir%
    if not exist "%dest%" mkdir "%dest%"
    if @various@==1 set Flac_VA_tag=-T "album artist=%AlbumArtist%"
    @tools@\flac.exe %Flac_opt% %Flac_VA_tag% -T artist="@artist@" -T album="@album@" -T tracknumber="@track@/@numtracks@" -T title="@title@" -T date="@year@" -T genre="@genre@" -T comment="Ripped with EAC/REACT" -T CRC="%CRC%" "@source@" -o "%dest%\%TrackName%.flac"
:end_flac_tracks


I've probably missed something major.

REACT 2 Released

Reply #71
YEAH! That worked. Thanks SS.
No problem.  This is actually what I was referring to in post #57 when I suggested:

Code: [Select]
FLAC.EXE ... %userText% ...

... but I mistakingly used FLAC.EXE in the example assuming --user-text to be a FLAC switch, and not a METAMP3 switch.  Ah well, we got there in the end.

Code: [Select]
if %Flac%==0 goto end_flac_tracks
    set dest=%Flac_TrackDir%
    if not exist "%dest%" mkdir "%dest%"
    if @various@==1 set Flac_VA_tag=-T "album artist=%AlbumArtist%"
    @tools@\flac.exe %Flac_opt% %Flac_VA_tag% -T artist="@artist@" -T album="@album@" -T tracknumber="@track@/@numtracks@" -T title="@title@" -T date="@year@" -T genre="@genre@" -T comment="Ripped with EAC/REACT" -T CRC="%CRC%" "@source@" -o "%dest%\%TrackName%.flac"
:end_flac_tracks
I think you want -T CRC="@crc@" and not -T CRC="%CRC%", unless you have set a DOS variable previously in your config.

Thanks for the thanks.
I'm on a horse.

REACT 2 Released

Reply #72
I think you want -T CRC="@crc@" and not -T CRC="%CRC%", unless you have set a DOS variable previously in your config.


I was afraid it was something simple like that! It's working perfectly now, Thanks again.

I was having something odd happen last night - I would start ripping a CD by hitting F4 - EAC would begin checking for gaps, and the coverart downloader would start. Then EAC would just stop after finishing saving the cue sheets - no copying tracks.
I've rebooted and have not been able to re-produce the problem (not that I'm complaining!).
Has anybody else had this trouble?

REACT 2 Released

Reply #73
I've installed REACT 2 several times on Windows Vista Ultimate (final, not beta or RC) and I never get a REACT.ini file.  The other files seem to be there.  Hitting Alt-F2 gets me a "Cannot find the C:\Program Files\REACT2\React.ini file would you like to create it?" dialog.  I assume I can just get a copy from somebody else or create my own if somebody can post or PM me the text of the file, right?

REACT 2 Released

Reply #74
I've installed REACT 2 several times on Windows Vista Ultimate (final, not beta or RC) and I never get a REACT.ini file.  The other files seem to be there.  Hitting Alt-F2 gets me a "Cannot find the C:\Program Files\REACT2\React.ini file would you like to create it?" dialog.  I assume I can just get a copy from somebody else or create my own if somebody can post or PM me the text of the file, right?

Are you starting EAC or REACT? When you run REACT it creates the INI file for you. You should always start with REACT going forward.