Skip to main content

Topic: REACT 2 Released (Read 983586 times) previous topic - next topic

0 Members and 1 Guest are viewing this topic.
  • ESP85
  • [*]
REACT 2 Released
Reply #125
I just discovered another possible bug today.

REACT2 has a problem with slashes "/" in the title.  I have some CDs that have slashes in the title and when I press F10 to make an image the screen just flashes and the Save Waveform window doesn't pop up at all unless I take the slashes out of the title.

  • Synthetic Soul
  • [*][*][*][*][*]
  • Global Moderator
REACT 2 Released
Reply #126
Good band by the way. 

Hmm... if I do:

MOVE /Y "C:\Documents and Settings\Neil\Desktop\12345678901234567890123456789012345678901234567890123456789012345678901234567890123456789012345
67890.flac" "C:\Documents and Settings\Neil\Desktop\12345678901234567890123456789012345678901234567890123456789012345678901234567890123456789012345
67890"

... on my XP laptop it works fine.

I've had a look at this problem and it doesn't look like there's an easy way in NT DOS to get the short file name.  I did find this page, but I wouldn't call the resolve easy.

One option may be for REACT to use short file names by default (AutoIt has built-in functions to get the SFN for a path), or perhaps even to provide some more placeholders, like ~cuesheet~ or ~eaclog~, which return SFN filenames.
I'm on a horse.

  • Synthetic Soul
  • [*][*][*][*][*]
  • Global Moderator
REACT 2 Released
Reply #127
REACT2 has a problem with slashes "/" in the title.  I have some CDs that have slashes in the title and when I press F10 to make an image the screen just flashes and the Save Waveform window doesn't pop up at all unless I take the slashes out of the title.
Known issue with EAC.
I'm on a horse.

  • ESP85
  • [*]
REACT 2 Released
Reply #128
Good band by the way. 

Hmm... if I do:

MOVE /Y "C:\Documents and Settings\Neil\Desktop\12345678901234567890123456789012345678901234567890123456789012345678901234567890123456789012345
67890.flac" "C:\Documents and Settings\Neil\Desktop\12345678901234567890123456789012345678901234567890123456789012345678901234567890123456789012345
67890"

... on my XP laptop it works fine.

I've had a look at this problem and it doesn't look like there's an easy way in NT DOS to get the short file name.  I did find this page, but I wouldn't call the resolve easy.

One option may be for REACT to use short file names by default (AutoIt has built-in functions to get the SFN for a path), or perhaps even to provide some more placeholders, like ~cuesheet~ or ~eaclog~, which return SFN filenames.

I have Windows 2000 Pro.

I've tried to find where the maximum filename length would be set but with no luck.  Maybe my settings are messed up somewhere.

REACT2 has a problem with slashes "/" in the title.  I have some CDs that have slashes in the title and when I press F10 to make an image the screen just flashes and the Save Waveform window doesn't pop up at all unless I take the slashes out of the title.
Known issue with EAC.

The slashes in the title work just fine when I'm not running REACT2 so I think it's a REACT2 issue.

  • Fameless
  • [*]
REACT 2 Released
Reply #129
I just started to mess around this this, and I have a few issues/questions. 

I want to use React to make .mp3's for my portable player, and .flac files for listening at home. Here is how my REACT.ini file is set up:
[Settings]
Version=2.0
ImageExt=wav
ImageNaming=$artist$ - [$year$] $album$
ImageHotKey={F10}
TracksHotKey={F4}
TracksHotVal=+{F5}
VA=Various Artists
CreateAllCuesheets=0
RunCoverDownloader=1
CoverDownloader=C:\Program Files\REACT2\coverdownloader\albumart.exe
EAC=C:\Program Files\Exact Audio Copy\EAC.exe
Tools=C:\Program Files\REACT2\tools
MinimizeCompressionWindow=1
ProcessPriority=1
Sla_Bks_Col_Qst_Bar_Quo_Ast_Lt_Gt=-|-|-||!|'|#|[|]

[UserTrackFormats]
Flac=1
Wavpack=0
LameMP3=1
NeroAac=0
iTunesAac=0
OggEnc2=0

[UserOutputNames]
OutRoot=@mymusic@\EAC
ImageDir_Flac=@OutRoot@\FLAC-images\$cdartist$
ImageDir_Wavpack=@OutRoot@\WV-images\$cdartist$
ImageDir_MP3=@OutRoot@\MP3-images\$cdartist$
TrackDir_Flac=@OutRoot@\FLAC\$cdartist$\[$year$] $album$
TrackDir_Wavpack=@OutRoot@\WV\$cdartist$\[$year$] $album$
TrackDir_MP3=@OutRoot@\MP3\$cdartist$\[$year$] $album$
TrackDir_AAC=@OutRoot@\AAC\$cdartist$\[$year$] $album$
TrackDir_OGG=@OutRoot@\OGG\$cdartist$\[$year$] $album$
TrackName_SA=$track$ - $title$
TrackName_VA=$track$ - $title$ [$artist$]
TrackName_SA_acdir=$n - $~t
TrackName_VA_acdir=$n - $~t [$~a]

[UserSettings]
Debug=1
Comment=Created with EAC/REACT2, @curdate@
EmbedCover=1
ReplayGain=1
ApplyAlbumGain=1
AdjustAlbumGain_dB=+3.0
AddCuesheetAG=1
UseWaveGainAG=1
Opt_Flac=-5 -f
Opt_Wavpack=-hmy
Opt_LameMP3=-V2 --vbr-new  --nohist
Opt_NeroAac=-lc -q 0.21
Opt_iTunesAac=-d -s 2000
Opt_OggEnc2=-q 3.0
Ver_Flac=1.1.3
Ver_Wavpack=4.40
Ver_LameMP3=3.97
Ver_NeroAac=1.0.0.2
Ver_OggEnc2=2.83 Lancer aoTuV b5

After React runs, the wave files are not deleted even though I checked Delete WAV after compression in EAC. How do I configure React to delete .wav's after it runs? Can I use the single .cue file created to decompress the .flac tracks to restore to a cd-r for back-up? I've never used .flac before and I'm unsure the best course of action to take for track restoration with React. I had installed flac frontend to decompress the flac tracks, but React would no longer create .flac tracks for new cd's. I apologize if this is hard to follow, but I'm new to flac and React. I'm good with LAME, I'll LAME it up all day long.

That was LAME...

  • Martin H
  • [*][*][*][*][*]
REACT 2 Released
Reply #130
For getting the WAV image and cuesheet deleted afterwards, then you need to set 'Debug' to '0' instead of '1'. If you want a cuesheet for your ripped tracks, then you must set the 'CreateAllCuesheets' to '1' and then all the 4 different cuesheet formats are made, but they are only copied into the directories of lossless formats, though, so if you want a cuesheet into a lossy formats directory, then just copy the changed line a little under here, and place it into your lossy format's track section in your CFG file.

Press ALT+F3 and there you need to scroll down to the '---tracks---' section and then under the FLAC tracks section, then find this line :
Code: [Select]
IF EXIST "@albumfile@.[*].cue" COPY /Y "@albumfile@.[*].cue" .

And then change it to :
Code: [Select]
IF EXIST "@albumfile@.[mg].cue" COPY /Y "@albumfile@.[mg].cue" "@basename@.cue"


CU, Martin.
  • Last Edit: 24 January, 2007, 04:39:43 AM by Martin H

  • ESP85
  • [*]
REACT 2 Released
Reply #131

Good band by the way. 

Hmm... if I do:

MOVE /Y "C:\Documents and Settings\Neil\Desktop\12345678901234567890123456789012345678901234567890123456789012345678901234567890123456789012345
67890.flac" "C:\Documents and Settings\Neil\Desktop\12345678901234567890123456789012345678901234567890123456789012345678901234567890123456789012345
67890"

... on my XP laptop it works fine.

I've had a look at this problem and it doesn't look like there's an easy way in NT DOS to get the short file name.  I did find this page, but I wouldn't call the resolve easy.

One option may be for REACT to use short file names by default (AutoIt has built-in functions to get the SFN for a path), or perhaps even to provide some more placeholders, like ~cuesheet~ or ~eaclog~, which return SFN filenames.

I have Windows 2000 Pro.

I've tried to find where the maximum filename length would be set but with no luck.  Maybe my settings are messed up somewhere.

REACT2 has a problem with slashes "/" in the title.  I have some CDs that have slashes in the title and when I press F10 to make an image the screen just flashes and the Save Waveform window doesn't pop up at all unless I take the slashes out of the title.
Known issue with EAC.

The slashes in the title work just fine when I'm not running REACT2 so I think it's a REACT2 issue.


Does anybody have any idea how to fix either of these problems?
  • Last Edit: 05 January, 2007, 08:05:27 AM by ESP85

  • Fameless
  • [*]
REACT 2 Released
Reply #132
Thanks Martin H, that's what I was looking for. One more question: which .cue sheet should I use to decode the .flac tracks to burn to a cd-r for back-up? If I read the EAC .cue sheet guide correctly, I want to use the noncompliant sheet, right? Out of the four sheets that React creates, which one is it?

  • Martin H
  • [*][*][*][*][*]
REACT 2 Released
Reply #133
You are very welcome Fameless

The cuesheet you will need is the "multiple files with gaps" i.e. "@albumfile@.[mg].cue" and that should also be copied to your FLAC files directory according to the changes i posted to you previously.

CU, Martin.

  • Fameless
  • [*]
REACT 2 Released
Reply #134
Awesome, thanks for the help.

REACT 2 Released
Reply #135
I've tried to figure this out on my own, but with no success. I'm trying to create a WavPack image and mp3 tracks. The image comes out fine and in the proper folder, but when it comes to the track creation, it looks like React is running it correctly, but no files are created and all I get is an empty folder. Any ideas?

Edit: Never mind, of course I figured it out five minutes after I posted.
  • Last Edit: 07 January, 2007, 04:30:30 PM by The Chaos Path

  • lwbecker2
  • [*]
REACT 2 Released
Reply #136
I was looking at using EAC with iTunesEncode and Nero's AAC encoder, along with REACT. I see that support is built in and was looking at the code in the config section and have questions about the following two code segments.  The line before :end_itunes_aac_tracks says "GOTO end_nero_aac_tracks" (see code below)... is this a typo? not sure why the itunes acc section would goto the end of the nero aac section.

In the second code snippet, the one for Nero's encoder, it calls neroAacEnc.exe but doesn't call the nero tagger (neroAacTag.exe), but instead uses some other tagging program.. why is this?  Thanks in advance for any information.

Code: [Select]
IF NOT @iTunesAac@==1 GOTO end_itunes_aac_tracks
    IF NOT EXIST %TrackDir_AAC% MKDIR %TrackDir_AAC%
    PUSHD %TrackDir_AAC%
        IF %embed_cover%==1 SET Cover_tag=-r "@cover@"
        ECHO ON
        @tools@\iTunesEncode.exe @Opt_iTunesAac@ -e "AAC Encoder" %Cover_tag% -x @various@ -a "@artist@" -l "@album@" -n "@track@" -m "@numtracks@" -t "@title@" -y "@year@" -g "@genre@" -c "@comment@" -i "@source@" -o "%TrackName%.m4a"
        @ECHO OFF
        IF %have_cover%==1 IF NOT EXIST folder.jpg COPY "@cover@" folder.jpg
    POPD
    GOTO end_nero_aac_tracks
:end_itunes_aac_tracks

Code: [Select]
IF NOT @NeroAac@==1 GOTO end_nero_aac_tracks
    IF NOT EXIST %TrackDir_AAC% MKDIR %TrackDir_AAC%
    PUSHD %TrackDir_AAC%
        IF @various@==1 SET VA_tag=--albumArtist "@VA@" --compilation true
        IF %embed_cover%==1 SET Cover_tag=--artwork "@cover@"
        ECHO ON
        @tools@\neroAacEnc.exe @Opt_NeroAac@ -if "@source@" -of "%TrackName%.m4a"
        @tools@\AtomicParsley.exe "%TrackName%.m4a" -o REACT_tmp.m4a %Cover_tag% %VA_tag% --artist "@artist@" --album "@album@" --tracknum "@track@/@numtracks@" --title "@title@" --year "@year@" --genre "@genre@" --comment "@comment@" --encodingTool "neroAacEnc @Ver_NeroAac@ @Opt_NeroAac@"
        @ECHO OFF
        MOVE /Y REACT_tmp.m4a "%TrackName%.m4a"
        IF %have_cover%==1 IF NOT EXIST folder.jpg COPY "@cover@" folder.jpg
    POPD
:end_nero_aac_tracks

REACT 2 Released
Reply #137
I've been looking in the WIKI and configs for a while, but can't seem to figure out:

Is there a way to generate M3U files for track ripping?  (like EAC does normally when it rips tracks)

Thanks,
GS

  • Synthetic Soul
  • [*][*][*][*][*]
  • Global Moderator
REACT 2 Released
Reply #138
Is there a way to generate M3U files for track ripping?  (like EAC does normally when it rips tracks)
Does EAC do this normally?  If it does then it probably still can.

If not, I have created a batch file to create an M3U.  It accepts a folder to process and a filename as parameters, e.g.:

@tools@\CREATE-M3U.BAT "@TrackDir_MP3@" "$cdarist$ - $album$"

Here's the code.  If you're interested, copy it into a text file, save it in the REACT "tools" directory as "create-m3u.bat", and then use the line above after your track files have been created.

Code: [Select]
@ECHO OFF
CLS

REM CREATE-M3U.BAT Written by Neil Popham, 2005 (neilpopham@bigfoot.com)

SET batchname=CREATE-M3U.BAT
SET version=1.1.0
TITLE=%batchname%, Version %version%

REM Set the name of the playlist to create in each folder
IF [%2] EQU [] (SET playlist=playlist.m3u) ELSE (SET playlist="%~2.m3u")
REM Create list of valid file extensions
SET validExtn=.mp3.mp2.mp1.mpc.mp+.mpp.ogg.aac.mac.ape.flac.fla.wv.shn.ofr.ofs.ogg.m4a.mp4

REM Add another delimiter to the end so I can search for .<ext>.
SET validExtn=%validExtn%.

REM Check a folder has been passed
IF NOT EXIST %1 GOTO NoParams
IF %~z1 GTR 0 GOTO NoParams

REM Remove all existing "playlist.m3u" files otherwise files will be appended
FOR /R %1 %%G IN (%playlist%) DO IF EXIST %%G DEL "%%G"

REM Iterate through every file and pass the path to :WriteToPlayList
FOR /R %1 %%G IN (*.*) DO CALL :WriteToPlayList "%%G" %playlist%

GOTO:EOF

REM ======================================================================
REM WriteToPlayList : Adds the file to the playlist, if the extension fits
REM : %1 The file to process
REM ======================================================================
:WriteToPlayList
REM Check that the file extension is valid
SET extn=%~x1
IF [%extn%] EQU [] GOTO:EOF
SET tmpExtn=%validExtn%
CALL SET result=%%tmpExtn:%extn%.=%%
REM If no match found in list of extensions exit function
IF [%result%] EQU [%validExtn%] GOTO:EOF
REM Escape ampersand and caret
SET tmpString="%~nx1"
SET tmpString=%tmpString:^=^^%
SET tmpString=%tmpString:&=^^^&%
REM Remove quotes
SET tmpString=%tmpString:"=%
REM Write filename to playlist
ECHO %tmpString%>>"%~dp1\%~2"
GOTO:EOF

REM =======================================
REM NoParams : a folder has not been passed
REM =======================================
:NoParams
ECHO To run this script, please pass a folder as a parameter.
ECHO.
ECHO Press any key to exit
PAUSE >NUL

REM ===============
REM Version History
REM ===============
REM 1.0.0 ---------- Initial Version
REM 1.1.0 2006-11-01 Fixed bug when hypens used.
NB: This was originally posted in the REACT 1 thread here and here.
  • Last Edit: 08 January, 2007, 06:38:59 AM by Synthetic Soul
I'm on a horse.

  • grombulk
  • [*]
  • Members (Donating)
REACT 2 Released
Reply #139
Is there a way to generate M3U files for track ripping?  (like EAC does normally when it rips tracks)


I use tag as in:
@tools@\tag.exe --playlist --onlyfiles --sort track --plname "00 - @basename@.m3u" "%dest%\*.mp3"
in
REACT-image.cfg

I us the Synthetic Soul's version

  • cpalcott
  • [*]
REACT 2 Released
Reply #140
I am a curremt 1.0 user, but am having some trouble getting 2.0 to work. Here's what I am looking to do:

• Rip to Flac 1.1.3 tracks and Lame 3.97 tracks
• Run Wavegain and store Album-Gain, Album-Peak, Track-Gain and Track-Peak findings in Flac tags and mp3 tags and apply Track-Gain to the mp3s.
• Get album art, save it as folder.jpg in the Flac album folder, embed art in Flac file and mp3 file.

Any sample ini or cfg files out there?

See below for current config:

Code: [Select]
[Settings]
Version=2.0
ImageExt=wav
ImageNaming=$artist$ - [$year$] $album$
ImageHotKey={F10}
TracksHotKey={F4}
TracksHotVal=+{F6}
VA=Various Artists
CreateAllCuesheets=0
RunCoverDownloader=1
CoverDownloader=C:\Program Files\REACT2\coverdownloader\albumart.exe
EAC=C:\Program Files\Exact Audio Copy\EAC.exe
Tools=C:\Program Files\REACT2\tools
MinimizeCompressionWindow=1
ProcessPriority=1
Sla_Bks_Col_Qst_Bar_Quo_Ast_Lt_Gt=-|-|-||!|'|#|[|]

[UserTrackFormats]
Flac=1
Wavpack=0
LameMP3=1
NeroAac=0
iTunesAac=0
OggEnc2=0

[UserOutputNames]
OutRoot=@mymusic@\EAC
ImageDir_Flac=C:\Documents and Settings\calcott\My Documents\My Music\Archive\$cdartist$
ImageDir_Wavpack=@OutRoot@\WV-images\$cdartist$
ImageDir_MP3=C:\Documents and Settings\calcott\My Documents\My Music\Portable\$cdartist$
TrackDir_Flac=C:\Documents and Settings\calcott\My Documents\My Music\Archive\$cdartist$\[$year$] $album$
TrackDir_Wavpack=@OutRoot@\WV\$cdartist$\[$year$] $album$
TrackDir_MP3=C:\Documents and Settings\calcott\My Documents\My Music\Portable\$cdartist$\[$year$] $album$
TrackDir_AAC=@OutRoot@\AAC\$cdartist$\[$year$] $album$
TrackDir_OGG=@OutRoot@\OGG\$cdartist$\[$year$] $album$
TrackName_SA=$track$ - $title$
TrackName_VA=$track$ - $title$ [$artist$]
TrackName_SA_acdir=$n - $~t
TrackName_VA_acdir=$n - $~t [$~a]

[UserSettings]
Debug=1
Comment=Created with EAC/REACT2, @curdate@
EmbedCover=1
ReplayGain=1
ApplyAlbumGain=1
AdjustAlbumGain_dB=+3.0
AddCuesheetAG=0
UseWaveGainAG=1
Opt_Flac=-5 -f
Opt_Wavpack=-hmy
Opt_LameMP3=-V3 --vbr-new
Opt_NeroAac=-lc -q 0.21
Opt_iTunesAac=-d -s 2000
Opt_OggEnc2=-q 3.0
Ver_Flac=1.1.3
Ver_Wavpack=4.40
Ver_LameMP3=3.97
Ver_NeroAac=1.0.0.2
Ver_OggEnc2=2.83 Lancer aoTuV b5

@ECHO OFF
CHCP 1252
TITLE @track@/@numtracks@ - "@album@"

REM Copyright © Tycho, 2006
REM
REM ** Create compressed audio tracks from ripped .wav tracks.
REM **
REM ** You may consider using image mode (F10)
REM ** as it supports creating tracks via acdir.exe,
REM ** and post-processing will always work (see below).
REM **
REM ** Flac requires flac.exe/metaflac.exe (v1.1.3)
REM ** NeroAac requires NeroAacEnc.exe/NeroAacTag.exe/AacGain.exe.
REM ** OggEnc2 requires OggEnc2.exe/VorbisGain.exe.
REM **
REM ** I prefer applying album gain 92dB to get a reasonable
REM ** volume for my DAP. The RG tags are still relative
REM ** to 89dB SPL, i.e. album gain will be about -3.0dB.


REM ============== Begin Main Script ==================


IF @Debug@==1 ECHO ON

SET TrackDir_Flac="@TrackDir_Flac@"
SET TrackDir_Wavpack="@TrackDir_Wavpack@"
SET TrackDir_MP3="@TrackDir_MP3@"
SET TrackDir_AAC="@TrackDir_AAC@"
SET TrackDir_OGG="@TrackDir_OGG@"

IF @various@==0    SET TrackName=@TrackName_SA@
IF @various@==1    SET TrackName=@TrackName_VA@

SET add_rg=@ReplayGain@
SET have_cover=0
SET embed_cover=0

IF NOT @ReplayGain@==1 GOTO end_RG
   SET RG_Flac=--replay-gain
   SET RG_MetaFlac=--add-replay-gain
   SET RG_MetaMP3=--replay-gain
:end_RG

IF NOT @ApplyAlbumGain@==1 GOTO end_apply_AG
   SET ApplyAG_MetaMP3=--apply-gain album@AdjustAlbumGain_dB@
   SET ApplyAG_AacGain=/a /o /c /d @AdjustAlbumGain_dB@
   SET add_rg=1
:end_apply_AG

IF EXIST "@cover@" (
   SET have_cover=1
   SET embed_cover=@EmbedCover@
)

IF @various@==0 (
   SET ArtistField=artist
   SET MP3Artist=--artist "@artist@"
) else (
   SET ArtistField=album artist
   SET MP3Artist=--user-text "[album artist]@VA@" --frame "TPE2:@VA@"
)

SET run_wavegain=@UseWaveGainAG@
IF @AddCuesheetAG@==1 SET run_wavegain=1

IF %run_wavegain%==0 GOTO end_wavegain
   SET wg_tmp=wg_%RANDOM%
   @tools@\WaveGain.exe --album "@source@" --exec ECHO '%%ALBUM_GAIN%%'%%ALBUM_PEAK%%'%%ALBUM_NEW_PEAK%%'%%ALBUM_SCALE%%'> %wg_tmp%.txt
   FOR /F "usebackq tokens=1-6 delims='" %%a IN (%wg_tmp%.txt) DO (
       SET album_gain=%%b
       SET album_peak=%%c
       SET album_new_peak=%%d
       SET album_scale=%%e
   )
   ECHO REM REPLAYGAIN_ALBUM_GAIN %album_gain% dB> %wg_tmp%.cue
   ECHO REM REPLAYGAIN_ALBUM_PEAK %album_peak%>> %wg_tmp%.cue
   ECHO REM REPLAYGAIN_ALBUM_SCALE %album_scale%>> %wg_tmp%.cue
   DEL %wg_tmp%.txt
   TYPE "@cuesheet@" >> %wg_tmp%.cue
   MOVE /Y %wg_tmp%.cue "@cuesheet@"
:end_wavegain


REM ** Transfer RG values from Wavgain calculations, instead of recalculation.
IF @UseWaveGainAG@==1 IF %add_rg%==1 (
   SET RG_Flac=-T "replaygain_album_gain=%album_gain% dB" -T "replaygain_album_peak=%album_peak%"
   SET RG_MetaFlac=--set-tag="replaygain_album_gain=%album_gain% dB" --set-tag="replaygain_album_peak=%album_peak%"
   SET RG_Wavpack=-w "replaygain_album_gain=%album_gain% dB" -w "replaygain_album_peak=%album_peak%"
   SET RG_Wavpack_acdir=-w $qreplaygain_album_gain=%album_gain% dB$q -w $qreplaygain_album_peak=%album_peak%$q
   SET RG_MetaMP3=--user-text "[replaygain_album_gain]%album_gain% dB" --user-text "[replaygain_album_peak]%album_peak%"
   SET RG_OggEnc2_acdir=-c $qreplaygain_album_gain=%album_gain% dB$q -c $qreplaygain_album_peak=%album_peak%$q
)

REM ** Apply AlbumGain by using --scale <factor> computed from WaveGain. Only for MP3 and OGG.
IF @UseWaveGainAG@==1 IF @ApplyAlbumGain@==1 (
   SET ApplyAG_Lame=--scale %album_scale%
   SET ApplyAG_MetaMP3=--apply-gain @AdjustAlbumGain_dB@
   SET RG_MetaMP3=--user-text "[replaygain_album_gain]0.0 dB" --user-text "[replaygain_album_peak]%album_new_peak%"
   SET RG_OggEnc2_acdir=--scale %album_scale% -c $qreplaygain_album_gain=0.0 dB$q -c $qreplaygain_album_peak=%album_new_peak%$q
)


REM ---- Track ----


IF NOT @Flac@==1 GOTO end_flac_tracks
   IF NOT EXIST %TrackDir_Flac% MKDIR %TrackDir_Flac%
   PUSHD %TrackDir_Flac%
       IF @various@==1 SET VA_tag=-T "album artist=@VA@"
       IF %embed_cover%==1 SET Cover_tag=--picture="|image/jpeg|||@cover@"
       ECHO ON
       @tools@\flac.exe @Opt_Flac@ %Cover_tag% %VA_tag% -T artist="@artist@" -T album="@album@" -T tracknumber="@track@/@numtracks@" -T title="@title@" -T date="@year@" -T genre="@genre@" -T comment="@comment@" -T encoded-by="%USERNAME%" -T encoding="Flac @Ver_Flac@ @Opt_Flac@" "@source@" -o "%TrackName%.flac"
       @ECHO OFF
       IF %have_cover%==1 IF NOT EXIST folder.jpg COPY "@cover@" folder.jpg
   POPD
:end_flac_tracks


IF NOT @Wavpack@==1 GOTO end_wavpack_tracks
   IF NOT EXIST %TrackDir_Wavpack% MKDIR %TrackDir_Wavpack%
   PUSHD %TrackDir_Wavpack%
       IF @various@==1 SET VA_tag=-w "album artist=@VA@"
       ECHO ON
       @tools@\wavpack.exe @Opt_Wavpack@ %VA_tag% -w artist="@artist@" -w album="@album@" -w track="@track@/@numtracks@" -w title="@title@" -w year="@year@" -w genre="@genre@" -w comment="@comment@" -w encodedby="%USERNAME%" -w encodersettings="Wavpack @Ver_Wavpack@ @Opt_Wavpack@" "@source@" "%TrackName%.wv"
       @ECHO OFF
       IF %have_cover%==1 IF NOT EXIST folder.jpg COPY "@cover@" folder.jpg
       TITLE @track@/@numtracks@ - "@album@"
   POPD
:end_wavpack_tracks


IF NOT @LameMP3@==1 GOTO end_lame_tracks
   IF NOT EXIST %TrackDir_MP3% MKDIR %TrackDir_MP3%
   PUSHD %TrackDir_MP3%
       IF @various@==1 SET VA_tag=--user-text "[album artist]@VA@" --frame "TPE2:@VA@"
       IF %embed_cover%==1 SET Cover_tag=--pict "{3}@cover@"
       ECHO ON
       @tools@\lame.exe @Opt_LameMP3@ "@source@" "%TrackName%.mp3"
       @tools@\metamp3.exe %Cover_tag% %VA_tag% --artist "@artist@" --album "@album@" --track @track@/@numtracks@ --title "@title@" --year "@year@" --genre "@genre@" --comment "@comment@" --frame TENC:"%USERNAME%" --frame TSSE:"LAME @Ver_LameMP3@ @Opt_LameMP3@" "%TrackName%.mp3"
       @ECHO OFF
       IF %have_cover%==1 IF NOT EXIST folder.jpg COPY "@cover@" folder.jpg
   POPD
:end_lame_tracks


IF NOT @iTunesAac@==1 GOTO end_itunes_aac_tracks
   IF NOT EXIST %TrackDir_AAC% MKDIR %TrackDir_AAC%
   PUSHD %TrackDir_AAC%
       IF %embed_cover%==1 SET Cover_tag=-r "@cover@"
       ECHO ON
       @tools@\iTunesEncode.exe @Opt_iTunesAac@ -e "AAC Encoder" %Cover_tag% -x @various@ -a "@artist@" -l "@album@" -n "@track@" -m "@numtracks@" -t "@title@" -y "@year@" -g "@genre@" -c "@comment@" -i "@source@" -o "%TrackName%.m4a"
       @ECHO OFF
       IF %have_cover%==1 IF NOT EXIST folder.jpg COPY "@cover@" folder.jpg
   POPD
   GOTO end_nero_aac_tracks
:end_itunes_aac_tracks

IF NOT @NeroAac@==1 GOTO end_nero_aac_tracks
   IF NOT EXIST %TrackDir_AAC% MKDIR %TrackDir_AAC%
   PUSHD %TrackDir_AAC%
       IF @various@==1 SET VA_tag=--albumArtist "@VA@" --compilation true
       IF %embed_cover%==1 SET Cover_tag=--artwork "@cover@"
       ECHO ON
       @tools@\neroAacEnc.exe @Opt_NeroAac@ -if "@source@" -of "%TrackName%.m4a"
       @tools@\AtomicParsley.exe "%TrackName%.m4a" -o REACT_tmp.m4a %Cover_tag% %VA_tag% --artist "@artist@" --album "@album@" --tracknum "@track@/@numtracks@" --title "@title@" --year "@year@" --genre "@genre@" --comment "@comment@" --encodingTool "neroAacEnc @Ver_NeroAac@ @Opt_NeroAac@"
       @ECHO OFF
       MOVE /Y REACT_tmp.m4a "%TrackName%.m4a"
       IF %have_cover%==1 IF NOT EXIST folder.jpg COPY "@cover@" folder.jpg
   POPD
:end_nero_aac_tracks


IF NOT @OggEnc2@==1 GOTO end_oggenc_tracks
   IF NOT EXIST %TrackDir_OGG% MKDIR %TrackDir_OGG%
   PUSHD %TrackDir_OGG%
       IF @various@==1 SET VA_tag=-c "album artist=@VA@"
       ECHO ON
       @tools@\oggenc2.exe @Opt_OggEnc2@ %VA_tag% -c artist="@artist@" -c album="@album@" -c tracknumber="@track@/@numtracks@" -c title="@title@" -c date="@year@" -c genre="@genre@" -c comment="@comment@" -c encoded-by="%USERNAME%" -c encoding="OggEnc @Ver_OggEnc2@ @Opt_OggEnc2@" "@source@" -o "%TrackName%.ogg"
       @ECHO OFF
       IF %have_cover%==1 IF NOT EXIST folder.jpg COPY "@cover@" folder.jpg
   POPD
:end_oggenc_tracks


REM ================ End Main Script ===================


IF @Debug@==1 (
   PAUSE
   EXIT
)

REM ** Cleanup

DEL "@source@"
DEL "@eaclog@"
DEL "@cuesheet@"
DEL "@albumfile@.[*].cue"
DEL "@cover@"

REM ** Delete this .bat file:
DEL %0
[!--sizeo:1--][span style=\"font-size:8pt;line-height:100%\"][!--/sizeo--]
Moderation: Changed CODE to CODEBOX
[/size]
  • Last Edit: 08 January, 2007, 04:27:48 PM by Synthetic Soul

REACT 2 Released
Reply #141
If not, I have created a batch file to create an M3U.  It accepts a folder to process and a filename as parameters, e.g.:
[snip]

I use tag as in:
[snip]


Thanks for both of your suggestions!  I apologize for not finding the script before -- I was not certain if the information from the old threads would apply to the new version.

I'll try those out -- Thanks muchly!

GS

[edit] My understanding as to why EAC doesn't create an M3U automatically when using REACT with image + tracks is due to the behavior when one wants to rip an image as opposed to tracks.  Since EAC is just ripping in bulk, it doesn't send an M3U out including a track listing -- nor could it know that it will end up in FLAC (or whatever format) in the end anyway (to set the M3U file names correctly). [/edit]
  • Last Edit: 08 January, 2007, 10:41:14 PM by getsource

  • Synthetic Soul
  • [*][*][*][*][*]
  • Global Moderator
REACT 2 Released
Reply #142
Thanks for both of your suggestions! I apologize for not finding the script before -- I was not certain if the information from the old threads would apply to the new version.
If the Tag solution works I would go with that, seeing as it's already in the tools dir.  I wasn't saying that you should have found my batch file in the other thread - to be fair, it's around 20 pages long - I was just providing a little background to my post.

My understanding as to why EAC doesn't create an M3U automatically when using REACT with image + tracks is due to the behavior when one wants to rip an image as opposed to tracks. Since EAC is just ripping in bulk, it doesn't send an M3U out including a track listing -- nor could it know that it will end up in FLAC (or whatever format) in the end anyway (to set the M3U file names correctly).
Ah, I see.  I'm not familiar with EAC's M3U generation.  Thanks for the explanation.
I'm on a horse.

  • mmortal03
  • [*][*][*][*][*]
REACT 2 Released
Reply #143
I have CreateAllCuesheets=1, but I am using track creation.  No cuesheets are created.  Are cuesheets created only with image creation?  Further, is there any way to have it create ONLY a non-compliant cuesheet (e.g. the EAC cuesheet that is created when choosing "Create cuesheet with current settings")?  Is there any way to have it replace inside of the cuesheet the string ".wav" with ".flac", and the filenames relative to the position of the cuesheet placement, such to make the cuesheet compatible with the files that are actually outputted?
  • Last Edit: 10 January, 2007, 01:06:50 AM by mmortal03
WARNING:  Changing of advanced parameters might degrade sound quality.  Modify them only if you are expirienced in audio compression!

REACT 2 Released
Reply #144
Another question, if I may.  If it turns out that this is the incorrect place to ask it, please let me know, as I'm new here.

I'm attempting to plan the backup of my CD collection and trying to get the planning right this time -- as I started it earlier only to find out the plan was flawed.  What I'm trying to figure out is if REACT is correct for the job -- I believe it is, but am having some trouble getting the final details correct.

Here's what I'd like to have at the end of the process:
1) I'd like to have a lossless backup of each CD with all of the gaps (and potentially CD-TEXT, although this is less important) preserved.  Whether this backup is easy to listen to (i.e. in Tracks) or just a .flac and a .cue, for instance, is unimportant, although I certainly wouldn't mind having the .flacs in tracks that I could listen to on a regular basis.

2) MP3s of each track to use on portable devices and for standard listening with .M3U to have easy access to the album's correct order.  These would be better without the 'gaps' attached at the end of each track ... although if it's impossible to preserve the album another way, I'd be willing to do it like this.  I like how REACT tags, sets volume information, and adds album art -- I'd certainly like to still have all of this included if possible.

During this process, I'd prefer to use AccurateRip to verify my rips, since I know that some of my CDs are getting old and already starting to get errors (this is part of the reason for backing up now as opposed to later).  Plus, I haven't used these drives for very much secure audio ripping and am still in the process of trusting them.

The problem I've been coming upon is that with REACT and similar tools is in using AccurateRip due to the problem I talked about before with EAC using bulk mode instead of track mode because AccurateRip only functions in track mode.

Is there some way to preserve gaps by creating a .CUE that points to MP3s or WAVs (or requires decoding into WAVs to reburn) -- or otherwise another manner to get a perfect CD backup when ripping to tracks?  Maybe I can use REACT with some sort of script to reconstruct the album after ripping in track mode?

I also noticed it mentioned that there are some problems with album art and volume checking with track ripping -- what are these, and should I avoid this mode due to these problems?

Is there some automated way to do what I'm seeking -- or would it be better to just hit two buttons for each CD (even though the 'image' wouldn't be verified, per se)?

Am I just being overcautious/paranoid and should just use REACT and trust EAC/ignore AccurateRip?

Thanks for your help -- Again, if this should be moved, let me know, and I'll do so.  I'd like to use REACT, since I like its faculties, which is the reason I decided to post this here.

GS

  • Synthetic Soul
  • [*][*][*][*][*]
  • Global Moderator
REACT 2 Released
Reply #145
Ok.  I turned Debug on.  Apparently the problem is not with FLAC.  It's right after FLAC encodes and tries to move the cue and FLAC image to the FLAC dir.

Here's where the problem is..

Code: [Select]
C:\EAC>MOVE /Y "C:\EAC\Sublime - What I Got (Very Clean Radio Version) (Promo CD Single GAS5P-3874) [1996].flac" "C:\EAC\FLAC-images\Sublime - What I Got (Very Clean Radio Version) (Promo CD Single GAS5P-3874) [1996]"
The filename or extension is too long.

C:\EAC>MOVE /Y "C:\EAC\Sublime - What I Got (Very Clean Radio Version) (Promo CD Single GAS5P-3874) [1996].cue" "C:\EAC\FLAC-images\Sublime - What I Got (Very Clean Radio Version) (Promo CD Single GAS5P-3874) [1996]"
The filename or extension is too long.
I think I have found a resolve for this (maybe a bit late ):

If you define a label as such:

Code: [Select]
:GetShortPath
SET %2=%~fs1
GOTO:EOF

You can then use:

Code: [Select]
CALL :GetShortPath "C:\This is a long path\to a file.mp3" shortValue

ECHO %shortValue%


Or in the above example:

Code: [Select]
REM Remove original code
REM MOVE /Y "@image@" %dest%
REM MOVE /Y "@cuesheet@" %dest%

REM Create short name variables
CALL :GetShortPath %dest% destShortPath
  CALL :GetShortPath "@image@" imageShortPath
  CALL :GetShortPath "@cuesheet@" cuesheetShortPath

REM Move using short names
MOVE /Y %imageShortPath% %destShortPath%
MOVE /Y %cuesheetShortPath% %destShortPath%
  
...

:GetShortPath
SET %2=%~fs1
GOTO:EOF

May be useful in future... may not be.
I'm on a horse.

  • happypyro
  • [*]
REACT 2 Released
Reply #146
(Sorry Soul, I originally put this in the wrong thread)

Hi all, I want to start by thanking everyone who has worked on this great tool. I am a definate noob as far as ripping and archiving goes, but Ive found so much info here at hydrogenaudio I am almost overwelmed. What I have learned I am now acting on - I am using EAC with React2 to rip to flac for archiving and encode to vbr mp3 using lame for playback. So far everything is going great after reading through most of these posts and the wiki, so thanks again for all of your hard work.

One thing I havent found is how to define "mymusic" within React. currently EAC is ripping wav to a music folder on my desktop which is defined within EAC as the working directory, but then transcodes the flac and mp3 to the EAC folder in "C\docs & settings\my docs\my music". Not a big deal right now, but as the archive gets larger I want to have these files saved onto my D: drive. Can someone tell me how to define the "my music folder?
Thanks!

Heres my configs:
Code: [Select]
Version=2.0
ImageExt=wav
ImageNaming=$artist$ - [$year$] $album$
ImageHotKey={F10}
TracksHotKey={F4}
TracksHotVal=+{F5}
VA=Various Artists
CreateAllCuesheets=0
RunCoverDownloader=1
CoverDownloader=C:\Program Files\REACT2\coverdownloader\albumart.exe
EAC=C:\Program Files\Exact Audio Copy\EAC.exe
Tools=C:\Program Files\REACT2\tools
MinimizeCompressionWindow=1
ProcessPriority=1
Sla_Bks_Col_Qst_Bar_Quo_Ast_Lt_Gt=-|-|-||!|'|#|[|]

[UserTrackFormats]
Flac=1
Wavpack=0
LameMP3=1
NeroAac=0
iTunesAac=0
OggEnc2=0

[UserOutputNames]
OutRoot=@mymusic@\EAC
ImageDir_Flac=@OutRoot@\FLAC-images\$cdartist$
ImageDir_Wavpack=@OutRoot@\WV-images\$cdartist$
ImageDir_MP3=@OutRoot@\MP3-images\$cdartist$
TrackDir_Flac=@OutRoot@\FLAC\$cdartist$\[$year$] $album$
TrackDir_Wavpack=@OutRoot@\WV\$cdartist$\[$year$] $album$
TrackDir_MP3=@OutRoot@\MP3\$cdartist$\[$year$] $album$
TrackDir_AAC=@OutRoot@\AAC\$cdartist$\[$year$] $album$
TrackDir_OGG=@OutRoot@\OGG\$cdartist$\[$year$] $album$
TrackName_SA=$track$ - $title$
TrackName_VA=$track$ - $title$ [$artist$]
TrackName_SA_acdir=$n - $~t
TrackName_VA_acdir=$n - $~t [$~a]

[UserSettings]
Debug=0
Comment=Created with EAC/REACT2, @curdate@
EmbedCover=1
ReplayGain=1
ApplyAlbumGain=1
AdjustAlbumGain_dB=+3.0
AddCuesheetAG=0
UseWaveGainAG=0
Opt_Flac=-5 -f
Opt_Wavpack=-hmy
Opt_LameMP3=-V2 --vbr-new --noreplaygain --nohist
Opt_NeroAac=-lc -q 0.21
Opt_iTunesAac=-d -s 2000
Opt_OggEnc2=-q 3.0
Ver_Flac=1.1.3
Ver_Wavpack=4.40
Ver_LameMP3=3.97
Ver_NeroAac=1.0.0.2
Ver_OggEnc2=2.83 Lancer aoTuV b5
[!--sizeo:1--][span style=\"font-size:8pt;line-height:100%\"][!--/sizeo--]Moderation: changed CODE to CODEBOX[/size]
  • Last Edit: 18 January, 2007, 02:32:21 AM by Synthetic Soul

  • Synthetic Soul
  • [*][*][*][*][*]
  • Global Moderator
REACT 2 Released
Reply #147
(Sorry Soul, I originally put this in the wrong thread)
...
Not a big deal right now, but as the archive gets larger I want to have these files saved onto my D: drive. Can someone tell me how to define the "my music folder?
I have deleted your other post.

@mymusic@ is hard-coded to your "My Music" system folder.  Don't worry about it, just adjust OutRoot accordingly:

Change:

Code: [Select]
OutRoot=@mymusic@\EAC

... to:

Code: [Select]
OutRoot=D:

OutRoot uses @mymusic@ as its base purely as an example, and can be amended to any path you want.
  • Last Edit: 18 January, 2007, 02:34:58 AM by Synthetic Soul
I'm on a horse.

  • ESP85
  • [*]
REACT 2 Released
Reply #148
Ok.  I turned Debug on.  Apparently the problem is not with FLAC.  It's right after FLAC encodes and tries to move the cue and FLAC image to the FLAC dir.

Here's where the problem is..

Code: [Select]
C:\EAC>MOVE /Y "C:\EAC\Sublime - What I Got (Very Clean Radio Version) (Promo CD Single GAS5P-3874) [1996].flac" "C:\EAC\FLAC-images\Sublime - What I Got (Very Clean Radio Version) (Promo CD Single GAS5P-3874) [1996]"
The filename or extension is too long.

C:\EAC>MOVE /Y "C:\EAC\Sublime - What I Got (Very Clean Radio Version) (Promo CD Single GAS5P-3874) [1996].cue" "C:\EAC\FLAC-images\Sublime - What I Got (Very Clean Radio Version) (Promo CD Single GAS5P-3874) [1996]"
The filename or extension is too long.
I think I have found a resolve for this (maybe a bit late ):

If you define a label as such:

Code: [Select]
:GetShortPath
SET %2=%~fs1
GOTO:EOF

You can then use:

Code: [Select]
CALL :GetShortPath "C:\This is a long path\to a file.mp3" shortValue

ECHO %shortValue%


Or in the above example:

Code: [Select]
REM Remove original code
REM MOVE /Y "@image@" %dest%
REM MOVE /Y "@cuesheet@" %dest%

REM Create short name variables
CALL :GetShortPath %dest% destShortPath
  CALL :GetShortPath "@image@" imageShortPath
  CALL :GetShortPath "@cuesheet@" cuesheetShortPath

REM Move using short names
MOVE /Y %imageShortPath% %destShortPath%
MOVE /Y %cuesheetShortPath% %destShortPath%
  
...

:GetShortPath
SET %2=%~fs1
GOTO:EOF

May be useful in future... may not be.


Thanks alot.  It works great!!

  • mmortal03
  • [*][*][*][*][*]
REACT 2 Released
Reply #149
Are cuesheets created only with image creation when CreateAllCuesheets=1?
WARNING:  Changing of advanced parameters might degrade sound quality.  Modify them only if you are expirienced in audio compression!