i have problems with "last play", display only newer or from night to afternoon.
edit
solved using cwb_systemdatetime% and modified script.
// Mode of display - normal, warmth, rainbow, fade, album
$puts(mode,warmth)
// General global crap
// key
// a = first row bg, b= second row bg, c = first track row bg
// t = text, u = first track text
// f = frame
//left rows
$set_global(1a,FFFFFF)
$set_global(1b,F4F4F4)
$set_global(1f,E8E8E8)
$set_global(1t,999999)
$set_global(1u,666666)
//right rows
$set_global(2a,F0F0F0)
$set_global(2b,E6E6E6)
$set_global(2f,D2D2D2)
$set_global(2t,787878)
$set_global(2c,D2D2D2)
$set_global(2u,646464)
// faded stuff = tracknumber, genres etc
$set_global(3t,AAAAAA)
$set_global(3u,8A8A8A)
// Controls the now playing bar colours.
$set_global(pback,1A1A1A)
$set_global(pborder,1A1A1A)
$set_global(ptext,FFFFFF)
// Selected colours
$set_global(sel_fg,555555)
$set_global(sel_bg,CCCCCC)
// Per album colours
$if($strcmp($get(mode),album),
$set_global(hue1,$add($mod($div($crc32(%album%),135),255),1))
$set_global(sat1,120)
)
$if($strcmp($get(mode),fade),
// Fading saturation
$set_global(sat1,$sub(255,$mul($sub(%tracknumber%,1),$div(205,$if(%totaltracks%,$sub(%totaltracks%,1),010)))))
$set_global(hue1,$add($div(%tracknumber%,2),6))
)
$if($strcmp($get(mode),warmth),
// Warmth
$if(%play_count%,
$set_global(sat1,$mul(10,$add(%play_count%,0)))
$set_global(hue1,$add(10,$div(%tracknumber%,2)))
,
// these are the default colours if track has not been played
$set_global(sat1,25)
$set_global(hue1,140)
)
)
$if($strcmp($get(mode),rainbow),
// RAINBOW MODE !!
$set_global(hue1,$mul($div(240,$if(%totaltracks%,%totaltracks%,60)),$sub(%tracknumber%,1)))
$set_global(sat1,260)
)
$if($strcmp($get(mode),normal),
// Normal colours;]
$set_global(sat1,25)
$set_global(hue1,140)
)
/////////////////////////////////////////
// NATURAL LANGUAGE TIMESTAMPS
// by topdownjimmy
// v0.4 - June 4, 2006
/////////////////////////////////////////
////modified (melomane
/////////
$puts(sd,$right(%cwb_systemdate%,2))
$puts(sm,$left($right(%cwb_systemdate%,5),2))
$puts(sy,$left(%cwb_systemdate%,4))
$puts(sh,$right($left(%cwb_systemdatetime%,16),5))
//////////////////////////////////////////////////////////////
// calculate "dayssince": number of days since song was last played
$if(%last_played%,$puts(dayssince,$sub($add($mul($right($get(sy),2),365),$select($get(sm),0,31,59,90,120,151,181,212,243,273,304,334),$add($div($right($get(sy),2),4),$if($or($greater($get(sm),2),$greater($mod($get(sy),4),0)),1,0)),$get(sd)),$add($mul($substr(%last_played%,3,4),365),$select($substr(%last_played%,6,7),0,31,59,90,120,151,181,212,243,273,304,334),$add($div($substr(%last_played%,3,4),4),$if($or($greater($substr(%last_played%,6,7),2),$greater($mod($substr(%last_played%,1,4),4),0)),1,0)),$substr(%last_played%,9,10)))),$puts(dayssince,))
// correct "dayssince" to consider early AM to be an extension of previous day
$puts(dayssince,$sub($get(dayssince),$if($and($greater(7,$get(sh)),$greater($substr(%last_played%,12,13),6)),1,0)))
$if($and($greater($get(sh),6),$greater(7,$substr(%last_played%,12,13))),$puts(dayssince,$add($get(dayssince),1)),)
// calculate day of week
$puts(calcdayofweek,$add(1,$mod($add($substr(%last_played%,3,4),$div($substr(%last_played%,3,4),4),$select($substr(%last_played%,6,7),6,2,2,5,0,3,5,1,4,6,2,4),$substr(%last_played%,9,10)),7)))
// correct day of week to consider early AM to be an extension of previous day
$puts(calcdayofweek,$sub($get(calcdayofweek),$ifgreater(7,$substr(%last_played%,12,13),1,0)))
$if($strcmp($get(calcdayofweek),0),$puts(calcdayofweek,7),)
// calculate period of day (night, morning, etc.)
$puts(dayperiod,$select($add(1,$substr(%last_played% ,12,13)),Night,Night,Night,Night,Night,Night,Night,Morning,Morning,Morning,Morning,Morning,Afternoon
,Afternoon,Afternoon,Afternoon,Afternoon,Evening,Evening,Evening,Evening,Night,Night,Night))
// calculate natural language timestamp
$if(%last_played%,$puts(nat_lang_stamp,$ifgreater($get(dayssince),0,$ifgreater($get(dayssince),1,$ifgreater($get(dayssince),6,$if($and($greater($get(dayssince),21),$not($strcmp($get(sm),$substr(%last_played%,6,7)))),$if($not($strcmp($get(sy),$substr(%last_played%,1,4))),$select($substr(%last_played%,6,7),January,February,March,April,May,June,July,August,September,October,November,December)' '$substr(%last_played%,1,4),$ifgreater(2,$sub($get(sm),$substr(%last_played%,6,7)),'Last Month',$select($substr(%last_played%,6,7),January,February,March,April,May,June,July,August,September,October,November,December))),$ifgreater($div($add($get(dayssince),4),7),1,$div($add($get(dayssince),4),7)' Weeks Ago',Last Week)),$select($get(calcdayofweek),Sunday,Monday,Tuesday,Wednesday,Thursday,Friday,Saturday)' '$get(dayperiod)),$if($strcmp($get(dayperiod),Night),Last,Yesterday)' '$get(dayperiod)),$if($strcmp($get(dayperiod),Night),Tonight,This $get(dayperiod)))),$puts(nat_lang_stamp,Never))
$set_global(nat_lang_stamp,$get(nat_lang_stamp))
/////////////////////////////////////////