Skip to main content ↑ ↓

Notice

Please note that most of the software linked on this forum is likely to be safe to use. If you are unsure, feel free to ask in the relevant topics, or send a private message to an administrator or moderator. To help curb the problems of false positives, or in the event that you do find actual malware, you can contribute through the article linked here.
Topic: REACT 2 Released (Read 1281387 times) previous topic - next topic
0 Members and 2 Guests are viewing this topic.

REACT 2 Released

Reply #275 –
Quote from: Martin H on
You need to download metamp3 v0.92b4 from this page : http://www.hydrogenaudio.org/forums/index....showtopic=49751

Then you also need an external manifest file to get the beta to run, so follow the instructions from this previous post of mine : http://www.hydrogenaudio.org/forums/index....st&p=478005


Hi,  I have downloaded metamp3 v0.92b5 (not b4 as you suggest as I can't find this anymore) and now I am not getting any tags at all added to my mp3 files via REACT.
I think its something to do with the --pict parameter not appearing in the metamp3.txt file. Presumably I now need to make changes to the REACT config files to get all this working again since the metamp3 command line parameters have changed - I think its the %Cover_tag% and possibly the %VA-tag% fields that need changing, but what do they need changing to and does the mp3 image bit need to change as well.
I have checked that metamp3 does work by adding an artist without using REACT.

REACT 2 Released

Reply #276 –
Thanks to some encouragement from Synthetic Soul I have braved my first day with REACT.  I know have it doing everything I need apart from a few things and I was advised to post here rather than in my 'Help' thread.

I am managing to modify the REACT files but I am a batchfile newbie

I unREMed the logfile line and added a cuesheet command to REACT-track.cfg to move the log and cuesheet

IF @Flac@==1 (
      PUSHD %TrackDir_Flac%
         IF %add_rg%==1 @tools@\Glob.exe -v -c @tools@\metaflac.exe %RG_MetaFlac% *.flac
         COPY /Y "@eaclog@" "@album@ EAClog.txt"
         COPY /Y "@albumfile@.[mg].cue" "@album@ (noncmpl).cue"
      POPD
   )
   
This is great, as react also creates the cuesheet for me.  However react insists on %D in the EAC naming scheme whereas I do not use the artist name in the FLAC/MP3 names.  Therefore the cuesheet FILE entries do not match the FLAC (or extracted WAVS).  I can use a text editor to correct the cuesheet (searching for '"* -- ' IOW the part of the filename to the first divider)  Can I script this within react?.

I manually add the accuraterip info to the log, I am considering delaying the copying of the logfile so I can add the accrip info to the temporary log and have react then move it to the FLAC and MP3 directories.  My question is can I make an entry in REACT-track.cfg which would put up a prompt reminding the user to copy the accrip info, then take the clipboard contents and append it to the temporary logfile before duplicating this to FLAC and MP3?

I had to change the FLAC tag to '-T tracknumber="@track@" -T totaltracks="@numtracks@"' rather than use 1/18 (with lame these end up in different fields but not with the default for flac)  With the default foobar could not pad the numbers

Finally, I removed the +3.0dB from the ini file, was this right? (the author said it was to get some extra volume on his portable?).  So I have AdjustAlbumGain_dB=+0.0.  I haven't used replaygain before, I understand it does not change the actual FLAC, but I might like the MP3 file to be modified (can an ipod shuffle understand replaygain?  I can create the MP3 after if REACT does not permit this)

Thanks in advance
L

REACT 2 Released

Reply #277 –
Can anyone confirm the replaygain settings?  I am ripping to FLAC tracks and (sometimes) LAME mp3

ReplayGain     Enable/Disable ReplayGain calculation and tagging.
I want this on to add tags to my flacs and mp3? Will this setting alone RG as an album?

ApplyAlbumGain    Apply the album gain to the files, so they are played back with a consistent volume across the albums on every player.
So will this actually adjust the mp3, not just tag it (but leave the flac as is with RG tags?).  If this is off will the flac tracks be RGed as an album?
Quote
@Meddler: You are correct. ApplyAlbumGain should probably have been set to 0 by default. Note that 'ApplyAlbumGain' is only for lossy formats. FLAC and WAVPACK are always tagged only.
Ok, so...
Quote
If you don't want to apply album gain, set ApplyAlbumGain=0 in the REACT.ini file.
If you don't want replay gain tags at all, set ReplayGain=0 in the REACT.ini file.
This is what is confusing me, I want album gain, but not to 'apply' it.  By 'apply' I guess you mean directly to the files

AdjustAlbumGain_dB    If you want to adjust the album gain from 89.0 dB when applying to the audio, set adjustment in dB here.
Is this for the flac file tags, or just the adjusted mp3 as questioned above.

AddCuesheetAG    Add Album gain/Album peak values to the cuesheet as REM lines. This implies that WaveGain is ran.
I have tracks and a cusheet, but I guess I do not need this

UseWaveGainAG    Instruct to use WaveGain to calculate AlbumGain values on the wav image file. The values will be transferred to the various compressed formats, rather than calculating them via other tools. If ApplyAlbumGain=1, LAME and OggEnc2 will use the --scale option to apply the album gain scale factor calculated by WaveGain.
Again, not needed for individual tracks?

REACT 2 Released

Reply #278 –
I don't use ReplayGain, so I can't really answer your RG questions.

Quote from: lipidicman on
This is great, as react also creates the cuesheet for me. However react insists on %D in the EAC naming scheme whereas I do not use the artist name in the FLAC/MP3 names. Therefore the cuesheet FILE entries do not match the FLAC (or extracted WAVS). I can use a text editor to correct the cuesheet (searching for '"* -- ' IOW the part of the filename to the first divider) Can I script this within react?.
You could do what you need using SED, but it's a tool that I'm not familiar with, so I can't really advise any further.

Quote from: lipidicman on
I manually add the accuraterip info to the log, I am considering delaying the copying of the logfile so I can add the accrip info to the temporary log and have react then move it to the FLAC and MP3 directories. My question is can I make an entry in REACT-track.cfg which would put up a prompt reminding the user to copy the accrip info, then take the clipboard contents and append it to the temporary logfile before duplicating this to FLAC and MP3?
You can easily get the script to display a reminder and pause, but I don't know about copying rfom the clipboard.  If the info was all on one line you could enter it at a prompt, but I suspect it isn't.  To pause with a message just add the lines:

Code: [Select]
ECHO Please copy the accuraterip info to the logfile and then press any key.
PAUSE>NUL

Quote from: lipidicman on
Finally, I removed the +3.0dB from the ini file, was this right? (the author said it was to get some extra volume on his portable?). So I have AdjustAlbumGain_dB=+0.0. I haven't used replaygain before, I understand it does not change the actual FLAC, but I might like the MP3 file to be modified (can an ipod shuffle understand replaygain? I can create the MP3 after if REACT does not permit this)
I increase files to 97dB for my Creative Zen, as I found quiter albums needed too much volume, and many of my albums were at that sort of level in the first place.  For my car stereo I use 89dB.

I think your subsequent questions mean that you have a better understanding of RG, so I'll not say much.  Normally RG is used to just tag the files so that an RG-aware player will adjust the level accordingly.  However, REACT will also let you apply the gain to the files, so that the volume is physically changed, and any player will play at the new volume.
I'm on a horse.

REACT 2 Released

Reply #279 –
Thanks for the tip about SED, I am looking into it now.

I really don't know much about replaygain.  I like the idea of having it in the tags as I can easily tell foobar to ignore it.  I also quite like the idea of having my mp3 files actually adjusted so they play ok on my shuffle.

Now I am settling on having react create my flacs and using foobar to make the mp3 as I need them.  Can convert create mp3 with the actual levels adjusted using the flac tags (or by calculating them itself)

REACT 2 Released

Reply #280 –
I'm a little strapped for time at the mo, so I probably won't get chance to action, but my current thought is this (given that I'd like a solution that anyone can use):
  • On every track write a SED command, to change that track's FILE reference in the cuesheet, to a text file (sed-commands.txt).
  • Use REACT's $ tokens to create the find/replace values.
  • On the last track use SED -f sed-commands.txt <old >new to perform the find and replaces (see tutorial).
This should create a process that anyone can easily use to amend the cuesheet to their requirements.

If you aren't successful by the time I can find some time I'll have a go myself.
I'm on a horse.

REACT 2 Released

Reply #281 –
Quote from: Synthetic Soul on
  • On every track write a SED command, to change that track's FILE reference in the cuesheet, to a text file (sed-commands.txt).
  • Use REACT's $ tokens to create the find/replace values.
  • On the last track use SED -f sed-commands.txt <old >new to perform the find and replaces (see tutorial).



I don't understand the first line.  I think I am thinking of a solution that would only work for me, I wanted to test the idea in a very simple way.  I need to remove "Pearl Jam  -- " etc as REACT insists on %D in the EAC naming, but my react naming does not have the artist.  I thought I could use "@artist@ -- " in the SED command to achieve this.  I would then issue a SED command with .wav for .flac.

REACT 2 Released

Reply #282 –
Not everyone wants to just remove the first part, so I would like a solution that worked for any replacement format.

On thinking there is no need to create a text file with all the commands, you may as well just run SED for each track.

I think you could use something like:

Code: [Select]
SED 's/$artist$ \-\- \(.*\)\.wav/\1\.flac/' <old.cue >new.cue

..but that's untested, and likely only 90% there!
I'm on a horse.

REACT 2 Released

Reply #283 –
I've just managed to do a quick test with a dummy "cuesheet" and by George I think I was 100% right!

Therefore, instead of:

Code: [Select]
COPY /Y "@albumfile@.[mg].cue" "@album@ (noncmpl).cue"

... you could try:

Code: [Select]
@tools@\SED 's/$artist$ \-\- \(.*\)\.wav/\1\.flac/' <"@albumfile@.[mg].cue" >"@album@ (noncmpl).cue"

(put SED.EXE in your tools directory)
I'm on a horse.

REACT 2 Released

Reply #284 –
Thank you very much SS.  I will give that a shot when I get home.

edit: I haven't tried this and I understand most of it (had a look at SED earlier)
I followed the tutorial with: sed 's/day/night/' <old >new
and even
sed 's_/usr/local/bin_/common/bin_' <old >new
Some people use commas, others use the "|" character. Pick one you like. As long as it's not in the string you are looking for, anything goes not sure I get why this works

but yours:
's/$artist$ \-\- \(.*\)\.wav/\1\.flac/'

I get the s/ and $artist$
but
why \-\- for --
and
(.*\) has me lost

I need to replace '$artist$ -- ' with *nothing*, zip zilch
also shouldn't it end with '.wav/.flac/'

Don't take this the wrong way.  I'm not saying it wont work.  I am asking why it does!

edit2: Just read some more of the tutorial and delved into regular expressions.  My brain hurts.  I find the slashes very unreadable.  I don't follow what \1 is for (this doesn't really matter for now) but why cant I simply use '.wav/.flac/'?

edit3: sorry about the mess I tried
SED -e "s/Pearl Jam -- //" -e "s/.wav/.flac/" <"test.txt" >"testoutput.txt"
and this worked
so what do you think of
@tools@\SED -e "s/$artist$ -- //" -e "s/.wav/.flac/" <"@albumfile@.[mg].cue" >"@album@ (noncmpl).cue"
To me this is more readable and seems to work
Oh, and thanks again!

REACT 2 Released

Reply #285 –
I've run further tests, and come up with a solution that would work for any set-up.

I forgot why I originally suggested using SED's -f switch, and that is so that we can easily run multiple replacements on the cuesheet.  I think that often we could just do one replace, to remove the artist (as per lipidicman), or both artist and album, but it's useful to be able to replace the standard "$artist$ - $album$ - $track$ - $title$.wav" format with anything we want, which may require a specific replace for each track.

The process involves writing a SED command for each track to a temporary text file, and then running them all in one go.

The two key lines are:

Code: [Select]
ECHO s/FILE "$artist$ \- $album$ \- $track$ \- $title$\.wav"/FILE "$track$ \- $title$\.flac"/>>sedlist.txt
This line will be run for each track, and writes the SED command to the temporary file "sedlist.txt".  The example above replaces "$artist$ - $album$ - $track$ - $title$.wav"  with "$track$ - $title$.flac" .  Notice that the hypens and file delimiter are all escaped with a backslash.

Code: [Select]
@tools@\SED -f sedlist.txt <"@albumfile@.[mg].cue" >"$cdartist$ - $album$.cue"
The call to SED  is only made at the end.  It runs the SED commands in sedlist.txt on  "@albumfile@.[mg].cue"  and outputs the result to "$cdartist$ - $album$.cue".

I had to comment out the codepage change (CHCP 1252) to achieve this, as SED was writing some  characters shit at the beginning of the new cuesheet.

Add in a line to delete "sedlist.txt" after the call to SED and you're basically there.

Here is my test config for reference (MP3 used):

Code: [Select]
@ECHO OFF
REM CHCP 1252
TITLE @track@/@numtracks@ - "@album@"

REM Copyright © Tycho, 2006
REM
REM ** Create compressed audio tracks from ripped .wav tracks.
REM **
REM ** You may consider using image mode (F10)
REM ** as it supports creating tracks via acdir.exe,
REM ** and post-processing will always work (see below).
REM **
REM ** Flac requires flac.exe/metaflac.exe (v1.1.3)
REM ** NeroAac requires NeroAacEnc.exe/NeroAacTag.exe/AacGain.exe.
REM ** OggEnc2 requires OggEnc2.exe/VorbisGain.exe.
REM **
REM ** I prefer applying album gain 92dB to get a reasonable
REM ** volume for my DAP. The RG tags are still relative
REM ** to 89dB SPL, i.e. album gain will be about -3.0dB.


REM ============== Begin Main Script ==================


IF @Debug@==1 ECHO ON

SET TrackDir_Flac="@TrackDir_Flac@"
SET TrackDir_Wavpack="@TrackDir_Wavpack@"
SET TrackDir_MP3="@TrackDir_MP3@"
SET TrackDir_AAC="@TrackDir_AAC@"
SET TrackDir_OGG="@TrackDir_OGG@"

IF @various@==0    SET TrackName=@TrackName_SA@
IF @various@==1    SET TrackName=@TrackName_VA@

SET have_cover=0
SET embed_cover=0

IF EXIST "@cover@" (
    SET have_cover=1
    SET embed_cover=@EmbedCover@
)

REM ---- Track ----

IF NOT @Flac@==1 GOTO end_flac_tracks
    IF NOT EXIST %TrackDir_Flac% MKDIR %TrackDir_Flac%
    PUSHD %TrackDir_Flac%
        IF @various@==1 SET VA_tag=-T "album artist=@VA@"
        IF %embed_cover%==1 SET Cover_tag=--picture="|image/jpeg|||@cover@"
        ECHO ON
        @tools@\flac.exe @Opt_Flac@ %Cover_tag% %VA_tag% -T artist="@artist@" -T album="@album@" -T tracknumber="@track@/@numtracks@" -T title="@title@" -T date="@year@" -T genre="@genre@" -T comment="@comment@" -T encoded-by="%USERNAME%" -T encoding="Flac @Ver_Flac@ @Opt_Flac@" "@source@" -o "%TrackName%.flac"
        @ECHO OFF
        IF %have_cover%==1 IF NOT EXIST folder.jpg COPY "@cover@" folder.jpg
    POPD
:end_flac_tracks


IF NOT @Wavpack@==1 GOTO end_wavpack_tracks
    IF NOT EXIST %TrackDir_Wavpack% MKDIR %TrackDir_Wavpack%
    PUSHD %TrackDir_Wavpack%
        IF @various@==1 SET VA_tag=-w "album artist=@VA@"
        ECHO ON
        @tools@\wavpack.exe @Opt_Wavpack@ %VA_tag% -w artist="@artist@" -w album="@album@" -w track="@track@/@numtracks@" -w title="@title@" -w year="@year@" -w genre="@genre@" -w comment="@comment@" -w encodedby="%USERNAME%" -w encodersettings="Wavpack @Ver_Wavpack@ @Opt_Wavpack@" "@source@" "%TrackName%.wv"
        @ECHO OFF
        IF %have_cover%==1 IF NOT EXIST folder.jpg COPY "@cover@" folder.jpg
        TITLE @track@/@numtracks@ - "@album@"
    POPD
:end_wavpack_tracks


IF NOT @LameMP3@==1 GOTO end_lame_tracks
    IF NOT EXIST %TrackDir_MP3% MKDIR %TrackDir_MP3%
    PUSHD %TrackDir_MP3%
        IF @various@==1 SET VA_tag=--user-text "[album artist]@VA@" --frame "TPE2:@VA@"
        IF %embed_cover%==1 SET Cover_tag=--pict "{3}@cover@"
        ECHO ON
        @tools@\lame.exe @Opt_LameMP3@ "@source@" "%TrackName%.mp3"
        @tools@\metamp3.exe %Cover_tag% %VA_tag% --artist "@artist@" --album "@album@" --track @track@/@numtracks@ --title "@title@" --year "@year@" --genre "@genre@" --comment "@comment@" --frame TENC:"%USERNAME%" --frame TSSE:"LAME @Ver_LameMP3@ @Opt_LameMP3@" "%TrackName%.mp3"
        ECHO s/FILE "$artist$ \- $album$ \- $track$ \- $title$\.wav"/FILE "$track$ \- $title$\.mp3"/>>sedlist.txt
        @ECHO OFF
        IF %have_cover%==1 IF NOT EXIST folder.jpg COPY "@cover@" folder.jpg
        
    POPD
:end_lame_tracks


IF NOT @iTunesAac@==1 GOTO end_itunes_aac_tracks
    IF NOT EXIST %TrackDir_AAC% MKDIR %TrackDir_AAC%
    PUSHD %TrackDir_AAC%
        IF %embed_cover%==1 SET Cover_tag=-r "@cover@"
        ECHO ON
        @tools@\iTunesEncode.exe @Opt_iTunesAac@ -e "AAC Encoder" %Cover_tag% -x @various@ -a "@artist@" -l "@album@" -n "@track@" -m "@numtracks@" -t "@title@" -y "@year@" -g "@genre@" -c "@comment@" -i "@source@" -o "%TrackName%.m4a"
        @ECHO OFF
        IF %have_cover%==1 IF NOT EXIST folder.jpg COPY "@cover@" folder.jpg
    POPD
    GOTO end_nero_aac_tracks
:end_itunes_aac_tracks

IF NOT @NeroAac@==1 GOTO end_nero_aac_tracks
    IF NOT EXIST %TrackDir_AAC% MKDIR %TrackDir_AAC%
    PUSHD %TrackDir_AAC%
        IF @various@==1 SET VA_tag=--albumArtist "@VA@" --compilation true
        IF %embed_cover%==1 SET Cover_tag=--artwork "@cover@"
        ECHO ON
        @tools@\neroAacEnc.exe @Opt_NeroAac@ -if "@source@" -of "%TrackName%.m4a"
        @tools@\AtomicParsley.exe "%TrackName%.m4a" -o REACT_tmp.m4a %Cover_tag% %VA_tag% --artist "@artist@" --album "@album@" --tracknum "@track@/@numtracks@" --title "@title@" --year "@year@" --genre "@genre@" --comment "@comment@" --encodingTool "neroAacEnc @Ver_NeroAac@ @Opt_NeroAac@"
        @ECHO OFF
        MOVE /Y REACT_tmp.m4a "%TrackName%.m4a"
        IF %have_cover%==1 IF NOT EXIST folder.jpg COPY "@cover@" folder.jpg
    POPD
:end_nero_aac_tracks


IF NOT @OggEnc2@==1 GOTO end_oggenc_tracks
    IF NOT EXIST %TrackDir_OGG% MKDIR %TrackDir_OGG%
    PUSHD %TrackDir_OGG%
        IF @various@==1 SET VA_tag=-c "album artist=@VA@"
        ECHO ON
        @tools@\oggenc2.exe @Opt_OggEnc2@ %VA_tag% -c artist="@artist@" -c album="@album@" -c tracknumber="@track@/@numtracks@" -c title="@title@" -c date="@year@" -c genre="@genre@" -c comment="@comment@" -c encoded-by="%USERNAME%" -c encoding="OggEnc @Ver_OggEnc2@ @Opt_OggEnc2@" "@source@" -o "%TrackName%.ogg"
        @ECHO OFF
        IF %have_cover%==1 IF NOT EXIST folder.jpg COPY "@cover@" folder.jpg
    POPD
:end_oggenc_tracks


REM ** Delete the source .wav
DEL "@source@"


REM ---- Post-processing ----


rem ** Scan and compute ReplayGain and add cover picture for supported formats.
rem ** NB: The following will only work if at least the last track is selected,
rem ** and it is a regular audio track.

IF NOT @track@==@numtracks@ GOTO end_post_process

    SET add_rg=@ReplayGain@
    SET aac_enc=@NeroAac@
    IF @iTunesAac@==1 SET aac_enc=1

    IF NOT @ReplayGain@==1 GOTO end_RG
        SET RG_MetaFlac=--add-replay-gain
        SET RG_MetaMP3=--replay-gain
    :end_RG

    IF NOT @ApplyAlbumGain@==1 GOTO end_apply_AG
        SET RG_MetaMP3=--apply-gain album@AdjustAlbumGain_dB@
        SET RG_AacGain=/a /o /c /d @AdjustAlbumGain_dB@
        SET add_rg=1
    :end_apply_AG


    REM ** Audio Formats:

    IF @Flac@==1 (
        PUSHD %TrackDir_Flac%
            IF %add_rg%==1 @tools@\Glob.exe -v -c @tools@\metaflac.exe %RG_MetaFlac% *.flac
            REM COPY /Y "@eaclog@" "EAClog.txt"
        POPD
    )

    IF @Wavpack@==1 (
        PUSHD %TrackDir_Wavpack%
            IF %add_rg%==1 @tools@\wvgain.exe -a *.wv
            REM COPY /Y "@eaclog@" "EAClog.txt"
        POPD
    )

    IF @LameMP3@==1 (
        PUSHD %TrackDir_MP3%
            IF %add_rg%==1 @tools@\metamp3.exe %RG_MetaMP3% *.mp3
            REM COPY /Y "@eaclog@" "EAClog.txt"
            REM COPY /Y "@albumfile@.[mg].cue" "@album@ (noncmpl).cue"
            @tools@\SED -f sedlist.txt <"@albumfile@.[mg].cue" >"$cdartist$ - $album$.cue"
            DEL sedlist.txt
        POPD
    )

    IF %aac_enc%==1 (
        PUSHD %TrackDir_AAC%
            IF %add_rg%==1 @tools@\aacgain.exe %RG_AacGain% *.m4a > "gainlog.txt"
            REM COPY /Y "@eaclog@" "EAClog.txt"
        POPD
    )

    IF @OggEnc2@==1 (
        PUSHD %TrackDir_OGG%
            IF %add_rg%==1 @tools@\vorbisgain.exe -a *.ogg
            REM COPY /Y "@eaclog@" "EAClog.txt"
        POPD
    )


    REM ** Cleanup

    DEL "@eaclog@"
    DEL "@albumfile@.[*].cue"
    DEL "@cover@"

:end_post_process


REM ================ End Main Script ===================


IF @Debug@==1 (
    PAUSE
    EXIT
)

REM ** Delete this .bat file:
DEL %0
I'm on a horse.

REACT 2 Released

Reply #286 –
Quote from: lipidicman on
but yours:
's/$artist$ \-\- \(.*\)\.wav/\1\.flac/'

I get the s/ and $artist$
but
why \-\- for --
and
(.*\) has me lost
"-" is a regular expression special character, used to provide ranges, like "a-z", so I thought it needed escaping, thus "\-" instead of "-".  I'm surprised it doesn't.  NB: escaping is essentially preceding any special character with a backslash to state that you want a string literal, instead of the normal special meaning. Therefore "-" becomes "\-", "." becomes "\.", etc.

"\(.*\)" basically means grab anything else [.*] and remember it [the brackets].  This will capture the rest of the filename, so if your filename was "$artist$ -- $album$ -- $track$ -- $title$.wav" it would match and record "$album$ -- $track$ -- $title$".  This match can then be referenced in the replacement text using "\1".

Quote from: lipidicman on
I need to replace '$artist$ -- ' with *nothing*, zip zilch
also shouldn't it end with '.wav/.flac/'
My single command simply matches  "$artist$ -- <stuff>.wav" and replaces it with "<stuff>.flac".  That's it in a nutshell.  As mentioned earlier "\(.*\)" captures "<stuff>" and "\1" references that capture.  If I knew what your filename format was I could used something more specific than ".*" I guess.

Quote from: lipidicman on
edit3: sorry about the mess I tried
SED -e "s/Pearl Jam -- //" -e "s/.wav/.flac/" <"test.txt" >"testoutput.txt"
and this worked
so what do you think of
@tools@\SED -e "s/$artist$ -- //" -e "s/.wav/.flac/" <"@albumfile@.[mg].cue" >"@album@ (noncmpl).cue"
To me this is more readable and seems to work
If you're happier with that then go with it - the concept is sound.  My solution uses one command rather than two, but I hardy think you'll get a performance hit. 

Hmm.. I see you're not escaping the "." also.  I think that may translated as "*wav" -> ".flac" (where "*" is any character), which may screw you if you have "wav" in the middle of a word.  Please test.  I would use "s/\.wav/\.flac/" (the delimiter is escaped to show it is a string literal). Check out this quick test:

Code: [Select]
C:\Documents and Settings\Neil\Desktop>sed s/.ped/.es/ test.txt
The quick brown fox ju.es over the lazy dog.
I'm on a horse.

REACT 2 Released

Reply #287 –
Wow    I see the error of my ways.

I think you are right about using \.wav looking at your example.  I didn't run into that problem as I did not have wav anywhere else in the file.  You have just saved me a lot of trouble.

Quote
My single command simply matches "$artist$ -- <stuff>.wav" and replaces it with "<stuff>.flac"

I get this now!

I think I follow your (save to a text file and then read it) method and why you have a line for each track.  This is very clever and will certainly make this more flexible.  By using the default config that REACT puts into EACs naming config it could even be added to the distribution (REACT would have to enforce the default EAC naming more strongly and the ECHO command could be derived directly from the REACT.ini?)

Thank you for taking the trouble to look at this (and to educate a newb).  I have seen several other people ask about .wav to .flac in the cuesheet and get no joy, so I really appreciate this.  My girlfriend will be happy when she can click on the cuesheets and click BURRRN.  That is, if I still have a girlfriend bearing in mind the time I spend planning my FLAC library (which luckily she is quite keen to have too)

REACT 2 Released

Reply #288 –
Quote from: lipidicman on
I think I follow your (save to a text file and then read it) method and why you have a line for each track. This is very clever and will certainly make this more flexible. By using the default config that REACT puts into EACs naming config it could even be added to the distribution (REACT would have to enforce the default EAC naming more strongly and the ECHO command could be derived directly from the REACT.ini?)
Yes, that method should be flexible enough for anyone, and I wanted a solution that anyone could adapt.  That said, I think the type of command you are using may be adequate for many - I personally name my tracks "$track$ - $title$" so I could just do a blanket removal of "$artist$ - $album$ - ".  I use image mode though.

I did think about using REACT variables to create the commands (@basename@ and %TrackName%), but I would have to write more code to escape the hyphens - i.e.: turn "$artist$ - $album$ - $track$ - $title$" into "$artist$ /- $album$ /- $track$ /- $title$".  Hmm... I just remembered that useful tool SED.  Maybe I'll have a play.

Edit:  I've just had a quick test, and a quick skim of of the tutorial, and it doesn't seem that "-" is used as a special character in SED.  I guess instead of "a-z" you have to do "[abcdefghijklmnopqrstuvwxyz]".  Anyway, that's good news for simplifying the commands.  I can't test now, but I guess the line could be changed to:

Code: [Select]
ECHO s/FILE "@basename@\.wav"/FILE "%TrackName%\.flac"/>>sedlist.txt

That makes things look a lot less complicated, and a hell of a lot more portable.  Thanks for highlighting that for me.

Quote from: lipidicman on
Thank you for taking the trouble to look at this (and to educate a newb). I have seen several other people ask about .wav to .flac in the cuesheet and get no joy, so I really appreciate this. My girlfriend will be happy when she can click on the cuesheets and click BURRRN. That is, if I still have a girlfriend bearing in mind the time I spend planning my FLAC library (which luckily she is quite keen to have too)
You're welcome. I was pleased to see the work you put in also, so I feel that my help was well-deserved.  I like a challenge as well.

It must be nice to have a girlfriend that's interested in the subject.  My wife ribs me about my obsession, and the time I spent yesterday morning posting and testing almost caused a massive argument (I was supposed to be doing jobs around the house)!  As I say though, I like a challenge.
I'm on a horse.
 

REACT 2 Released

Reply #289 –
Quote from: Synthetic Soul on
I did think about using REACT variables to create the commands (@basename@ and %TrackName%), but I would have to write more code to escape the hyphens - i.e.: turn "$artist$ - $album$ - $track$ - $title$" into "$artist$ /- $album$ /- $track$ /- $title$".  Hmm... I just remembered that useful tool SED.  Maybe I'll have a play.


Are you talking about using SED to alter the string to send to SED?  Ouch!  That would be very neat though.  This would certainly allow it to be included in REACT for everyone to benefit from.  For now I think I have a solution (I don't get home to my computer until later).

edit:  I'm trying to think through whether your method will work for VA, mine would not I fear.  Anyhow I am sold on using a sedlist.txt now!

I did try to do as much of the work as I could, but you were way ahead of me.  Your replies left me very pleasantly surprised!

My other issue was copying the accuraterip details to the clipboard and having these be inserted into the logfile.
I came up with this suite including winclip:
http://www.dmst.aueb.gr/dds/sw/outwit/

My idea is to clear the clipboard (so you dont accidentally paste the details from the previous rip! paranoia I know), ask the user to grab the accrip log and then output it to a file (winclip -p file.txt) before appending this file to the EAClog.  There is even scope for checking that the clipboard contains accrip data I guess and looping until it does (might be problems here if the window has been closed, easy to do!)

Even the idea that any of this was possible was way off of my radar a few days ago so I should thank you for the pointer towards REACT really!

Let me be clear about my GF.  She likes the end result, the fact she can grab an album or make a compilation (from our library) in a few seconds with burrrn.  She also wants a jukebox PC for the lounge.  When I try to explain the problems with the cuesheet and the fine details of the naming conventions her eyes glaze over.  Still at least there have been no arguments.

REACT 2 Released

Reply #290 –
Quote from: Synthetic Soul on
Edit:  I've just had a quick test, and a quick skim of of the tutorial, and it doesn't seem that "-" is used as a special character in SED.  I guess instead of "a-z" you have to do "[abcdefghijklmnopqrstuvwxyz]".  Anyway, that's good news for simplifying the commands.  I can't test now, but I guess the line could be changed to:

Code: [Select]
ECHO s/FILE "@basename@\.wav"/FILE "%TrackName%\.flac"/>>sedlist.txt
That makes things look a lot less complicated, and a hell of a lot more portable.  Thanks for highlighting that for me.
Tested, and works just great.  Using %TrackName% means it will work for VA albums also (tested).

Here's my current test config:

Code: [Select]
@ECHO OFF
REM CHCP 1252
TITLE @track@/@numtracks@ - "@album@"

REM Copyright © Tycho, 2006
REM
REM ** Create compressed audio tracks from ripped .wav tracks.
REM **
REM ** You may consider using image mode (F10)
REM ** as it supports creating tracks via acdir.exe,
REM ** and post-processing will always work (see below).
REM **
REM ** Flac requires flac.exe/metaflac.exe (v1.1.3)
REM ** NeroAac requires NeroAacEnc.exe/NeroAacTag.exe/AacGain.exe.
REM ** OggEnc2 requires OggEnc2.exe/VorbisGain.exe.
REM **
REM ** I prefer applying album gain 92dB to get a reasonable
REM ** volume for my DAP. The RG tags are still relative
REM ** to 89dB SPL, i.e. album gain will be about -3.0dB.


REM ============== Begin Main Script ==================


IF @Debug@==1 ECHO ON

SET TrackDir_Flac="@TrackDir_Flac@"
SET TrackDir_Wavpack="@TrackDir_Wavpack@"
SET TrackDir_MP3="@TrackDir_MP3@"
SET TrackDir_AAC="@TrackDir_AAC@"
SET TrackDir_OGG="@TrackDir_OGG@"

IF @various@==0    SET TrackName=@TrackName_SA@
IF @various@==1    SET TrackName=@TrackName_VA@

SET have_cover=0
SET embed_cover=0

IF EXIST "@cover@" (
    SET have_cover=1
    SET embed_cover=@EmbedCover@
)

REM ---- Track ----

IF NOT @Flac@==1 GOTO end_flac_tracks
    IF NOT EXIST %TrackDir_Flac% MKDIR %TrackDir_Flac%
    PUSHD %TrackDir_Flac%
        IF @various@==1 SET VA_tag=-T "album artist=@VA@"
        IF %embed_cover%==1 SET Cover_tag=--picture="|image/jpeg|||@cover@"
        ECHO ON
        @tools@\flac.exe @Opt_Flac@ %Cover_tag% %VA_tag% -T artist="@artist@" -T album="@album@" -T tracknumber="@track@/@numtracks@" -T title="@title@" -T date="@year@" -T genre="@genre@" -T comment="@comment@" -T encoded-by="%USERNAME%" -T encoding="Flac @Ver_Flac@ @Opt_Flac@" "@source@" -o "%TrackName%.flac"
        @ECHO OFF
        IF %have_cover%==1 IF NOT EXIST folder.jpg COPY "@cover@" folder.jpg
    POPD
:end_flac_tracks


IF NOT @Wavpack@==1 GOTO end_wavpack_tracks
    IF NOT EXIST %TrackDir_Wavpack% MKDIR %TrackDir_Wavpack%
    PUSHD %TrackDir_Wavpack%
        IF @various@==1 SET VA_tag=-w "album artist=@VA@"
        ECHO ON
        @tools@\wavpack.exe @Opt_Wavpack@ %VA_tag% -w artist="@artist@" -w album="@album@" -w track="@track@/@numtracks@" -w title="@title@" -w year="@year@" -w genre="@genre@" -w comment="@comment@" -w encodedby="%USERNAME%" -w encodersettings="Wavpack @Ver_Wavpack@ @Opt_Wavpack@" "@source@" "%TrackName%.wv"
        @ECHO OFF
        IF %have_cover%==1 IF NOT EXIST folder.jpg COPY "@cover@" folder.jpg
        TITLE @track@/@numtracks@ - "@album@"
    POPD
:end_wavpack_tracks


IF NOT @LameMP3@==1 GOTO end_lame_tracks
    IF NOT EXIST %TrackDir_MP3% MKDIR %TrackDir_MP3%
    PUSHD %TrackDir_MP3%
        IF @various@==1 SET VA_tag=--user-text "[album artist]@VA@" --frame "TPE2:@VA@"
        IF %embed_cover%==1 SET Cover_tag=--pict "{3}@cover@"
        ECHO ON
        @tools@\lame.exe @Opt_LameMP3@ "@source@" "%TrackName%.mp3"
        @tools@\metamp3.exe %Cover_tag% %VA_tag% --artist "@artist@" --album "@album@" --track @track@/@numtracks@ --title "@title@" --year "@year@" --genre "@genre@" --comment "@comment@" --frame TENC:"%USERNAME%" --frame TSSE:"LAME @Ver_LameMP3@ @Opt_LameMP3@" "%TrackName%.mp3"
        ECHO s/FILE "@basename@\.wav"/FILE "%TrackName%\.mp3"/>>sedlist.txt
        @ECHO OFF
        IF %have_cover%==1 IF NOT EXIST folder.jpg COPY "@cover@" folder.jpg
        
    POPD
:end_lame_tracks


IF NOT @iTunesAac@==1 GOTO end_itunes_aac_tracks
    IF NOT EXIST %TrackDir_AAC% MKDIR %TrackDir_AAC%
    PUSHD %TrackDir_AAC%
        IF %embed_cover%==1 SET Cover_tag=-r "@cover@"
        ECHO ON
        @tools@\iTunesEncode.exe @Opt_iTunesAac@ -e "AAC Encoder" %Cover_tag% -x @various@ -a "@artist@" -l "@album@" -n "@track@" -m "@numtracks@" -t "@title@" -y "@year@" -g "@genre@" -c "@comment@" -i "@source@" -o "%TrackName%.m4a"
        @ECHO OFF
        IF %have_cover%==1 IF NOT EXIST folder.jpg COPY "@cover@" folder.jpg
    POPD
    GOTO end_nero_aac_tracks
:end_itunes_aac_tracks

IF NOT @NeroAac@==1 GOTO end_nero_aac_tracks
    IF NOT EXIST %TrackDir_AAC% MKDIR %TrackDir_AAC%
    PUSHD %TrackDir_AAC%
        IF @various@==1 SET VA_tag=--albumArtist "@VA@" --compilation true
        IF %embed_cover%==1 SET Cover_tag=--artwork "@cover@"
        ECHO ON
        @tools@\neroAacEnc.exe @Opt_NeroAac@ -if "@source@" -of "%TrackName%.m4a"
        @tools@\AtomicParsley.exe "%TrackName%.m4a" -o REACT_tmp.m4a %Cover_tag% %VA_tag% --artist "@artist@" --album "@album@" --tracknum "@track@/@numtracks@" --title "@title@" --year "@year@" --genre "@genre@" --comment "@comment@" --encodingTool "neroAacEnc @Ver_NeroAac@ @Opt_NeroAac@"
        @ECHO OFF
        MOVE /Y REACT_tmp.m4a "%TrackName%.m4a"
        IF %have_cover%==1 IF NOT EXIST folder.jpg COPY "@cover@" folder.jpg
    POPD
:end_nero_aac_tracks


IF NOT @OggEnc2@==1 GOTO end_oggenc_tracks
    IF NOT EXIST %TrackDir_OGG% MKDIR %TrackDir_OGG%
    PUSHD %TrackDir_OGG%
        IF @various@==1 SET VA_tag=-c "album artist=@VA@"
        ECHO ON
        @tools@\oggenc2.exe @Opt_OggEnc2@ %VA_tag% -c artist="@artist@" -c album="@album@" -c tracknumber="@track@/@numtracks@" -c title="@title@" -c date="@year@" -c genre="@genre@" -c comment="@comment@" -c encoded-by="%USERNAME%" -c encoding="OggEnc @Ver_OggEnc2@ @Opt_OggEnc2@" "@source@" -o "%TrackName%.ogg"
        @ECHO OFF
        IF %have_cover%==1 IF NOT EXIST folder.jpg COPY "@cover@" folder.jpg
    POPD
:end_oggenc_tracks


REM ** Delete the source .wav
DEL "@source@"


REM ---- Post-processing ----


rem ** Scan and compute ReplayGain and add cover picture for supported formats.
rem ** NB: The following will only work if at least the last track is selected,
rem ** and it is a regular audio track.

IF NOT @track@==@numtracks@ GOTO end_post_process

    SET add_rg=@ReplayGain@
    SET aac_enc=@NeroAac@
    IF @iTunesAac@==1 SET aac_enc=1

    IF NOT @ReplayGain@==1 GOTO end_RG
        SET RG_MetaFlac=--add-replay-gain
        SET RG_MetaMP3=--replay-gain
    :end_RG

    IF NOT @ApplyAlbumGain@==1 GOTO end_apply_AG
        SET RG_MetaMP3=--apply-gain album@AdjustAlbumGain_dB@
        SET RG_AacGain=/a /o /c /d @AdjustAlbumGain_dB@
        SET add_rg=1
    :end_apply_AG


    REM ** Audio Formats:

    IF @Flac@==1 (
        PUSHD %TrackDir_Flac%
            IF %add_rg%==1 @tools@\Glob.exe -v -c @tools@\metaflac.exe %RG_MetaFlac% *.flac
            REM COPY /Y "@eaclog@" "EAClog.txt"
        POPD
    )

    IF @Wavpack@==1 (
        PUSHD %TrackDir_Wavpack%
            IF %add_rg%==1 @tools@\wvgain.exe -a *.wv
            REM COPY /Y "@eaclog@" "EAClog.txt"
        POPD
    )

    IF @LameMP3@==1 (
        PUSHD %TrackDir_MP3%
            IF %add_rg%==1 @tools@\metamp3.exe %RG_MetaMP3% *.mp3
            COPY /Y "@eaclog@" "EAClog.txt"
            @tools@\SED -f sedlist.txt <"@albumfile@.[mg].cue" >"$cdartist$ - $album$.cue"
            DEL sedlist.txt
        POPD
    )

    IF %aac_enc%==1 (
        PUSHD %TrackDir_AAC%
            IF %add_rg%==1 @tools@\aacgain.exe %RG_AacGain% *.m4a > "gainlog.txt"
            REM COPY /Y "@eaclog@" "EAClog.txt"
        POPD
    )

    IF @OggEnc2@==1 (
        PUSHD %TrackDir_OGG%
            IF %add_rg%==1 @tools@\vorbisgain.exe -a *.ogg
            REM COPY /Y "@eaclog@" "EAClog.txt"
        POPD
    )


    REM ** Cleanup

    DEL "@eaclog@"
    DEL "@albumfile@.[*].cue"
    DEL "@cover@"

:end_post_process


REM ================ End Main Script ===================


IF @Debug@==1 (
    PAUSE
    EXIT
)

REM ** Delete this .bat file:
DEL %0
Quote from: lipidicman on
My other issue was copying the accuraterip details to the clipboard and having these be inserted into the logfile.
I came up with this suite including winclip:
http://www.dmst.aueb.gr/dds/sw/outwit/

My idea is to clear the clipboard (so you dont accidentally paste the details from the previous rip! paranoia I know), ask the user to grab the accrip log and then output it to a file (winclip -p file.txt) before appending this file to the EAClog.  There is even scope for checking that the clipboard contains accrip data I guess and looping until it does (might be problems here if the window has been closed, easy to do!)
Cool, I have no idea what you are talking about, but I'll try to take a look.

NB: To append file.txt to the logfile you could use:

Code: [Select]
TYPE file.txt >> "@eaclog@"
... or if you wanted a few carriage returns, etc.:

Code: [Select]
ECHO.>>"@eaclog@"
ECHO.>>"@eaclog@"
ECHO Accuraterip data:>>"@eaclog@"
ECHO.>>"@eaclog@"
TYPE file.txt >> "@eaclog@"
Quote from: lipidicman on
When I try to explain the problems with the cuesheet and the fine details of the naming conventions her eyes glaze over. Still at least there have been no arguments.
I'm on a horse.

REACT 2 Released

Reply #291 –
Quote from: Synthetic Soul on
Tested, and works just great.  Using %TrackName% means it will work for VA albums also (tested).


Great news.  I thought it would, and I had realised my method was going to trip up here

with the TYPE hint I will have a go at the clipboard solution tomorrow.  I am just unsure if I can test the contents of the clipboard to make the solution more robust

REACT 2 Released

Reply #292 –
Quote from: lipidicman on
I am just unsure if I can test the contents of the clipboard to make the solution more robust
I have no idea what text you will have so I can't really make any suggestions as yet as to how to validate.  I'll gladly stick my nose in though if you paste an example.

@All:

NB: In my test I used the MP3 section for ease.  I'm sure most people interested in this process would be using lossless, but I feel I should point out that if you do use MP3 you should really use:

Code: [Select]
ECHO s/FILE "@basename@\.wav" WAVE/FILE "%TrackName%\.mp3" MP3/>>sedlist.txt

Valid values for the file type are "WAVE", "MP3" and "AIFF", so if you use FLAC, Wavpack, Monkey's Audio, etc. it's fine/recommended to just leave "WAVE" as "WAVE", but for MP3 you need "MP3".
I'm on a horse.

REACT 2 Released

Reply #293 –
Quote from: Synthetic Soul on
Quote from: lipidicman on
I am just unsure if I can test the contents of the clipboard to make the solution more robust
I have no idea what text you will have so I can't really make any suggestions as yet as to how to validate.  I'll gladly stick my nose in though if you paste an example.

Can't at the moment, it is standard accurate rip output though.  So I was going to test if the contents of the clipboard contained the word 'accurate'.  The plan was to empty the clipboard in the script first (to avoid identifying data from an earlier rip) then check the user had done a manual paste with this check

Quote from: Synthetic Soul on
@All:

NB: In my test I used the MP3 section for ease.  I'm sure most people interested in this process would be using lossless, but I feel I should point out that if you do use MP3 you should really use:

Code: [Select]
ECHO s/FILE "@basename@\.wav" WAVE/FILE "%TrackName%\.mp3" MP3/>>sedlist.txt

Valid values for the file type are "WAVE", "MP3" and "AIFF", so if you use FLAC, Wavpack, Monkey's Audio, etc. it's fine/recommended to just leave "WAVE" as "WAVE", but for MP3 you need "MP3".


If this does not end up in a distribution it should be in a guide at least.  You wrote the knowledgebase article, right?

REACT 2 Released

Reply #294 –
I've no idea what the standard AccurateRip output is, as I always use images.

I wrote the initial wiki article/help, but tycho has since made numerous updates.

In response to Nik's crusade to document everything, and create a REACT GUI, I did suggest a wiki page (or pages) that had suggestions for improvements or amendments to the REACT configs.  Maybe I should start one and document this...
I'm on a horse.

REACT 2 Released

Reply #295 –
BTW I had a play with winclip.  I'm not sure how far you have got, but you may get some help from this:

Code: [Select]
REM Clear the clipboard
WINCLIP.EXE -c <NUL

REM Prompt to copy to the clipboard
:PauseForClipboard
ECHO.
ECHO Please copy the AccurateRip data to the clipboard and press any key
REM Wait
PAUSE >NUL

REM Copy the clipboard contents to winclip.txt
WINCLIP.EXE -p >winclip.txt

REM Check file for the word 'Accurate'
FINDSTR /I "ACCURATE" winclip.txt
IF ERRORLEVEL 1 (
  ECHO.
  ECHO Cannot find the word 'Accurate'.  Please try again.
  GOTO PauseForClipboard
)

REM Append the AccurateRip data to the log
ECHO.>>"@eaclog@"
ECHO.>>"@eaclog@"
ECHO AccurateRip Data:>>"@eaclog@"
ECHO.>>"@eaclog@"
TYPE winclip.txt >>"@eaclog@"
DEL winclip.txt
I'm on a horse.

REACT 2 Released

Reply #296 –
This is what I did (don't laugh, I've never written batch files before so mine only gave the user two chances.  I'm off to learn from your code now!) edit: result in second code window, basically the same as yours with a different search string (cant remember if you get 'Accurate' when it fails, and cant find a failing disc right now!)  Only thing it might need is a way to get out of the loop if you have closed the AccRip window.  Thanks

Code: [Select]
        REM ** winclip test first clear the clipboard
    echo notgrabbed| @tools@\winclip -c
    REM ** prompt
    echo.
    echo Please copy the accurate rip data
    pause
    @tools@\winclip -p clipboard.txt    
    REM ** TEST CONTENTS
    findstr "notgrabbed" clipboard.txt >NUL
    if errorlevel 1 GOTO end_NOTGRABBED
        echo.
        echo You need to copy the accuraterip data
        pause
        @tools@\winclip -p clipboard.txt
    :end_NOTGRABBED
    
    REM modify the EAClog
    ECHO.>>"@eaclog@"
    ECHO.>>"@eaclog@"
    ECHO Accuraterip data:>>"@eaclog@"
    ECHO.>>"@eaclog@"
    TYPE clipboard.txt >> "@eaclog@"
    DEL clipboard.txt


Code: [Select]
REM Get AccurateRip Data
    REM first clear the clipboard
    @tools@\WINCLIP.EXE -c <NUL
    REM Prompt to copy to clipboard
    :PauseForClipboard
    ECHO.
    ECHO Please copy the accurate rip data and press a key
    PAUSE >NUL
    
    REM Copy the clipboard contents to winclip.txt
    @tools@\WINCLIP.EXE -p clipboard.txt    
    
    REM Check file for the phrase 'Ripping Status'
    FINDSTR /I "RIPPING STATUS" clipboard.txt
    IF ERRORLEVEL 1 (
          ECHO.
          ECHO Cannot find the phrase 'Ripping Status'.  Please try again.
          GOTO PauseForClipboard
    )
    
    REM modify the EAClog
    ECHO.>>"@eaclog@"
    ECHO.>>"@eaclog@"
    ECHO Accuraterip data:>>"@eaclog@"
    ECHO.>>"@eaclog@"
    TYPE clipboard.txt >> "@eaclog@"
    DEL clipboard.txt

REACT 2 Released

Reply #297 –
Quote from: lipidicman on
My other issue was copying the accuraterip details to the clipboard and having these be inserted into the logfile.
I came up with this suite including winclip:
http://www.dmst.aueb.gr/dds/sw/outwit/

My idea is to clear the clipboard (so you dont accidentally paste the details from the previous rip! paranoia I know), ask the user to grab the accrip log and then output it to a file (winclip -p file.txt) before appending this file to the EAClog.  There is even scope for checking that the clipboard contains accrip data I guess and looping until it does (might be problems here if the window has been closed, easy to do!)


Alegedly, AutoFLAC already does that (inserts AccurateRip results into log files), and it's based on the same scripting language, so maybe that part of the code can be borrowed from there.

REACT 2 Released

Reply #298 –
Quote from: Nik on
Alegedly, AutoFLAC already does that (inserts AccurateRip results into log files), and it's based on the same scripting language, so maybe that part of the code can be borrowed from there.
That would be interesting to see.  I know nothing of AutoFLAC.

Quote from: lipidicman on
Only thing it might need is a way to get out of the loop if you have closed the AccRip window.
Code: [Select]
REM Get AccurateRip Data
REM Clear the clipboard
@tools@\WINCLIP.EXE -c <NUL
:PauseForClipboard
SET k=
ECHO.
SET /P k=Copy the Accurate Rip data and press return, or enter 'X' to ignore: 
IF /I [%k%] EQU [X] GOTO PostAccurateRip

REM Copy the clipboard contents to clipboard.txt
@tools@\WINCLIP.EXE -p clipboard.txt

REM Check file for the phrase 'Ripping Status'
FINDSTR /I "RIPPING STATUS" clipboard.txt
IF ERRORLEVEL 1 (
    ECHO.
    ECHO Cannot find the phrase 'Ripping Status'.  Please try again.
    GOTO PauseForClipboard
)

REM Modify the EAC log
ECHO.>>"@eaclog@"
ECHO.>>"@eaclog@"
ECHO Accuraterip data:>>"@eaclog@"
ECHO.>>"@eaclog@"
TYPE clipboard.txt >> "@eaclog@"
DEL clipboard.txt

:PostAccurateRip
I'm on a horse.

REACT 2 Released

Reply #299 –
Synth, cheers.  Of course it was simple to add that it is just that  I find batchfile syntax perverse after much simpler languages like python and VB.

I've done some tweaking to make it look nicer.  One problem is that it clears the clipboard too late if you copied the data whilst an earlier track was encoding.  This is a detail really and I could tell my GF to wait for the prompt, but encoding should be a background task.  I am going to add a test for FIRSTTRACK, like there is for postprocessing.  Clear the clipboard then and if the Accrip data is not already done the code will not need to prompt (rearranging the loop really)

Nik, didn't you ask before about correcting the cuesheets?  Was all this helpful to you?  Anyway I'm off to investigate AUTOFLAC, cheers

edit: AUTOFLACs ToDo list:
Quote
add support for rip/write verification
add support for WavPack and Monkey's Audio
add support for pars - comment 45
add support for AccurateRip - comment 90