Oh wow. back up your title strings before upgrading. I didn't and lost 'em. I went back to the old version to rewrite 'em. And I was *this* close to posting it too. ::sigh::
This is what I managed to throw together in 5 minutes, still has work to go. The only really original thing in it is that I put the percent progress inside the progress bar instead of outside.
// Original code by necropimp, modified by AstreaEdge, final by KockRoach
// Appearance changed by Habla. Muchas gracias to those above!
// Changed again by PiezoTransducer
// font: Arial Narrow 8pt, background: 0,0,16
// !!!!BEGIN USER CONFIGURATION!!!!
// Info Heading Color e.g. "Title:"
$puts(head,$rgb(61,129,193))
// Info Color e.g. "Black Dog"
$puts(info,$rgb(255,255,255))
// Info Color e.g. "Black Dog"
$puts(info2,$rgb(212,212,212))
// Info Color e.g. "Black Dog"
$puts(info3,$rgb(170,170,170))
// Info Annotation Color (e.g. kbps is the annotation)
$puts(anno,$rgb(128,255,16))
// Info Annotation Color (e.g. kbps is the annotation)
$puts(nota,$rgb(255,170,16))
// Separator
// the separators (Song,Play,Tech info) will change to a different color if the panel mode is set to Follow cursor.
// change "followcursorcol" to change this color. It is currently set to flash orange.
$puts(followcursorcol,$rgb(200,150,50))
$puts(text2,$rgb(255,255,255))
$puts(text1,$if(%_trackinfo_nowplaying%,$rgb(61,129,193))$if(%_trackinfo_followcursor%,$get(followcursorcol)))
$puts(fadeend,$rgb(0,0,0))
$puts(seplen,29)
$puts(sepchar,'_')
// Set Rating character
$puts(ratingchar,'●')
// !!!!END USER CONFIGURATION!!!!
// Day Conversion
$puts(day,$substr(%last_played%,9,10))
$if(%last_played%,
$if($strcmp($left($get(day),1),0),$puts(day,$right($get(day),1))))
$if($strcmp($get(day),11),$puts(xx,th),
$if($strcmp($get(day),12),$puts(xx,th),
$if($strcmp($get(day),13),$puts(xx,th),
$if($strcmp($right($get(day),1),1),$puts(xx,st),
$if($strcmp($right($get(day),1),2),$puts(xx,nd),
$if($strcmp($right($get(day),1),3),$puts(xx,rd),
$puts(xx,th)))))))
// Month Conversion
$puts(month,$substr(%last_played%,6,7))
$puts(month_name,$select($get(month),
Jan,Feb,Mar,Apr,May,Jun,Jul,Aug,Sep,Oct,Nov,Dec))
// Year Conversion
$puts(year,$substr(%last_played%,1,4))
// Time Conversion
$puts(hour,$substr(%last_played%,12,13))
$puts(min,$substr(%last_played%,14,16))
// 24 Hour to 12 Hour Conversion
$if($strcmp($left($get(hour),1),0),$puts(hour1,$right($get(hour),1)))
$if($strcmp($left($get(hour),1),1),$puts(hour1,$sub($get(hour),12)))
$if($strcmp($left($get(hour),1),2),$puts(hour1,$sub($get(hour),12)))
$if($strcmp($get(hour),00),$puts(hour1,12))
$if($strcmp($get(hour),10),$puts(hour1,10))
$if($strcmp($get(hour),11),$puts(hour1,11))
$if($strcmp($get(hour),12),$puts(hour1,12))
// AM/PM Conversion
$if($strcmp($get(hour),00),$puts(yy,am))
$if($strcmp($get(hour),10),$puts(yy,am))
$if($strcmp($get(hour),11),$puts(yy,am))
$if($strcmp($get(hour),12),$puts(yy,pm))
$if($strcmp($get(hour),24),$puts(yy,am))
$if($strcmp($left($get(hour),1),0),$puts(yy,am))
$if($strcmp($left($get(hour),1),1),$puts(yy,pm))
$if($strcmp($left($get(hour),1),2),$puts(yy,pm))
// Date Format
$puts(time_of_year,$get(month_name) $get(day)$get(xx)',' $get(year))
// Time Format
$puts(time_of_day,$get(hour1)$get(min) $get(yy))
$char(1)C$get(anno)'['$get(head)$progress(%_time_elapsed_seconds%,%_time_total_seconds%,100,
$get(info)$muldiv(%_time_elapsed_seconds%,100,%_length_seconds%)'%'$get(head),
'|')$get(anno)']'$char(10)
// SONG INFO SEPARATOR
$char(1)R$transition($repeat($get(sepchar),$get(seplen)),$get(fadeend),$get(text1))$get(text1)'[' $get(text2)S o n g I n f o $get(text1)']'$char(10)
$if(%title%,$char(1)C$if(%tracknumber%,$get(anno)'['%tracknumber%'] ')$get(info)%title%$char(10))
$if(%artist%,$char(1)C$get(info2)%artist%$char(10))
$if(%album%,$char(1)C$get(info3)%album% $if(%disc%,$get(nota)'[disc '%disc%']' )$if(%date%,$get(anno)'('%date%')')$char(10))
$if(%genre%,$char(1)C$get(info)%genre%$char(10))
$if(%rating%,
$char(1)C
$repeat($get(info)$get(ratingchar),%rating%)
$repeat($rgb(70,70,70)$get(ratingchar),$sub(5,%rating%))$tab()$char(10)
)
// TECH INFO SEPARATOR
$char(1)R$transition($repeat($get(sepchar),$get(seplen)),$get(fadeend),$get(text1))$get(text1)'[' $get(text2)T e c h I n f o $get(text1)']'$char(10)
$get(head)Length: $get(info)$if(%_isplaying%,%_time_elapsed%$get(anno)$if(%_length%, / %_length%,)$if(%_length%, / -%_time_remaining%),%_length%)$char(10)
$get(head)Type:$if(%__codec%, $get(info)%__codec%) $get(info)
$if2(%__bitrate_dynamic%,%__bitrate%) $get(anno)Kb/s $if($stricmp(%__codec%,mp3),$if($stricmp(%__extrainfo%,vbr),VBR,CBR))
$char(10)
$if(%__lame_version%,$get(head)Preset: $get(info)$left(%__lame_version%,4) $right(%__lame_version%,4) [$upper(%__lame_profile%)]$char(10),)
$if(%__flac_vendor%,$get(head)Encoder: $get(info)$if($stricmp(%__flac_vendor%,reference libFLAC 1.1.2 20050205),FLAC 1.1.2 -8)$char(10),)
$if(%__mpc_profile%,$get(head)MPC Profile: $get(info)%__mpc_profile%$char(10),)
$get(head)Compression: $get(info)$div(1411,%__bitrate%).$substr($muldiv(1411,100,%__bitrate%),2,3):1 '('$get(info)$muldiv(%__bitrate%,100,1411)$get(anno)'%)'$char(10)
$get(head)Channels: $get(info)$if($stricmp($codec(),MP3),$get(space2)$caps(%__mp3_stereo_mode%),
$if(%__channels%,$ifgreater(%__channels%,1,Stereo,Mono),'?'))$char(10)
$if(%__bitspersample%,$get(head)Bitdepth: $get(info)%__bitspersample% bits/sample$char(10),)
$if(%__samplerate%,$get(head)Samplerate: $get(info)$div(%__samplerate%,1000).$substr(%__samplerate%,3,3) KHz $char(10))
$if(%last_played%,
// PLAY STATS SEPARATOR
$char(1)R$transition($repeat($get(sepchar),$get(seplen)),$get(fadeend),$get(text1))$get(text1)'[' $get(text2)P l a y I n f o $get(text1)']'
$char(10),)
$if(%play_count%,$get(head)Played $get(info)%play_count% times$char(10))
$if(%last_played%,$get(head)Last played on $get(info)$get(time_of_year) at $get(time_of_day)$char(10),)
Also, check out the wiki