i created a little string for the info box today that i think looks pretty sweet. i made it easy enough to configure the colors and such. i might work on it a bit more latter but for the most part i think its finished. tell me what u guys think.
////////////////////////////////
//Colors, etc.
////////////////////////////////
$puts(info_box_size,36)
$puts(default_color,d4d4d4)
$puts(rating_color_1,5357EF)
$puts(rating_color_2,042573)
$puts(rating_symbol,♫)
$puts(is_playing_color,5357EF)
$puts(tag_missing_color,757575)
$puts(heading_color_l,ffb00d)
$puts(heading_color_r,000000)
$puts(is_playing_color,5357EF)
////////////////////////////////
//Code
////////////////////////////////
////////////////////////////////
///////Song Info
////////////////////////////////
$transition(----- Song Info $repeat(-,$add($get(info_box_size),4)),$get(heading_color_l),$get(heading_color_r))
$char(10)$get(default_color)
$if(%title%,$if(%_isplaying%,
$get(is_playing_color)$iflonger(%title%,$get(info_box_size),$cut(%title%,$sub($get(info_box_size),3))...,%title%),
$iflonger(%title%,$get(info_box_size),$trim($cut(%title%,$sub($get(info_box_size),3)))...,%title%)),
$if(%_isplaying%,
$get(is_playing_color)$iflonger(%_filename_ext%,$get(info_box_size),$cut(%_filename_ext%,$sub($get(info_box_size),3))...,%_filename_ext%),
$iflonger(%_filename_ext%,$get(info_box_size),$trim($cut(%_filename_ext%,$sub($get(info_box_size),3)))...,%_filename_ext%)))
$char(10)$get(default_color)
$if(%artist%,
$iflonger(%artist%,$get(info_box_size),$cut(%artist%,$sub($get(info_box_size),3))...,%artist%),
$get(tag_missing_color)no artist info)
$char(10)$get(default_color)
$if(%album%,
$iflonger(%album%,$get(info_box_size),$cut(%album%,$sub($get(info_box_size),3))...,%album%),
$get(tag_missing_color)no album info)
$char(10)$get(default_color)
$if($or(%publisher%.%label%,%date%),$if($or(%publisher%,%label%),© ,)%date%$if($or(%publisher%,%label%),'. ',)[%publisher% ][%label%],
$get(tag_missing_color)no date or copyright info)
$char(10)$get(default_color)
$if(%rating%,
$repeat($get(rating_color_1)$get(rating_symbol) ,%rating%)$repeat($get(rating_color_2)$get(rating_symbol) ,$sub(5,%rating%)) ,)
$get(default_color)$if(%genre%,%genre%,$get(tag_missing_color)no genre info)
$char(10)$char(10)
////////////////////////////////
///////Statistics
////////////////////////////////
$transition(----- Statistics $repeat(-,$add($get(info_box_size),4)),$get(heading_color_l),$get(heading_color_r))
$char(10)$get(default_color)
$if(%play_date%,
$puts(month,$left(%play_date%,2))
$puts(day,$substr(%play_date%,4,5))
$if($strcmp($left($get(day),1),0),$puts(day,$right($get(day),1)))
$puts(year,$right(%play_date%,2))
$puts(month_name,$select($get(month),
Jan,Feb,March,April,May,June,July,Aug,Sept,Oct,Nov,Dec))
$if($strcmp($right($get(day),1),1),$puts(xx,st),
$if($strcmp($right($get(day),1),2),$puts(xx,nd),
$if($strcmp($right($get(day),1),3),$puts(xx,rd),
$puts(xx,th)))))
$puts(time_of_year,$get(month_name) $get(day)$get(xx) 20$get(year))
$if(%play_counter%,Played $if($strcmp(%play_counter%,1),
once$if(%play_date%,',')$if(%play_date%, on $get(time_of_year)),
%play_counter% times$if(%play_date%,
$char(10) Last played on $get(time_of_year))),This song has not played before)
$ifgreater(%play_counter%,1,,$char(10))
$char(10)$char(10)
////////////////////////////////
///////Tech Info
////////////////////////////////
$transition(----- Tech Info $repeat(-,$add($get(info_box_size),4)),$get(heading_color_l),$get(heading_color_r))
$char(10)$get(default_color)
%__codec%
$if(%__bitrate_dynamic%,%__bitrate_dynamic%,%__bitrate%)kbps
$if($stricmp(%__codec%,mp3),$if($stricmp(%__extrainfo%,vbr),VBR,CBR))
$if($stricmp($codec(),MP3),%__mp3_stereo_mode%,$channels())
$char(10)$get(default_color)
[%_time_elapsed%/][%_length%][ -%_time_remaining%]
$if(%_isplaying%,
$muldiv(%_time_elapsed_seconds%,100,%_time_total_seconds%)'%',)
$div(%_filesize%,1048576).
$left($num($muldiv($mod(%_filesize%,1048576),1000,1048576),3),2)' MB'
$char(10)$get(default_color)
$if($or(%__replaygain_track_gain%,%__replaygain_album_gain%),
['['Tg']' %__replaygain_track_gain% ]['['Ag']' %__replaygain_album_gain%],
$get(tag_missing_color)there is no gain)
Edited for bugz.
[a href=\"index.php?act=findpost&pid=269971\"][{POST_SNAPBACK}][/a]
Topic: foo_uie_trackinfo (Read 814793 times)
previous topic - next topic