Updated my track info strings. thought the updates were worth a new post. well, here it is:
// Basik Track Info 1.01
// Written by korsairr
// April 18th 2005
// Basik Track Info works best with:
// Arial bold 8pt
// Vertical padding 3
// Horizontal padding 5
// Line spacing -1
// Background color Black
// Adjust the following to suit your tastes
$puts(info_box_width,34)
$puts(default_color,d4d4d4)
$puts(rating_color_1,5357EF)
$puts(rating_color_2,042573)
$puts(rating_symbol,♫)
$puts(is_playing_color,5357EF)
$puts(tag_missing_color,575757)
$puts(heading_color_l,ffb00d)
$puts(heading_color_r,000000)
$puts(is_playing_color,5357EF)
////////////////////////////////
/////// Song Info Code
////////////////////////////////
$transition(----- Song Info $repeat(-,$sub($get(info_box_width),5)),$get(heading_color_l),$get(heading_color_r))
$char(10)$get(default_color)
$if(%_filename_ext%,
$if(%title%,$if(%_isplaying%,
$get(is_playing_color)$iflonger(%title%,$get(info_box_width),$cut(%title%,$sub($get(info_box_width),2))...,%title%),
$iflonger(%title%,$get(info_box_width),$trim($cut(%title%,$sub($get(info_box_width),3)))...,%title%)),
$if(%_isplaying%,
$get(is_playing_color)$iflonger(%_filename_ext%,$get(info_box_width),$cut(%_filename_ext%,$sub($get(info_box_width),3))...,%_filename_ext%),
$iflonger(%_filename_ext%,$get(info_box_width),$trim($cut(%_filename_ext%,$sub($get(info_box_width),2)))...,%_filename_ext%))),
$get(tag_missing_color) no track selected)
$char(10)$get(default_color)
$if(%_filename_ext%,
$if(%artist%,
$iflonger(%artist%,$get(info_box_width),$cut(%artist%,$sub($get(info_box_width),2))...,%artist%),
$get(tag_missing_color)no artist info)
)
$char(10)$get(default_color)
$if(%_filename_ext%,
$if(%album%,
$iflonger(%album%,$get(info_box_width),$cut(%album%,$sub($get(info_box_width),2))...,%album%),
$get(tag_missing_color)no album info)
)
$char(10)$get(default_color)
$if(%_filename_ext%,
$if($or(%publisher%.%label%,%date%),$if($or(%publisher%,%label%),© ,)%date%$if($or(%publisher%,%label%),'. ',)[%publisher% ][%label%],
$get(tag_missing_color)no date or copyright info)
)
$char(10)$get(default_color)
$if(%_filename_ext%,
$if(%rating%,$get(rating_color_1)
$repeat($get(rating_symbol) ,%rating%)
$get(rating_color_2)$repeat($get(rating_symbol) ,$sub(5,%rating%)) ,$get(tag_missing_color)$repeat($get(rating_symbol) ,5) )
$get(default_color)$if(%genre%,%genre%,$get(tag_missing_color)no genre)
)
$char(10)$char(10)
////////////////////////////////
/////// Statistics Code
////////////////////////////////
$transition(----- Statistics $repeat(-,$sub($get(info_box_width),5)),$get(heading_color_l),$get(heading_color_r))
$char(10)$get(default_color)
$if(%_filename_ext%,
$if(%last_played%,$puts(lastplayed,%last_played%),
$if(%play_date%,$puts(lastplayed,%play_date%),))
$if($get(lastplayed),
$puts(month,$left($get(lastplayed),2))
$puts(day,$substr($get(lastplayed),4,5))
$if($strcmp($left($get(day),1),0),$puts(day,$right($get(day),1)))
$puts(year,$right($get(lastplayed),2))
$puts(month_name,$select($get(month),
Jan,Feb,March,April,May,June,July,Aug,Sept,Oct,Nov,Dec))
$if($or($strcmp($get(day),11),$strcmp($get(day),12),$strcmp($get(day),13)),$puts(xx,th),
$if($strcmp($right($get(day),1),1),$puts(xx,st),
$if($strcmp($right($get(day),1),2),$puts(xx,nd),
$if($strcmp($right($get(day),1),3),$puts(xx,rd),
$puts(xx,th))))))
$puts(time_of_year,$get(month_name) $get(day)$get(xx) 20$get(year))
$if(%play_counter%,Played $if($strcmp(%play_counter%,1),
once$if($get(lastplayed),',')$if($get(lastplayed), on $get(time_of_year)),
%play_counter% times$if($get(lastplayed),
$char(10)$get(default_color) Last played on $get(time_of_year))),This song has not played before)
$ifgreater(%play_counter%,1,,$char(10))
,$char(10))
$char(10)$char(10)
////////////////////////////////
/////// Tech Info Code
////////////////////////////////
$transition(----- Tech Info $repeat(-,$sub($get(info_box_width),5)),$get(heading_color_l),$get(heading_color_r))
$char(10)$get(default_color)
$if(%_filename_ext%,
%__codec%
$if(%__bitrate_dynamic%,%__bitrate_dynamic%,%__bitrate%)kbps
$if($or($stricmp(%__extrainfo%,vbr),$stricmp($codec(),musepack),$stricmp($codec(),vorbis)),VBR,CBR)
$caps($if($stricmp($codec(),MP3),%__mp3_stereo_mode%,$channels()))
$char(10)$get(default_color)
$if($or(%__replaygain_track_gain%,%__replaygain_album_gain%),
['['Tg']' %__replaygain_track_gain%][ '['Ag']' %__replaygain_album_gain%],
$get(tag_missing_color)there is no gain)
$char(10)$get(default_color)
[%_time_elapsed%/][%_length%][ -%_time_remaining% ]
$if(%_isplaying%,
$muldiv(%_time_elapsed_seconds%,100,%_time_total_seconds%)'%',)
$div(%_filesize%,1048576).
$left($num($muldiv($mod(%_filesize%,1048576),1000,1048576),3),2)' MB',
)
Click for full Foobar2000