I'm using, and I love it. I made a few mods to personalize it, but the base design is top notch.
Could you tell me a little bit more about your customization? Would be very interesting as I'm also thinking about some mod for coverflow and albumart viewer.. What have u done and could you post your config?
By the way, just an idea for a more sophisticated Statusbar that I've picked up somewhere in this forum..
//**************************************
// set colors
//**************************************
$puts(col_paused,¬00c8ff¬)
$puts(col_streaming,¬008800¬)
$puts(col_cue_file,¬880000¬)
$puts(col_progbar_symb1,¬ee8888¬)
$puts(col_progbar_symb2,¬550000¬)
$puts(col_time_remaining,¬000000¬)
$puts(col_bitrate,¬00a3cc¬)
$puts(col_bitrate2,¬00a8ee¬)
$puts(col_stereo,¬808080¬)
//**************************************
// set variables
//**************************************
$puts(text_streaming,'Streaming')
$puts(text_listened_for,'Listened for:')
$puts(text_cue_file,'Cue File')
$puts(text_paused,'PAUSED')
$puts(text_time_remaining,[%_time_remaining%])
$puts(spacer_symb,' ')
$puts(spacer_width,2)
$puts(progbar_symb1,'ι')
$puts(progbar_symb2,'ι')
$puts(progbar_length,90)
$puts(text_bitrate,$get(col_bitrate)$if2($pad(%__bitrate_dynamic%,3)¬808080¬' kbps',$if2(%__bitrate%' kbps'¬¬,)))
$puts(text_extrainfo,[%__extrainfo%])
//**************************************
// add colors and formatting
//**************************************
$puts(spacer,$repeat($get(spacer_symb),$get(spacer_width)))
$puts(text_streaming,$get(col_streaming)$get(text_streaming)¬¬)
$puts(text_listened_for,$get(col_streaming)$get(text_listened_for)¬¬)
$puts(text_cue_file,$get(col_cue_file)$get(text_cue_file)¬¬)
$puts(text_paused,$get(col_paused)$get(text_paused)¬¬)
$puts(text_time_remaining,$get(col_time_remaining)$get(text_time_remaining)¬¬)
$puts(progbar_symb1,$get(col_progbar_symb1)$get(progbar_symb1)¬¬)
$puts(progbar_symb2,$get(col_progbar_symb2)$get(progbar_symb2)¬¬)
//***********************************************************
//***********************************************************
//**************************************
// streaming
//**************************************
$puts(streaming,
$if(%_time_total%,,
$get(text_streaming)$get(spacer)
)
)
//**************************************
// cuefile
//**************************************
$puts(cue_file,
$if(%__cue_audiotype%,
$get(text_cue_file)$get(spacer)
)
)
//**************************************
// codec
//**************************************
$if(%__codec%,
$if($stricmp(%__codec%,musepack),$puts(codec,'MPC'),
$if($stricmp(%__codec%,vorbis),$puts(codec,'Ogg'),
$get(spacer) $puts(codec,%__codec%)
))
,
//If no codec tag and not streaming, read file extention
$if($and(%_time_total%,$not(%__codec%)),
$puts(codec,$upper($ext(%_path%)))
)
)
//**************************************
// bitrate
//**************************************
$puts(bitrate,$get(spacer)$get(text_bitrate))
$if($stricmp(%__codec%,musepack),
$if(%__mpc_profile%,
$puts(bitrate,$get(spacer)%__mpc_profile%$get(spacer)$get(text_bitrate))
)
)
//**************************************
// extrainfo
//**************************************
$puts(extrainfo,$get(spacer)$get(text_extrainfo))
$if($stricmp(%__codec%,MP3),
$if(%__extrainfo%,,
$puts(extrainfo,$get(spacer)'CBR')
)
)
$if($stricmp(%__codec%,musepack),
$if(%__mpc_streamversion%,$puts(extrainfo,$get(spacer)'sv'%__mpc_streamversion%))
)
//**************************************
// samplerate
//**************************************
$puts(samplerate,
$if(%__samplerate%,
$get(spacer)$cut(%__samplerate%,2)'kHz'
)
)
//**************************************
// channels
//**************************************
$puts(channels,
$if(%__channels%,
$get(spacer)$ifgreater(%__channels%,2,%__channels%ch,$ifgreater(%__channels%,1,Stereo,Mono))
)
)
//**************************************
// mp3 stereo mode
//**************************************
$puts(stereo_mode,
$if2( $get(col_stereo)'['$caps(%__mp3_stereo_mode%)']',)
)
//**************************************
// Replay Gain
//**************************************
//track gain
$puts(rpg,
$if(%__replaygain_track_gain%,
$get(spacer)
' TGain:'$cut(%__replaygain_track_gain%,5)'dB'
$if(%__replaygain_album_gain%,
$get(spacer)' AGain:'$cut(%__replaygain_album_gain%,5)'dB'
)
)
)
//**************************************
// progress bar
// (checking total because of streaming)
//**************************************
$puts(progress_bar,
$if(%_time_total_seconds%,
$get(spacer)$get(spacer)
$progress2(%_time_elapsed_seconds%,%_time_total_seconds%,$get(progbar_length),$get(progbar_symb1),$get(progbar_symb2))
)
)
//**************************************
// progress %
// (checking total because of streaming)
//**************************************
$puts(progress_%,
$if(%_time_total_seconds%,
' '¬808080¬$pad_right($muldiv(%_time_elapsed_seconds%,100,%_time_total_seconds%),3)¬808080¬'%'¬¬' '
)
)
//**************************************
// 'Listened for:'
// (used for streaming)
//**************************************
$puts(listened_for,
$if(%_time_total%,,
$get(spacer)$get(spacer)$get(text_listened_for)
)
)
//**************************************
// time
//**************************************
$puts(time,
$get(spacer)
' '[%_time_elapsed%]
$if(%_time_total%,
'/'%_time_total%' ' $get(spacer)$get(spacer)$get(spacer)
'Remaining Time: '$get(text_time_remaining)
)
)
//**************************************
// paused
//**************************************
$puts(paused,
$if(%_ispaused%,
$get(text_paused)
)
)
//**************************************
//**************************************
// create string
//**************************************
//**************************************
$get(streaming)
$get(cue_file)
$get(codec)
$get(bitrate)
$get(extrainfo)
$get(samplerate)
$get(channels)
$get(stereo_mode)
$get(progress_bar)
$get(progress_%)
$get(spacer)$get(listened_for)
$get(time)
$get(spacer)$get(rpg)
//Right adjust from now on
$char(9)
$get(paused)
Topic: My Columns UI config · FooSune (Read 189794 times)
previous topic - next topic