Your Track-Info-Mod-Configs!

Topic: Your Track-Info-Mod-Configs! (Read 24581 times) previous topic - next topic

0 Members and 1 Guest are viewing this topic.

Your Track-Info-Mod-Configs!

2006-11-07 08:00:06

In order to make the appearancethread more readable:

thanx to sune,

$imageabs(0,0,images\FOOBOTTOM.png,)

///////PLAY/PAUSE
$button(21,9,0,0,28,30,
$if($or(%ispaused%,$not(%isplaying%)),images\iconsPLAYBACK\PLAY.png,images\iconsPLAYBACK\pause.png),
$if($or(%ispaused%,$not(%isplaying%)),images\iconsPLAYBACK\PLAY_OVER.png,images\iconsPLAYBACK\pause_OVER.png),
$if($or(%ispaused%,$not(%isplaying%)),play,pause)
,)

///////STOP

$button(49,12,0,0,22,24,images\iconsPLAYBACK\STOP.png,images\iconsPLAYBACK\STOP_OVER.png,stop,)

///////PREVIOUS

$button(89,12,0,0,22,24,images\iconsPLAYBACK\PREVIOUS.png,images\iconsPLAYBACK\PREVIOUS_OVER.png,previous,)


///////NEXT

$button(111,12,0,0,22,24,images\iconsPLAYBACK\NEXT.png,images\iconsPLAYBACK\NEXT_OVER.png,next,)

////////////////////////////////////////////////////////////////////
//////////PLAYBACK ORDER
////////////////////////////////////////////////////////////////////

//////DEFAULT//////
$if(
$not($stricmp(%cwb_playback_order%,default))
,
$button(152,16,0,0,15,15,images\iconsPLAYBACK\dfnot.png,images\iconsPLAYBACK\df_over.png,default,)
,
$imageabs(152,16,images\iconsPLAYBACK\df.png,)
)

//////SHUFFLE///
$if(
$xor(
$stricmp(%cwb_playback_order%,default),
$stricmp(%cwb_playback_order%,'repeat (track)'),
$stricmp(%cwb_playback_order%,'repeat (playlist)')
)
,
$button(171,16,0,0,15,15,images\iconsPLAYBACK\shnot.png,images\iconsPLAYBACK\shnot_over.png,'Shuffle (tracks)',)
,
$button(171,16,0,0,15,15,
$if($stricmp(%cwb_playback_order%,'Shuffle (tracks)'),images\iconsPLAYBACK\SHTRACKS.png,images\iconsPLAYBACK\SHalbums.png),
$if($stricmp(%cwb_playback_order%,'Shuffle (tracks)'),images\iconsPLAYBACK\SHTRACKS_over.png,images\iconsPLAYBACK\SHalbums_over.png),
$if($stricmp(%cwb_playback_order%,'Shuffle (tracks)'),'Shuffle (albums)','Shuffle (tracks)')
,)
)

///REPEAT///////
$if(
$xor(
$stricmp(%cwb_playback_order%,default),
$stricmp(%cwb_playback_order%,'shuffle (tracks)'),
$stricmp(%cwb_playback_order%,'shuffle (albums)')
)
,
$button(190,16,0,0,15,15,images\iconsPLAYBACK\rpnot.png,images\iconsPLAYBACK\rpnot_over.png,'repeat (track)',)
,
$button(190,16,0,0,15,15,
$if($stricmp(%cwb_playback_order%,'repeat (track)'),images\iconsPLAYBACK\RPTRACK.png,images\iconsPLAYBACK\RPPLAYLIST.png),
$if($stricmp(%cwb_playback_order%,'repeat (track)'),images\iconsPLAYBACK\RPTRACK_over.png,images\iconsPLAYBACK\RPPLAYLIST_over.png),
$if($stricmp(%cwb_playback_order%,'repeat (track)'),'repeat (playlist)','repeat (track)')
,)
)

////////////////////////////////////////////////////////////////////
//////////VOLUME
//////////////////////////////////////////////////////////////////

//VOLUME BAR

$alignabs(230,20,100,20,,)
$puts(volume,$substr($num(%cwb_volume%,4),2,4))
$puts(active,$rgb(117,211,255))
$puts(back,$rgb(81,81,77))
$font(arial,10,bold,)

$if($greater(1,$get(volume)),$puts(amp,12),
$if($greater(3,$get(volume)),$puts(amp,11),
$if($greater(6,$get(volume)),$puts(amp,10),
$if($greater(9,$get(volume)),$puts(amp,9),
$if($greater(13,$get(volume)),$puts(amp,8),
$if($greater(16,$get(volume)),$puts(amp,7),
$if($greater(21,$get(volume)),$puts(amp,6),
$if($greater(26,$get(volume)),$puts(amp,5),
$if($greater(33,$get(volume)),$puts(amp,4),
$if($greater(43,$get(volume)),$puts(amp,3),
$if($greater(58,$get(volume)),$puts(amp,2),
$puts(amp,1))))))))))))
$if($stricmp(100,$get(volume)),$puts(amp,0))
$font(wingdings,6,,)
$get(active)$repeat($char(376),$get(amp))
$get(back)$repeat($char(376),$sub(12,$get(amp)))

///nº Db///////

$font(kroeger 05_55,5,,117-211-255)$alignabs(278,19,35,20,right,)-$num($get(volume),1) Db

//BUTTONS

$if($greater(1,$get(volume)),$puts(amp,48),
$if($greater(3,$get(volume)),$puts(amp,44),
$if($greater(6,$get(volume)),$puts(amp,40),
$if($greater(9,$get(volume)),$puts(amp,36),
$if($greater(13,$get(volume)),$puts(amp,32),
$if($greater(16,$get(volume)),$puts(amp,28),
$if($greater(21,$get(volume)),$puts(amp,24),
$if($greater(26,$get(volume)),$puts(amp,20),
$if($greater(33,$get(volume)),$puts(amp,16),
$if($greater(43,$get(volume)),$puts(amp,12),
$if($greater(58,$get(volume)),$puts(amp,8),
$puts(amp,4))))))))))))
$if($stricmp(100,$get(volume)),$puts(amp,0))

$if($not($greater(1,$get(volume))),$button2($add($get(amp),230),20,0,-7,15,20,,'$font(wingdings,6,,250-0-0)$char(376)',volume up,))
$button2($add($get(amp),222),20,-10,-7,15,25,,'$font(wingdings,6,,0-0-250)$char(376)',volume down,)

//VOLUME CONTROLS

$imageabs(331,13,images\iconsPLAYBACK\VOL.png,)

$if($stricmp(100,$get(volume)),
$button(331,13,0,0,12,22,images\iconsPLAYBACK\VOL_DOWN_M.png,images\iconsPLAYBACK\VOL_DOWN_OVER_M.png,Volume DOWN,),
$button(331,13,0,0,12,22,images\iconsPLAYBACK\VOL_DOWN_V.png,images\iconsPLAYBACK\VOL_DOWN_OVER_V.png,Volume DOWN,))

$if($stricmp(100,$get(volume)),
$button(354,13,11,0,11,22,images\iconsPLAYBACK\VOL_UP_M.png,images\iconsPLAYBACK\VOL_UP_OVER_M.png,Volume UP,),
$button(354,13,11,0,11,22,images\iconsPLAYBACK\VOL_UP_V.png,images\iconsPLAYBACK\VOL_UP_OVER_V.png,Volume UP,))
$puts(volume,$substr($num(%cwb_volume%,4),2,4))

$if($stricmp(100,$get(volume)),
$button(343,13,0,0,22,22,images\iconsPLAYBACK\VOL_MUTE.png,images\iconsPLAYBACK\VOL_MUTE_OVER.png,Volume mute,),
$button(343,13,0,0,22,22,images\iconsPLAYBACK\VOL_ON.png,images\iconsPLAYBACK\VOL_ON_OVER.png,Volume mute,))

images

Your Track-Info-Mod-Configs!

Reply #1 – 2006-11-10 07:42:07

heres a text based info panel i've been using for some time. i don't really have the time these days to make a new one especially with the new features in the track info panel.

Requires:
foobar 9.x
foo_uie_trackinfo (any version should work)
foo_cwb_hooks
foo_playcount (official)

Code: [Select]

// ------------------[[ gob's Track Info Panel v6.11.11 ]]------------------ \\

// Recommended settings:
// Arial bold 8pt; line spacing: -1; vertical padding: 0; horizontal padding: 1

$puts(box_width,25)
$puts(defaultcolor,D4D4D4)
$puts(playingcolor,5357EF)
$puts(missingcolor,635757)
$puts(commentcolor,908080)
$puts(ratingcolor,00B3FF)
$puts(ratingsymbol,♫ )
$puts(headingcolor,FFB00D)
$puts(headingcolor_dim,191101)

[[
[[-- Song Info Code --]]
]]
$transition(----- Song Info --$repeat(-,$get(box_width)),
$get(headingcolor),$get(headingcolor_dim))
$char(10)$get(defaultcolor)

$if(%__codec%,

// Title formatting
$if(%_isplaying%,$get(playingcolor),)
$puts(title,$if2(%title%,%_filename_ext%))


$puts(ftitle,$replace($get(title),'(',$get(commentcolor)'('))
$puts(ftitle,$replace($get(ftitle),')',$get(commentcolor)')'
$if(%_isplaying%,$get(playingcolor),$get(defaultcolor))))
$puts(ftitle,$replace($get(ftitle),'[',$get(commentcolor)'['))
$puts(ftitle,$replace($get(ftitle),']',$get(commentcolor)']'
$if(%_isplaying%,$get(playingcolor),$get(defaultcolor))))

$if(%_isplaying%,$get(playingcolor),$get(defaultcolor))
$get(ftitle)

$char(10)$get(defaultcolor)' '

// Artist formatting
$if(%artist%,%artist%,
$get(missingcolor)unknown artist)

// Album formatting
$char(10)$get(defaultcolor)' '
$if(%album%,
$puts(falbum,
$if(%discname%,
%discname%' ('%album% Disc $roman(%discnumber%)')',
$if($stricmp(%artist%,%album%),'('self titled')',%album%)
[ '('Disc $roman(%discnumber%)')']))

$puts(falbum,$replace($get(falbum),'('
,$get(commentcolor)'('))
$puts(falbum,$replace($get(falbum),')',
$get(commentcolor)')'$get(defaultcolor)))
$puts(falbum,$replace($get(falbum),'[',
$get(commentcolor)'['))
$puts(falbum,$replace($get(falbum),']',
$get(commentcolor)']'$get(defaultcolor)))
$get(falbum)
,
$get(missingcolor)unknown album)

// Date & Label formatting
$char(10)$get(defaultcolor)' '
$if($or(%date%,%label%,%publisher%),
$if($and(%date%,$or(%label%,%publisher%)),© %date%. ,%date%)
[%label% ][%publisher% ]
,
$get(missingcolor)no date or label info)


// Rating formatting
$char(10)$get(defaultcolor)' '
$if(%rating%,$get(ratingcolor)$if(%rating%,$repeat($get(ratingsymbol),%rating%)
$get(missingcolor)
$repeat($get(ratingsymbol),$sub(5,%rating%)),
$get(missingcolor)$repeat($get(ratingsymbol),5))' ')
$get(defaultcolor)$if(%genre%,%genre%,$get(missingcolor)unknown genre)
,
$get(missingcolor)' '
there is no audio
$repeat($char(10),4))
$char(10)


[[
[[-- Statistics Code --]]
]]
$transition(----- Statistics --$repeat(-,$get(box_width)),
$get(headingcolor),$get(headingcolor_dim))
$char(10)$get(defaultcolor) 

$if(%__codec%,
// Last played formatting
$if($and(%play_count%,%last_played_timestamp%),
$puts(diff,$cwb_datediff(%last_played%,%cwb_systemdate%))

$ifgreater(1,$get(diff),$puts(last_played,today),$ifgreater(2,$get(diff),$puts(last_played,yesterday),
$puts(last_played_month,$substr(%last_played%,6,7))
$puts(last_played_day,$num($substr(%last_played%,9,10),1))
$puts(last_played_year,$substr(%last_played%,1,4))
$puts(last_played_month_name,$select($get(last_played_month),
Jan,Feb,March,April,May,June,July,Aug,Sept,Oct,Nov,Dec))
$if($or($strcmp($get(last_played_day),11),$strcmp($get(last_played_day),12),$strcmp($get(last_played_day),13)),
$puts(last_played_dayxx,th),
$if($strcmp($right($get(last_played_day),1),1),$puts(last_played_dayxx,st),
$if($strcmp($right($get(last_played_day),1),2),$puts(last_played_dayxx,nd),
$if($strcmp($right($get(last_played_day),1),3),$puts(last_played_dayxx,rd),
$puts(last_played_dayxx,th)))))
$puts(last_played,on' '
$get(last_played_month_name)' '$get(last_played_day)$get(last_played_dayxx)
$if($stricmp($substr(%last_played%,3,4),$substr(%cwb_systemdate%,3,4)),,' '$get(last_played_year))))))
$if($and(%play_count%,%last_played_timestamp%,%first_played_timestamp%),

// First played formatting
$puts(first_played,
$num($substr(%first_played%,6,7),1)'/'
$num($substr(%first_played%,9,10),1)'/'
$substr(%first_played%,1,4)))

// Display Stats
$ifgreater(%play_count%,0,
$ifgreater(2,%play_count%,Played once
$if(%last_played_timestamp%, $get(last_played).,.)
$char(10)$get(defaultcolor) ,
$if(%last_played_timestamp%,
Last played $get(last_played).$char(10)$get(defaultcolor) 
Played %play_count% times$if(%first_played_timestamp%, since $get(first_played).,.)
,Played %play_count% times.$char(10)$get(defaultcolor) ))
,This song has not played yet.$char(10)$get(defaultcolor))
,$char(10))
$char(10)

[[
[[-- Tech Info Code --]]
]]
$transition(----- Tech Info --$repeat(-,$get(box_width)),
$get(headingcolor),$get(headingcolor_dim))$char(10)
$if(%__codec%,
$get(defaultcolor)' '

// Codec formatting
%__codec% 
$if(%__bitrate_dynamic%,%__bitrate_dynamic%,%__bitrate%)Kbps 
$if($or($stricmp(%__extrainfo%,vbr),
$stricmp($codec(),musepack),$stricmp($codec(),vorbis),
$stricmp($codec(),flac)$stricmp($codec(),monkey''s audio)
),VBR,)

$char(10)$get(defaultcolor) 
$if(%__bitspersample%,Lossless %__bitspersample%bit )
$div(%__samplerate%,1000).$div($mod(%__samplerate%,1000),100)kHz 
$caps($if($stricmp($codec(),MP3),%__mp3_stereo_mode%,$channels()))


// Replaygain Formatting
$char(10)$get(defaultcolor) 
$if($or(%__replaygain_track_gain%,%__replaygain_album_gain%),
['['Ag']' %__replaygain_album_gain%]
$if(%__replaygain_album_gain%,
$ifgreater(%__replaygain_album_gain%,-10,$get(headingcolor_dim)0$get(defaultcolor),) ,)
['['Tg']' %__replaygain_track_gain%],
$get(missingcolor)there is no gain)

// Time formatting
$char(10)$get(defaultcolor) 
[%_time_elapsed%'/']
[%_length%]


$if(%_isplaying%,
' ▪ '
'['%_time_remaining%']'
' ▪ '
$muldiv(%_time_elapsed_seconds%,100,%_time_total_seconds%)'%',)

// File size formatting
' ▪ '
$div(%_filesize%,1048576).$num($div($mul($mod(%_filesize%,1048576),100),1048576),2) MB
)

11/11/2006:
added: Played Yesterday to statistics.

i hope more people share their configs in here..
and less thread crapping. can a mod please remove threads after this and perhaps it will prove to be useful.

Your Track-Info-Mod-Configs!

Reply #2 – 2006-11-29 05:36:41

my spin on some code that is around:

Code: [Select]

////////background  
$imageabs(0,0,images\maybe.png,)

$align(center,top)
$font(Anime Ace, 8, bold glow-0-0-0,255-255-255)

////////codec
$if($stricmp($substr(%codec%,1,7),windows),WMA,[%codec%]$char(32)|$char(32))

////////encode
$if($stricmp($codec(),mp3),
$if($stricmp(%__extrainfo%,VBR),VBR$char(32)|,$char(32)CBR$char(32)|$char(32)),)
$char(32)%__bitrate_dynamic%$char(32)kbps$char(32)|$char(32)

////////channels
$if($stricmp(%channels%,8ch),7.1$char(32),)
$if($stricmp(%channels%,7ch),6.1$char(32),)
$if($stricmp(%channels%,6ch),5.1$char(32),)

////////mode
$if($stricmp(%__mp3_stereo_mode%,joint stereo)JOINT STEREO$char(32)|,)
$if($stricmp(%channels%,stereo),STEREO$char(32)|,)
$if($stricmp(%channels%,MONO),MONO$char(32)|,)

/////////tag type
$if($strstr($info(tagtype),id3v1),$char(32)ID3V1$char(32),)
$if($strstr($info(tagtype),id3v2),$char(32)ID3V2$char(32),)
$if($strstr($info(tagtype),apev2),$char(32)APEV2,)

////////replaygain
$font(Anime Ace,8, bold glow-0-0-0,255-255-255)
$if(%__replaygain_track_gain%,$char(32)|$char(32)ReplayGain,)

/////////title
$alignabs(10,14,%_width%,%_height%,,)
$font(Anime Ace,12,bold glow-50-50-50 ,200-200-200)
[%artist% '/' ][%title%]

////////album
$alignabs(25,42,%_width%,%_height%,,)
$font(Anime Ace,8, bold glow-50-50-50,200-200-200)
[%album%][$char(32)'('%date%')']

////////status

$puts(count_idx,$add($mod(%_time_elapsed_seconds%,40),1))
$puts(count_path,images\count$get(count_idx).png)
$imageabs($sub(%_width%,102),3,$get(count_path),)

$if(%_ispaused%,
$alignabs($sub(%_width%,72),24,%_width%,%_height%,,)
$font(Lucida Sans Unicode,30, bold glow-0-0-0,200-200-200)
▮▮,
$alignabs($sub(%_width%,67),16,%_width%,%_height%,,)
$font(Lucida Sans Unicode,36, bold glow-0-0-0,200-200-200)
▶ )

////////progress
$alignabs(13,80,%_width%,%_height%,,)
$font(lucida sans unicode,8,bold glow-50-50-50 ,200-200-200)
%playback_time%

$drawrect(0,73,$sub(%_width%,132),7,pencolor-200-200-200 brushcolor-0-0-0 width-1)

$if3($strcmp(%playback_time_seconds%,0)
,,$drawrect(2,75,$muldiv(%playback_time_seconds%,$sub(%_width%,136),%length_seconds%),3,pencolor-200-200-200 brushcolor-200-200-200 width-1)
,)

$alignabs($sub(%_width%,148),80,%_width%,%_height%,,)
%playback_time_remaining%


///////PLAY/PAUSE
$button(776,30,0,0,28,30, 
$if($or(%ispaused%,$not(%isplaying%)),images\pause123.png,images\play2.png),
$if($or(%ispaused%,$not(%isplaying%)),images\pause123.png,images\play2.png),
$if($or(%ispaused%,$not(%isplaying%)),play,pause)
,)

///////PREVIOUS

$button(669,55,0,0,22,24,images\prev1.png,images\prev1_h1.png,previous,)


///////NEXT

$button(691,55,0,0,22,24,images\next1.png,images\next1_h1.png,next,) 


//////////VOLUME CONTROLS

$if($stricmp(100,$get(volume)),
$button(743,80,0,0,22,22,images\mute_1.png,images\mute_h1.png,Volume mute,),
$button(743,80,0,0,22,22,images\mute_1.png,images\mute_h1.png,Volume mute,))

[!--sizeo:1--][span style=\"font-size:8pt;line-height:100%\"][!--/sizeo--]Moderation: shortened CODE to CODEBOX.[/size]

Your Track-Info-Mod-Configs!

Reply #3 – 2006-11-29 06:37:57

I think we've problem sir

Your Track-Info-Mod-Configs!

Reply #4 – 2006-11-30 01:22:00

Quote from: SD14 on 2006-11-29 05:36:41

my spin on some code that is around:

Hmm! This looks pretty similar to mine. Especially the spinny thing i invented, heh. I like the background, could you post it please?

Your Track-Info-Mod-Configs!

Reply #5 – 2006-11-30 01:44:50

Quote from: rouge on 2006-11-30 01:22:00

Quote from: SD14 on 2006-11-29 05:36:41

my spin on some code that is around:

Hmm! This looks pretty similar to mine. Especially the spinny thing i invented, heh. I like the background, could you post it please?

ya, i took urs and changed it a little and added buttons.

Your Track-Info-Mod-Configs!

Reply #6 – 2006-11-30 02:39:52

Quote from: SD14 on 2006-11-30 01:44:50

Quote from: rouge on 2006-11-30 01:22:00

Quote from: SD14 on 2006-11-29 05:36:41

my spin on some code that is around:

Hmm! This looks pretty similar to mine. Especially the spinny thing i invented, heh. I like the background, could you post it please?

ya, i took urs and changed it a little and added buttons.

Well, it looks pretty good. Has sort-of a comic book feel about it.

Your Track-Info-Mod-Configs!

Reply #7 – 2006-11-30 03:09:31

ya that is kind of what i was going for and the buttons aren't really to noticeable either

Your Track-Info-Mod-Configs!

Reply #8 – 2006-11-30 04:57:07

I just use hot keys to control everything. No need for buttons.

Your Track-Info-Mod-Configs!

Reply #9 – 2007-01-13 15:23:38

SD14
Hi I tried your config, but I have some problems.

1) The window is not updating, it's static. It applies to all configs I tried. What's wrong?

2) The rotating wheel at the right side is missing. This might be related to problem #1.

3) Can the background be automatically stretched to fill in the window size?

Your Track-Info-Mod-Configs!

Reply #10 – 2007-01-13 15:32:27

Quote from: vlada on 2007-01-13 15:23:38

SD14
Hi I tried your config, but I have some problems.

1) The window is not updating, it's static. It applies to all configs I tried. What's wrong?

2) The rotating wheel at the right side is missing. This might be related to problem #1.

3) Can the background be automatically stretched to fill in the window size?

The newest track info mod panel can separate code based on a per track basis, or per second. SD14's config is from an older version of the panel. To get it to work, it would need to have certain information placed under a "//PerSecond" heading. Track specific information (i.e. Artist, Title, etc.) would go under a "//PerTrack" section.

The image could be expanded if you incorporate the "NOKEEPASPECT" function. Check the track_info_mod thread for useage.

Your Track-Info-Mod-Configs!

Reply #11 – 2008-02-15 03:47:39

Quote from: BaByB0y on 2006-11-29 06:37:57

I think we've problem sir

I have the same problem, it must be something with the background. I can't read the scripting but the first few lines references the background PNG image, can someone check it?

Edit, I fixed it (and I'm so proud that I did so):

Replace: $imageabs(0,0,images\FOOBOTTOM.png,) with: $imageabs2(399,46,0,0,399,46,0,0,X:\foobar\images\bg.png,)

whoo!

Edit 2: Also, I replaced the filename FOOBOTTOM.png to bg.png (a bit easier to work with) but I'm sure it can be named anything.

Notice