I think it would awesome if you could add hotness and hot_color. A lot of people use the hotness code, and it is now as far as I know not possible to display such data in the track info. panel. With this addition, one would be able to do so.
If someone posts the formula for hotness I will look into it.
Hotness Code (topdownjimmy's original code and modified by others).
Note: change %play_counter% if using official statistics component to %play_count%.
Code for global variables tab:
// hourly decay version (hotness)
/////////////////////////////////////////
// baselines: define baseline frequency and decay periods
//
// baselinefrequency: decrease if songs stay hot too long
// baselinedecay: decrease if too many songs are hot
//
$puts(baselinefrequency,14)
$puts(baselinedecay,7)
// convert baselines to hours
$puts(baselinefrequency,$mul($get(baselinefrequency),24))
$puts(baselinedecay,$mul($get(baselinedecay),24))
// calculate "age": the number of hours the song has been in the library
// actually it's just hardcoded ^^
$puts(age,$mul(%play_counter%,$get(baselinefrequency)))
// calculate "recentness": number of hours since song was last played
$puts(recentness,
$sub(
$add(
$mul(
$add(
$mul($right(%_system_year%,2),365),
$select(%_system_month%,0,31,59,90,120,151,181,212,243,273,304,334),
$add($div($right(%_system_year%,2),4),$if($or($greater(%_system_month%,2),$greater($mod(%_system_year%,4),0)),1,0)),
%_system_day%
),
24
),
%_system_hour%
)
,
$add(
$mul(
$add(
$mul($substr(%last_played%,3,4),365),
$select($substr(%last_played%,6,7),0,31,59,90,120,151,181,212,243,273,304,334),
$add($div($substr(%last_played%,3,4),4),$if($or($greater($substr(%last_played%,6,7),2),$greater($mod($substr(%last_played%,1,4),4),0)),1,0)),
$substr(%last_played%,9,10)
),
24
),
$substr(%last_played%,12,13)
)
)
)
// calculate "decay": the specific decay period
$puts(decay,$div($mul(%play_counter%,$get(baselinefrequency),$get(baselinedecay),$if2(%rating%,$get(avgrating))),$mul($max($get(age),$get(baselinefrequency)),3)))
// calculate "hotness"
$puts(hotness,$div($mul($max($sub($get(decay),$get(recentness)),0),100),$get(decay)))
$set_global(hotness,$get(hotness))
$set_global(hot_color,$blend(000000|000000,0000FF|0000FF,$get(hotness),100))
/////////////////////////////////////////
Display hotness with $get_global(hotness). This will diplay a hotness value of 0-100. I use a character to display my hotness (along with the hotness color) and no number, such as $char(9650). You access hotness color with the hot_color variable and can set column custom style with $set_style(text,$get_global(hot_color),$get_global(hot_color)). You custom sort the column with $num($get_global(hotness),3). You have to have all three boxes checked under global variables tab, except legacy support and obviously all three boxes checked on the hotness column.